[新手上路]分析内六角扳手在工作状态下应力应变情况

剑不如人

!fini
/clear
!分析内六角扳手在工作状态下应力应变情况
!模拟截面高度为1cm的合金内六角扳手在使用过程中，端部受到的横向作用力，同时还收到向下的作用力
!首先受到一个横向的100牛的力，随着螺钉的紧固，在保持前一个力的同时，再加上一个20牛的垂直压力。
!正六边形截面高度：H=1cm
!手柄长度：L1=20cm
!弯角高度：L2=7.5cm
!弯角轴线半径：R=1cm
!合金杨氏弹性模量：E=3.07e11 Pa
!泊松系数：u=0.28
!横向载荷：F1=100N
!垂直载荷：F2=20N
/filname,wrench,0
/title,static analysis of an allen wrench
/prep7
et,1,solid45
et,2,plane42
mp,ex,1,3.07e11
mp,prxy,1,0.25
!创建沿中心线路径的三个关键点
rpoly,6,0.0058
k,7,,,,
k,8,,,-0.075
k,9,,0.2,-0.075
/triad,ltop
/view,1,1,1,1
/angle,1,90,xm,0
/pnum,kp,1
/pnum,line,1
gplot
l,1,4
l,7,8
l,8,9
!创建两条相交线倒角
lfillt,8,9,0.01,,
/pnum,kp,0
!绘制面
aplot
!以线切分平面
a***l,1,7,,,keep
!定义图元组合
cm,botarea,area
!选择线
lsel,s,,,1,2
lsel,a,,,6
!定义线上单元划分的密度
lesize,all,,,3,,,,,1
!选择全部
allsel,all
!定义平面单元类型和单元材料属性
type,2
mat,1
!设定平面网格的划分方式
mshkey,1
mshape,0,2d
!保存数据库
save
!六边形面上划分单元
amesh,all
!设定空间单元的单元类型和材料号
type,1
mat,1
!设定单元尺寸
esize,0.0075,0,
!绘制线
lplot
!将面沿中心线拖拉形成体
vdrag,all,,,,,,8,10,9
!绘制单元
eplot
!保存
save
!选择图元组
cmsel,s,botarea
!清除平面上的网格
aclear,all
!绘单元
eplot
save
!切换进入求解器
finish
/solu
!选择图元组的轮廓线
lsel,s,ext
!选择轮廓线上的节点
nsll,s,1
!在所有节点上施加固定约束
d,all,,0,,,,all,,,,,
!控制显示方式，使用箭头符号显示压强
/pbc,all,,1
/psf,pres,norm,2,0,1
!选择全部
allsel,all
!按位置坐标选择面
asel,s,loc,y,0.01,0.2
asel,r,loc,x,0.0058/2,0.0058
!选择面上的节点
nsla,s,1
!选择节点中相应位置段的部分
nsel,r,loc,y,0.2+25e-6,0.2-3*0.0075-25e-6
!获取节点位置数据
*get,minyval,node,,mnloc,y,,,,
*get,maxyval,node,,mxloc,y,,,,
!换算节点压强
*set,ptorq,100/(0.01*(maxyval-minyval))
!施加面载荷
sf,all,press,ptorq
!查看载荷施加结果
nplot
!选择全部
allsel,all
!设置几何非线性
nlgeom,1
!设置求解了步数
nsubst,3,0,0
!设定载荷步的终止时间
time,1
!写入第一个载荷步
lswrite,1,
!重新选择加载面
asel,s,loc,z,-(0.075+0.01/2)
!选择面上的节点
nsla,s,1
!选择一定坐标范围内的节点
nsel,r,loc,y,0.2+25e-6,0.2-3*0.0075-25e-6
!换算纵向压强
*set,pdown,20/(0.0058*(maxyval-minyval))
!施加面力载荷
sf,all,pres,pdown
!查看载荷施加结果
nplot
!选择全部
allsel,all
!设置几何非线性
nlgeom,1
!设置求解子步数
nsubst,3,0,0
!设定载荷步的终止时间
time,2
!写入第二个载荷步
lswrite,2,
save
!求解载荷步
lssolve,1,2,1,
finish
/post1
!查看载荷步信息
set,list
!选择第一个载荷步查看结果
set,,,,,,,1
!列出反作用力求解结果
prrsol,
!选择第二个载荷步查看结果
set,last
!再次列出反作用力求解结果
prrsol,
!绘制应力强度云图
plnsol,s,int,2,1
!偏移工作平面
wpoff,0,0,-0.067
!设置截面应力查看选项
/graphics,power
/type,1,5
/cplane,1
/shade,1,0
!选择工作平面视角
/view,1,wp
!绘制等高线
/device,vector,1
/replot
!设置仅仅显示截面
/type,1,1
/replot
!取消工作平面的捕获功能
wpstyl,-1
!设定路径
path,path3,2,30,20,
!选择路径起始点
ppath,1,,0,-0.0044,-0.67e-01
ppath,2,,0,0.0056,-0.67e-01
!映射路径项目
pdef,sxy,s,xy,avg
pdef,sx,s,x,avg
!绘制沿路径分布的结果
plpath,sxy,sx

摘自《使用ansys进行结构力学分析》

剑不如人

觉得这个例子挺好的，对初学者来说认真理解一下很有好处

xuqionghe

楼上，你是如何将背景设置成白色得呢？

剑不如人

plotctrls|hard copy|to file
选中reverse video即可
这只是copy成文件是才能把背景设为白色，ansys本身窗口怎样变白还没有搞懂。