相变水结冰过程分析实例【命令流+最终温度分别图】

lingxue_001

这个例子可以学到很多东西，可以获得get命令、path定义、时间变量等多个知识点的内容，练习一下肯定大有收获。

水结冰过程分析

/filname,phase1
/title,water phase change analysis

/prep7
et,1,plane55
keyopt,1,3,1
mp,dens,1,1000                                 
mp,kxx,1,0.6            !导热系数
MPTEMP,,,,,,,,  
MPTEMP,1,-10
MPTEMP,2,-1
MPTEMP,3,0  
MPTEMP,4,10
MPDATA,ENTH,1,,0
MPDATA,ENTH,1,,3.78e7   
MPDATA,ENTH,1,,7.98e7   
MPDATA,ENTH,1,,1.22e8    !不同温度点焓值

rectang,0,0.02,0,0.1
/pnum,line,1
/replot
lsel,s,line,,1,3,2
lesize,all,,,5
lsel,s,line,,2,4,2
lesize,all,,,20
amesh,1
eplot
finish

/solu
antype,trans
bfunif,temp,0     !施加均匀温度载荷
lsel,s,line,,1,3
nsll,s,1
sf,all,conv,12.5,-10          !分别是对流系数、空气温度
allsel
time,7200    !单位秒
deltim,30,30,100
kbc,1                   !阶跃载荷
autots,on
outres,,all
solve
finish

/post1
set,,,,,1800        !读取1800秒时结果
plnsol,temp         
set,last
plnsol,temp
/axlab,x,dist,(m)
/axlab,y,temp
/gthk,axis,3
/gthk,curve,3
nsel,s,loc,x,0.02        !选择节点
nsel,r,loc,y,0
*get,node1,node,,num,max   !根据坐标选择最大节点编号

nsel,s,loc,x,0.02        !选择节点
nsel,r,loc,y,0.1
*get,node2,node,,num,max   !根据坐标选择最大节点编号

nsel,s,loc,x,0        !选择节点
nsel,r,loc,y,0.1
*get,node3,node,,num,max   !根据坐标选择最大节点编号

nsel,s,loc,x,0        !选择节点
nsel,r,loc,y,0.05
*get,node4,node,,num,max   !根据坐标选择最大节点编号

nsel,s,loc,x,0.02        !选择节点
nsel,r,loc,y,0.05
*get,node5,node,,num,max   !根据坐标选择最大节点编号

allsel

path,tpath1,2,,30        !定义路径
ppath,1,1
ppath,2,node1
pdef,temp,temp         ！映射路径
plpath,temp            !画出路径

path,tpath2,2,,30        !定义路径
ppath,1,1
ppath,2,node3
pdef,temp,temp         ！映射路径
plpath,temp            !画出路径

finish

/post26
/axlab,x,time,(sec)
/axlab,y,temp
nsol,2,node2,temp,,ta    !变量定义
nsol,3,node3,temp,,tb    !变量定义
nsol,4,node4,temp,,tc    !变量定义
nsol,5,node5,temp,,td    !变量定义
plvar,2,3,4,5
finish

/exit,all

lingxue_001

现在的好帖子都是03年左右的了，以前曾无比活跃的板块很多都落寞了，能出个好的帖子也越来越难了，高手一批批成名之后可能就隐退了，像我这样的菜鸟只能每天搜寻着以前高手们留下来的精华，努力地学习着，在慢慢地一步步地提升自己，尽管知道有限元的路是越走越艰辛，因为走得越远就会知道自己不会的东西越多，但还是坚信能追寻着高手的足迹，使自己的分析水平能在自己的能力范围内有个自我的顶点。希望斑竹给个技术分鼓励一下呗，虽不是原创，但自己也亲手进行了修改调试，并进行了简单的注释

fancunhui

lingxue_001 发表于 2011-9-16 20:08
现在的好帖子都是03年左右的了，以前曾无比活跃的板块很多都落寞了，能出个好的帖子也越来越难了，高手一批 ...

学习下
写楼主

zhuljuan

非常感谢楼主

flypanzxl

楼主讲的真好。说出了我们的心声啊。

liudapengsnd

楼主不错呀，很好的帖子

likeyu1118

唉，巨大的帮助，我快被老师搞疯了！

daoyongwu

有没有人做冻土中冰水相变的？

mole334

学到了很多  谢谢楼主！

不吃香菜

daoyongwu 发表于 2014-5-30 09:03
有没有人做冻土中冰水相变的？

请问你找到了吗