/rep
/prep7
/title,cablebridge
/rep
!定义单元类型及材料属性
et,1,beam188!梁单元
et,2,link8
et,3,plane82 !平面单元用于网格划分
et,4,beam4!鱼骨梁
mp,ex,1,2e6 !混凝土主梁材料属性
mp,prxy,1,0.3
mp,ex,2,2e5 !斜拉索材料属性
r,1,0.003!斜拉索实常数
r,2,1,1/12,1/12,,,,,1/3!鱼梁骨实常数
!建立主梁截面模型
k,1,465,0
k,2,465,80
k,3,500,90
k,4,500,100
ksym,x,all,,4
a,1,2,3,4,8,7,6,5
k,9,15,35
k,10,30,20
k,11,370,20
k,12,385,35
k,13,385,60
k,14,305,80
k,15,95,80
k,16,15,60
kplot
ksymm,x,9,16,1,8
a,9,10,11,12,13,14,15,16
a,17,18,19,20,21,22,23,24
asba,1,2
asba,4,3
numcmp,all
wpoffs,0,20
wprota,0,90
asbw,all
wpoffs,0,0,-15
asbw,all
wpoffs,0,0,-25
asbw,all
wpoffs,-465
wprota,0,0,90
asbw,all
/rep
aplot
wpoffs,0,0,80
/pnum,area,1
aplot
asbw,10
wpoffs,0,0,80
asbw,11
wpoffs,0,0,210
asbw,12
wpoffs,0,0,80
asbw,13
wpoffs,0,0,30
asbw,14
wpoffs,0,0,80
asbw,15
wpoffs,0,0,210
asbw,16
wpoffs,0,0,80
asbw,17
wpoffs,0,0,80
asbw,18
wpcsys
wpstyl
esize,25
mshape,0,2d
mshkey,1
amap,8,30,21,20,28
amap,2,26,5,1,25
amap,5,28,26,19,20
amap,1,17,18,10,9
amap,4,12,11,25,27
amap,7,13,12,27,29
amap,3,24,17,9,16
amap,17,40,2,3,4
amap,19,39,13,29,40
amap,16,38,14,13,39
amap,15,37,15,14,38
amap,14,36,16,15,37
amap,13,35,36,16,24
amap,12,34,23,24,35
amap,11,33,22,23,34
amap,10,32,33,22,21
amap,9,31,32,21,30
amap,6,8,31,6,7
allsel,all
secwrite,jiemian,sect,,3!写入主梁截面(1)
aclear,all
adele,all
ldele,all
kdele,all
wpcsys
!建立桥塔截面模型
k,1,65,0
k,2,65,25
k,3,60,30
k,4,60,100
k,5,65,105
k,6,65,130
ksymm,x,all,,,6
a,1,2,3,4,5,6,12,11,10,9,8,7
esize,13
mshape,0,2d
mshkey,1
wpoffs,0,25
wprota,0,90
asbw,all
/rep
aplot
wpoffs,0,0,-5
asbw,all
wpoffs,0,0,-70
asbw,all
wpoffs,0,0,-5
asbw,all
lsel,s,line,,6,12,6
lesize,all,,,5
lsel,s,line,,13,16
lesize,all,,,5
lsel,s,line,,1,11,10
lesize,all,,,1
lsel,s,line,,5,7,2
lesize,all,,,1
lsel,s,line,,3,9,6
lesize,all,,,4
amesh,all
allsel,all
secwrite,qiaota1,sect,,3!写入桥塔截面文件(2)
aclear,all
adele,all
ldele,all
kdele,all
wpcsys
/rep
!建立桥塔墩截面模型
k,1,85,0
k,2,85,25
k,3,80,30
k,4,80,140
k,5,85,145
k,6,85,170
ksymm,x,all,,,6
a,1,2,3,4,5,6,12,11,10,9,8,7
esize,17
mshape,0,2d
mshkey,1
wpoffs,0,25
wprota,0,90
asbw,all
/rep
aplot
wpoffs,0,0,-5
asbw,all
wpoffs,0,0,-110
asbw,all
wpoffs,0,0,-5
asbw,all
lsel,s,line,,6,12,6
lesize,all,,,5
lsel,s,line,,13,16
lesize,all,,,5
lsel,s,line,,1,11,10
lesize,all,,,1
lsel,s,line,,5,7,2
lesize,all,,,1
lsel,s,line,,3,9,6
lesize,all,,,4
amesh,all
allsel,all
secwrite,qiaota2,sect,,3!写入桥塔墩截面文件(3)
aclear,all
adele,all
ldele,all
kdele,all
wpcsys
wpstyl
/rep
!建立主梁节点
*do,i,1,52
n,i,0,(-300/5192)*100*(i-1)+300,100*(i-1)
*enddo
n,53,0,(-300/5192)*5192+300,5192
nsym,z,53,all
sectype,1,beam,mesh
secread,jiemian,sect,,mesh
type,1
mat,1
secnum,1
n,20000,0,1000,-10000
*do,i,1,52
e,i,i+1
e,53+i,54+i,20000
*enddo
/eshape,1
eplot
n,107,-425,-450
/pnum,node,1
/rep
ngen,136,1,107,,,0,5
ngen,118,1,242,,,0,5
ngen,29,1,359,,,0,5
n,388,-425,ny(387)+60
ngen,5,1,388,,,0,160
n,393,-425,ny(392)+100
nsym,x,287,107,393
fill,242,529,10,681!下横梁节点
n,916,0,ny(785)
fill,391,678,10,917!上横梁节点
!建立桥塔单元
sectype,2,beam,mesh
secread,qiaota1,sect,,mesh
type,1
mat,1
secnum,2
e,387,388,675
*repeat,6,1,1,0
e,674,675,388
*repeat,6,1,1,0
!建立桥塔及墩单元
k,1,nx(387),ny(387)
k,2,nx(107),ny(107)
k,3,nx(674),ny(674)
k,4,nx(394),ny(394)
l,1,2
l,3,4
sectype,3,beam,mesh
secread,qiaota2,sect,,mesh
sectype,4,taper
secdata,2,kx(1),ky(1)
secdata,3,kx(2),ky(2)
lsel,s,line,,1
latt,1,,1,,3,,4
lesize,all,5
lmesh,all
sectype,5,taper
secdata,2,kx(3),ky(3)
secdata,3,kx(4),ky(4)
lsel,s,line,,2
latt,1,,1,,1,,4
lesize,all,5
lmesh,all
gplot
nummrg,all
numcmp,all
!建立上横梁
sectype,5,beam,rect
secdata,120,130
type,1
mat,1
secnum,5
e,390,691
e,691,692
*repeat,9,1,1
e,700,677
!建立下横梁
sectype,6,beam,rect
secdata,50,200
type,1
mat,1
secnum,6
e,241,680
e,680,681
*repeat,4,1,1
e,684,690
e,690,685
e,685,686
*repeat,4,1,1
e,689,528
!建立刚性鱼刺骨横梁
ngen,2,2000,5,29,4,-425
ngen,2,3000,5,29,4,425
ngen,2,4000,57,81,4,-425
ngen,2,5000,57,81,4,425
type,4
mat,1
real,2
e,5,2005
*repeat,7,4,4
e,5,3005
*repeat,7,4,4
e,57,4057
*repeat,7,4,4
e,57,5057
*repeat,7,4,4
!建立斜拉索
type,2
mat,2
real,1
!左侧
e,308,2005
e,358,2009
e,387,2013
*repeat,5,1,4
e,595,3005
e,645,3009
e,674,3013
*repeat,5,1,4
!右侧
e,308,4057
e,358,4061
e,387,4065
*repeat,5,1,4
e,595,5057
e,645,5061
e,674,5065
*repeat,5,1,4
nummrg,all
numcmp,all
/solu
d,53,uy,0
d,105,uy,0,,,,uz
d,106,all
d,393,all
cp,1,uy,1,690
cp,2,uz,1,690
cp,3,ux,1,690
f,10,fy,-50
f,11,fy,-50
f,12,fy,-50
allsel,all
solve!求解
/post1 |