谁有有关用ansys做复合材料层合板的算例？

dangjt

小弟想练练手，学学人家怎么做，谢谢！！！
email:jt_dang@163.com

xqgao1224

我也想要。还是发上来我们下吧！！！

复合材料22

我做过缺口件的强度，不过没有考虑分层。

wangxiaohong422

我也想要，能否也给我一份？谢谢！
wangxiaohong422@126.com

hitng

如果有兄弟有的话 算我一个
小弟 联系方式   gongnanmail@163.com

QQ106363503

也 算我一个
小弟 联系方式   zxj982003@163.com

lbt18872

/COM,ANSYS MEDIA REL. 9.0 (10/15/2004) REF. VERIF. MANUAL: REL. 9.0
/VERIFY,VM144
/PREP7
/TITLE, VM144, BENDING OF A COMPOSITE BEAM
C***    FORMULAS FOR STRESS AND STRAIN, ROARK, 5TH ED.
C***    USING LAYERED SHELL ELEMENT (SHELL99)
ANTYPE,STATIC
ET,1,SHELL99                ! 8 NODE LAYERED SHELL ELEMENT
R,1,2                       ! 2 LAYERS PER ELEMENT
RMORE
RMORE,1,0,.2,2,0,.1         ! LAYER 1: 0.2 THK; LAYER 2: 0.1 THK
MP,EX,1,1.2E6               ! MATERIAL 1 PROPERTIES
MP,NUXY,1,0
MP,ALPX,1,18E-5
MP,ALPY,1,0.0
MP,EX,2,0.4E6               ! MATERIAL 2 PROPERTIES
MP,NUXY,2,0
MP,ALPX,2,6E-5
MP,ALPY,2,0
N,1
N,9,8
FILL
NGEN,3,10,1,9,,,.25
E,1,3,23,21,2,13,22,11
EGEN,4,2,-1                 ! 4 ELEMENTS ALONG BEAM LENGTH
CP,1,ROTY,9,19,29           ! COUPLE FREE END NODES FOR ROTATION
D,1,ALL,,,21,10             ! FIXED END
F,19,MY,10                  ! APPLY BENDING MOMENT AT FREE EDGE
BFUNIF,TEMP,100             ! ELEVATED TEMPERATURE LOAD
FINISH
/SOLU   
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,8              ! SELECT FREE EDGE
PRNSOL,U,Z                  ! PRINT DISPLACEMENTS
*GET,U1,NODE,9,U,Z
NSEL,S,LOC,Y                ! SELECT NODES ALONG LENGTH
SHELL,TOP
PRNSOL,S,COMP               ! PRINT TOP STRESSES
*GET,ST1,NODE,1,S,X
SHELL,BOT
PRNSOL,S,COMP               ! PRINT BOTTOM STRESSES
*GET,SB1,NODE,1,S,X
ALLSEL  
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DISP ','PRS TP ','PRS BTM '
LABEL(1,2) = 'in','psi','psi'
*VFILL,VALUE(1,1),DATA,.832,2258,1731
*VFILL,VALUE(1,2),DATA,U1,ST1,SB1
*VFILL,VALUE(1,3),DATA,ABS(U1/.832),ABS(ST1/2258),ABS(SB1/1731)
SAVE,TABLE_1
FINISH
/PREP7
C***     USING SHELL99 ELEMENTS WITH NODE OFFSET OPTION
ET,1,SHELL99                ! 8 NODE LAYERED SHELL ELEMENT
KEYOPT,1,11,2               !  WITH NODAL PLANE ON TOP FACE
R,1,1                       ! BOTTOM LAYER
RMORE
RMORE,1,0,.2
ET,2,SHELL99                ! 8 NODE LAYERED SHELL ELEMENT
KEYOPT,2,11,1               !  WITH NODAL PLANE ON BOTTOM FACE
R,2,1                       ! TOP LAYER
RMORE
RMORE,2,0,.1               
EGEN,2,0,1,4,1,,1,1         ! GENERATE OVERLAPPING ELEMENTS
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,8              ! SELECT FREE EDGE
PRNSOL,U,Z                  ! PRINT DISPLACEMENTS
*GET,U2,NODE,9,U,Z
NSEL,S,LOC,Y                ! SELECT NODES ALONG LENGTH
SHELL,TOP
ESEL,S,TYPE,,2              ! ELEMENTS REPRESENTING TOP LAYER
PRNSOL,S,COMP               ! PRINT TOP STRESSES
*GET,ST2,NODE,1,S,X
SHELL,BOT
ESEL,S,TYPE,,1              ! ELEMENTS REPRESENTING BOTTOM LAYER
PRNSOL,S,COMP               ! PRINT BOTTOM STRESSES
*GET,SB2,NODE,1,S,X
*VFILL,VALUE(1,1),DATA,.832,2258,1731
*VFILL,VALUE(1,2),DATA,U2,ST2,SB2
*VFILL,VALUE(1,3),DATA,ABS(U2/.832),ABS(ST2/2258),ABS(SB2/1731)
SAVE,TABLE_2
FINISH
/CLEAR,NOSTART
/PREP7
/TITLE, VM144, BENDING OF A COMPOSITE BEAM
C***    FORMULAS FOR STRESS AND STRAIN, ROARK, 5TH ED.
C***    USING LAYERED SOLID ELEMENTS (SOLID46)
ANTYPE,STATIC
ET,1,SOLID46,,,,,2,4        ! LAYERED SOLID ELEMENTS
R,1,2                       ! 2 LAYERS
RMORE
RMORE,1,0,2,2,0,1           ! RELATIVE LAYER THICKNESSES
MP,EX,1,1.2E6               ! MATERIAL 1 PROPERTIES
MP,NUXY,1,0
MP,ALPX,1,1.8E-4
MP,ALPY,1,0.0
MP,ALPZ,1,0.0
MP,EX,2,0.4E6               ! MATERIAL 2 PROPERTIES
MP,NUXY,2,0
MP,ALPX,2,0.6E-4
MP,ALPY,2,0.0
MP,ALPZ,2,0.0
N,1
N,9,8
FILL
NGEN,2,10,1,9,1,,.5
NGEN,2,20,1,19,1,,,.3
E,1,2,12,11,21,22,32,31
EGEN,8,1,-1                 ! 8 ELEMENTS ALONG LENGTH
D,1,ALL,,,31,10             ! FIXED END
F,9,FX,-(50/3),,19,10       ! APPLY NODAL FORCES TO GENERATE MOMENT
F,29,FX,(50/3),,39,10
BFUNIF,TEMP,100             ! ELEVATED TEMPERATURE LOAD
FINISH
/SOLU   
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,8
PRNSOL,U,Z                  ! PRINT FREE END DISPLACEMENTS
*GET,U3,NODE,9,U,Z
NSEL,S,LOC,Z,0.3
PRNSOL,S,COMP               ! PRINT STRESSES ALONG TOP SURFACE
*GET,ST3,NODE,21,S,X
NSEL,S,LOC,Z
PRNSOL,S,COMP               ! PRINT STRESSES ALONG BOTTOM SURFACE
*GET,SB3,NODE,1,S,X
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DISP ','PRS TP ','PRS BTM '
LABEL(1,2) = 'in','psi','psi'
*VFILL,VALUE(1,1),DATA,.832,2258,1731
*VFILL,VALUE(1,2),DATA,U3,ST3,SB3
*VFILL,VALUE(1,3),DATA,ABS(U3/.832),ABS(ST3/2258),ABS(SB3/1731)
SAVE, TABLE_3
FINISH
/CLEAR,NOSTART
/PREP7
/TITLE, VM144, BENDING OF A COMPOSITE BEAM
C***    FORMULAS FOR STRESS AND STRAIN, ROARK, 5TH ED.
C***    USING LAYERED SOLID ELEMENTS (SOLID191)
ANTYPE,STATIC
ET,1,SOLID191,,,,,2,        ! LAYERED SOLID ELEMENTS
R,1,2                       ! 2 LAYERS
RMORE
RMORE,1,0,2,2,0,1           ! RELATIVE LAYER THICKNESSES
MP,EX,1,1.2E6               ! MATERIAL 1 PROPERTIES
MP,NUXY,1,0
MP,ALPX,1,1.8E-4
MP,ALPY,1,0.0
MP,ALPZ,1,0.0
MP,EX,2,0.4E6               ! MATERIAL 2 PROPERTIES
MP,NUXY,2,0
MP,ALPX,2,0.6E-4
MP,ALPY,2,0.0
MP,ALPZ,2,0.0
N,1
N,9,8
FILL
NGEN,2,10,1,9,1,,.5
NGEN,2,20,1,19,1,,,.3
E,1,2,12,11,21,22,32,31
EGEN,8,1,-1                 ! 8 ELEMENTS ALONG LENGTH
emid
nsel,s,loc,x
D,all,ALL,                  ! FIXED END
nsel,all
nlist,all
sfe,8,3,pres,,4000/3,4000/3,-4000/3,-4000/3  ! tapered pressure to apply moment on face
BFUNIF,TEMP,100             ! ELEVATED TEMPERATURE LOAD
FINISH
/SOLU   
outpr,,1
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,8
PRNSOL,U,Z                  ! PRINT FREE END DISPLACEMENTS
*GET,U3,NODE,9,U,Z
NSEL,S,LOC,Z,0.3
PRNSOL,S,COMP               ! PRINT STRESSES ALONG TOP SURFACE
*GET,ST3,NODE,21,S,X
NSEL,S,LOC,Z
PRNSOL,S,COMP               ! PRINT STRESSES ALONG BOTTOM SURFACE
*GET,SB3,NODE,1,S,X
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DISP ','PRS TP ','PRS BTM '
LABEL(1,2) = 'in','psi','psi'
*VFILL,VALUE(1,1),DATA,.832,2258,1731
*VFILL,VALUE(1,2),DATA,U3,ST3,SB3
*VFILL,VALUE(1,3),DATA,ABS(U3/.832),ABS(ST3/2258),ABS(SB3/1731)
SAVE, TABLE_4

RESUME,TABLE_1
/COM
/OUT,vm144,vrt
/COM,------------------- VM144 RESULTS COMPARISON --------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,RESULTS USING SHELL99 MODEL
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING SHELL99 (WITH NODE OFFSET)
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,RESULTS USING SOLID46
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/NOPR
RESUME, TABLE_4
/GOPR
/COM,RESULTS USING SOLID191
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm144,vrt

lbt18872

Bending of a Composite Beam

Overview
Reference: R. J. Roark, W. C. Young, Formulas for Stress and Strain, McGraw-Hill Book Co., Inc., New York, NY, 1975, pg. 112-114, article 7.2.
Analysis Type(s): Static Analysis (ANTYPE = 0)
Element Type(s): Linear Layered Structural Shell Elements (SHELL99)
3-D 8-Node Layered Structural Solid Elements (SOLID46)  

Input Listing: vm144.dat

Test Case
A beam of length  and width w, made up of two layers of different materials, is subjected to a uniform rise in temperature from Tref to To and a bending moment My at the free-end. Determine the free-end displacement δ (in the Z-direction) and the X- direction stresses at the top and bottom surfaces of the layered beam. Ei and αi correspond to the Young's modulus and thermal coefficient of expansion for layer i, respectively.

Figure 144.1  Composite Beam Problem Sketch



Material Properties
MAT1:
E1 = 1.2 x 106 psi
α1 = 1.8 x 10-4 in/in/°F
MAT2:
E2 = 0.4 x 106 psi
α2 = 0.6 x 10-4 in/in/°F
Geometric Properties
= 8 in
w = 0.5 in
t1 = 0.2 in
t2 = 0.1 in
Loading
To = 100°F
Tref = 0°F
My = 10.0 in-lb


Analysis Assumptions and Modeling Notes
The beam is idealized to match the theoretical assumptions by taking ν = αy = αz = 0. Three models are used for verification of results as described below. Nodal coupling of the ROTY degree of freedom is used for the SHELL99 models to apply the uniform edge moment. Opposing nodal forces are applied at the top and bottom edges of the free end for the SOLID46 model to apply the end moment. The magnitude of these applied nodal forces is calculated as: FX = My/(2 * (t1+t2)) = 10/0.6 = (100/6). POST1 is used to obtain the nodal stresses and displacements.

The first model uses four SHELL99 elements (each with 2 layers).

The second model is a variation of the first model to verify the node offset option for SHELL99 elements. In this model, two sets of four overlapping elements (a total of eight SHELL99 elements) are used. Each set represents a single layer. The set of four elements representing the lower layer has its nodal plane located on the "top" face whereas the set of elements corresponding to the top layer has its nodal plane located on the "bottom" face. The combination of overlapping elements thus defines a two-layered beam with its nodal plane at the interface between the layers (offset from the middle plane).

The third model uses eight SOLID46 elements (each with 2 layers), similar to the first SHELL99 model.

Results Comparison
  Target ANSYS Ratio
SHELL99 model Displacement, in 0.832 0.832[1] 1.000
StressxTOP , psi 2258. 2258. 1.000
StressxBOT , psi 1731. 1731. 1.000
SHELL99 model (with node offset) Displacement, in 0.832 0.832[1] 1.000
StressxTOP , psi 2258. 2258.[2] 1.000
StressxBOT , psi 1731. 1731.[2] 1.000
SOLID46 model Displacement, in 0.832 0.832[1] 1.000
StressxTOP , psi 2258. 2258. 1.000
StressxBOT , psi 1731. 1731. 1.000
SOLID191 model Disp .832 .832 1.00
PRS TP 2258 2257.57 1.00
RRS BTM 1731 1730.57 1.00

UZ at Nodes 9, 19, 29

Corresponding shell TOP stresses for selected elements representing the top layer

Corresponding shell BOT stresses for selected elements representing the bottom layer

whf

我也要一份，谢谢！
whf0110@163.com

gaopeng4057

me,too!!
gaopeng2005@126.com

Tracy2007

给我也发一份吧，谢谢！
tianwei88@gmail.com

ering

虽然不清楚这是什么算例，但发现做复合材料的同行越来越多了，好事，只是都是在摸索中......

LUWEICA

真的，摸索的人越来越多啊，我也想要一份啊,谢谢啊
luweica@163.com

雨街

同问,谁能分享一下!!!

雨街

有没有人分享一下，急啊！！

WXTP

谢谢！我也是新手，也给我一份，W200123@163.COM