求助：关于《ANSYS土木工程应用实例》中钢筋混凝土梁例题的问题

hwaust

李围编的《ANSYS土木工程应用实例》中钢筋混凝土梁的计算，按照书上的命令流不能计算呀，那位版主给予纠正后发一份给我，谢谢

ztlikeyou

没看过这本书，上面的命令流写错了很正常，自己看看吧

wjw_8303

我这有一关于混凝土梁的命令流 看看对你是否有帮助：

!************************************************
!   钢筋混凝土梁的弹塑性分析命令流(单位制:SI制)
!************************************************
FINISH
/CLEAR
/FILENAME,RC-BEAM
/TITLE,ANALYSIS OF A RC-BEAM

/PREP7
ET,1,LINK8
ET,2,SOLID65
R,1,28.3E-6
R,2,113.1E-6
R,3,314.1E-6
R,4

MP,EX,1,2.1E11
MP,PRXY,1,0.3
TB,BKIN,1,1,2,1
TBDATA,,2.1E8,0.0

MP,EX,2,0.936E10
MP,PRXY,2,0.3
TB,KINH,2,1,8
TBTEMP,O
TBPT,,0.0001,0.936E6
TBPT,,0.0003,2.664E6
TBPT,,0.0006,4.896E6
TBPT,,0.0009,6.696E6
TBPT,,0.0012,8.064E6
TBPT,,0.0016,9.216E6
TBPT,,0.002,9.6E6
TBPT,,0.0033,9.6E6
TB,CONC,2,1,9   !定义混凝土的破坏参数
TBDATA,,0.3,0.55,1.5E6,-1

BLOCK,0.0,3.0,0.0,0.4,0.0,-0.2
/VIEW,1,1,2,3
/REP,FAST
LPLOT
/PNUM,LINE,1
/REPLOT

VATT,2,4,2
LSEL,S,LINE,,4,5,1
LSEL,A,LINE,,2,7,5
LESIZE,ALL,0.05
LSEL,INVE
LESIZE,ALL,0.025
LSEL,ALL
VMESH,ALL

!建立箍筋单元
NSEL,S,LOC,X,0.125,0.175
NPLOT
/VIEW,1,1
/REP,FAST
/PNUM,NODE,1
/REPLOT
TYPE,1
MAT,1
REAL,1
!通过循环建立第一圈箍筋
*DO,I,3349,3354,1
E,I,I+1
*ENDDO
*DO,I,3355,3446,7
E,I,I+7
*ENDDO
*DO,I,3452,3447,-1
E,I+1,I
*ENDDO
*DO,I,3447,3356,-7
E,I,I-7
*ENDDO
!复制第一圈箍筋，每隔0.15m布置一圈箍筋
ESEL,S,TYPE,,1
EGEN,19,315,ALL,,,,,,,,0.15,0.0,0.0
ALLSEL,ALL

!建立架立筋单元
TYPE,1
MAT,1
REAL,2
*DO,I,3237,9222,105
E,I,I+105
*ENDDO
ESEL,R,REAL,,2
EGEN,2,6,ALL,,,,,,,,0.0,0.0,0.15
ALLSEL,ALL

!建立纵筋单元
TYPE,1
MAT,1
REAL,3
*DO,I,3145,9130,105
E,I,I+105
*ENDDO
ESEL,R,REAL,,3
EGEN,3,-3,ALL,,,,,,,,0.0,0.0,-0.075
ALLSEL,ALL
ESEL,S,TYPE,,1
EPLOT
/VIEW,1,1,2,3
/REP

FINISH

/SOLU

!施加位移约束
NSEL,S,LOC,Y,0.19,0.21
NSEL,R,LOC,X,-0.01,0.01
D,ALL,ALL
ALLSEL,ALL
NSEL,S,LOC,Y,0.19,0.21
NSEL,R,LOC,X,2.99,3.01
D,ALL,ALL
ALLSEL,ALL

!施加荷载
NSEL,S,LOC,Y,0.39,0.41
SF,ALL,PRES,50000
ALLSEL,ALL

!设置求解选项
ANTYPE,0
NLGEOM,1
NROPT,FULL
EQSLV,SPARSE,,0
TIME,1.0
AUTOTS,1
NSUBST,100,200,50,1
KBC,0
CNVTOL,U,,0.03,0
NEQIT,50
PRED,ON,,ON
OUTRES,ALL,ALL

SOLVE
FINISH

/POST1
SET,LAST
/DSCALE,1,100
/REPLOT
PLDISP,2
PLNSOL,U,Y,0,1
PLCRACK,0,0

FINISH

酒神阿波罗

谢谢楼上！！

zhanfeng7467024

请问在哪儿可以下到这本书的命令流

zhadaonan

谢谢楼上！！

0921671482

谢谢楼楼上！！