下面是谐波分析的程序。麻烦高手各位看下啦!我实在是被折腾坏了。有啥发现可以qq联系我:584513882. 不甚感激呀!
FINISH
/CLEAR,START
/FILNAME,XIEBO-4,1 !两极两层三相绕组线圈电磁搅拌test6
/TITLE,MHD XIEBO ANALYSIS
KEYW,MAGNOD,1 !选择要显示的参数
!*****************************************************
!进入前处理区
!*****************************************************
/PREP7
R1=0.165 !定子外半径
R2=0.091 !定子内半径
H2=0.030 !定子槽深
R3=0.028 !熔体半径
R4=0.330 !远场区域半径
P=1 !定子极对数
IS1=5000000 !绕组A电流密度
IS2=2500000 !绕组B电流密度
IS3=2500000 !绕组C电流密度
!****************************************************
ET,1,PLANE53
MP,MURX,1,1 !No.1 材料为空气
MP,MURX,2,1 !No.2 材料为线圈
MP,RSVX,2,1.724E-8 !线圈电阻率
TB,BH,3,,45 !No.3 材料为硅钢片B-H曲线
TBPT,,50,0.1
TBPT,,60,0.16
TBPT,,70,0.285
TBPT,,80,0.32
TBPT,,90,0.41
TBPT,,100,0.52
TBPT,,110,0.63
TBPT,,120,0.74
TBPT,,130,0.82
TBPT,,140,0.905
TBPT,,150,0.97
TBPT,,160,1.05
TBPT,,170,1.07
TBPT,,180,1.09
TBPT,,190,1.12
TBPT,,200,1.15
TBPT,,210,1.175
TBPT,,220,1.2
TBPT,,230,1.22
TBPT,,240,1.24
TBPT,,250,1.265
TBPT,,260,1.275
TBPT,,270,1.29
TBPT,,280,1.305
TBPT,,290,1.32
TBPT,,300,1.335
TBPT,,400,1.41
TBPT,,500,1.46
TBPT,,600,1.48
TBPT,,700,1.505
TBPT,,800,1.515
TBPT,,900,1.535
TBPT,,1000,1.543
TBPT,,1500,1.575
TBPT,,2000,1.603
TBPT,,2500,1.623
TBPT,,3000,1.645
TBPT,,3500,1.655
TBPT,,4000,1.673
TBPT,,5000,1.705
TBPT,,6000,1.745
TBPT,,7000,1.77
TBPT,,8000,1.79
TBPT,,9000,1.81
TBPT,,10000,1.84
MP,MURX,4,1 !No.4 材料为不锈钢4Cr13液体
MP,RSVX,4,4.808E-7 !熔体的电阻率
!****************************************************
!建立几何模型
!****************************************************
!建立定子铁心模型
CYL4,0,0,R2,360,R1,360
PCIRC,R2,R2+H2,87,93
CSYS,1
AGEN,36,2,,,,-10
CSYS,0
ASBA,1,2,,,DELETE
NUMCMP,ALL
*DO,K,36,2,-1
ASBA,K,1,,,DELETE
NUMCMP,ALL
*ENDDO
!建立内层绕组线圈模型
RECTNG,-0.003,0.003,0.095,0.105
CSYS,1
AGEN,36,2,,,,-10
CSYS,0
!建立外层绕组线圈模型
RECTNG,-0.003,0.003,0.107,0.117
CSYS,1
AGEN,36,38,,,,-10
CSYS,0
!建立熔体模型
CYL4,0,0,R3,360
!建立空气模型
CYL4,0,0,R4,360
AOVLAP,ALL
NUMCMP,ALL
!****************************************************
!划分单元
!****************************************************
ASEL,S,AREA,,75,76 !空气单元
AATT,1,,1
ASEL,S,AREA,,2,73,1 !线圈单元
AATT,2,,1
ASEL,S,AREA,,1 !定子铁心单元
AATT,3,,1
ASEL,S,AREA,,74 !熔体单元
AATT,4,,1
ASEL,ALL
MSHAPE,1,2D
MSHKEY,0
SMRT,2
AMESH,ALL
!****************************************************
!定义约束并进行加载
!****************************************************
/SOLU
CSYS,0
!定义线圈电流密度
ASEL,S,AREA,,2,7,1 !内层绕组一相A1端
ESLA,S
BFE,ALL,JS,1,,,IS1,0
ASEL,S,AREA,,8,13,1 !内层绕组一相Z2端
ESLA,S
BFE,ALL,JS,1,,,-IS1,120
ASEL,S,AREA,,14,19,1 !内层绕组一相B1端
ESLA,S
BFE,ALL,JS,1,,,IS1,-120
ASEL,S,AREA,,20,25,1 !内层绕组一相X2端
ESLA,S
BFE,ALL,JS,1,,,-IS1,0
ASEL,S,AREA,,26,31,1 !内层绕组一相C1端
ESLA,S
BFE,ALL,JS,1,,,IS1,120
ASEL,S,AREA,,32,37,1 !内层绕组一相Y2端
ESLA,S
BFE,ALL,JS,1,,,-IS1,-120
ASEL,S,AREA,,38,39,1 !外层绕组一相A2端
ASEL,A,AREA,,70,73,1
ESLA,S
BFE,ALL,JS,1,,,IS1,0
ASEL,S,AREA,,40,45,1 !内层绕组一相Z1端
ESLA,S
BFE,ALL,JS,1,,,-IS1,120
ASEL,S,AREA,,46,51,1 !内层绕组一相B2端
ESLA,S
BFE,ALL,JS,1,,,IS1,-120
ASEL,S,AREA,,52,57,1 !内层绕组一相X1端
ESLA,S
BFE,ALL,JS,1,,,-IS1,0
ASEL,S,AREA,,58,63,1 !内层绕组一相C2端
ESLA,S
BFE,ALL,JS,1,,,IS1,120
ASEL,S,AREA,,64,69,1 !内层绕组一相Y1端
ESLA,S
BFE,ALL,JS,1,,,-IS1,-120
ALLSEL,ALL
!定义次级组件施加磁力标志
ASEL,S,AREA,,74
ESLA,S
CM,ARMATRUE,ELEM
FMAGBC,'ARMATRUE'
ALLSEL,ALL
!施加边界条件
CSYS,1
WPCSYS,1
LSEL,S,LOC,X,R4
NSLL,S
D,ALL,AZ,0
CSYS,0
WPCSYS,0
ALLSEL,ALL
NEQIT,50
ANTYP,HARM
HARFR,60
!****************************************************
!求解
!****************************************************
SOLVE
!****************************************************
!后处理
!**************************************************** |