- 积分
- 1
- 注册时间
- 2005-1-27
- 仿真币
-
- 最后登录
- 1970-1-1
|
发表于 2005-4-25 11:55:04
|
显示全部楼层
来自 贵州黔西南州兴义
Re:钢筋混凝土梁模拟问题?高手进!
我也做过类似例题,将我的发给你吧.
/PREP7
ET,1,SOLID65 !定义砼单元
ET,2,PIPE20 !定义管单元模拟钢筋
ET,3,PLANE42 !定义拉申实体单元
R,1,18,8.99, !定义受拉钢筋的实常数,管单元的外径为18毫米,半径为8.99毫米
R,2,8,3.99, !定义受压钢筋的实常数
r,3 !定义砼单元实常数
!材料属性
MP,EX,1,24000 !混凝土材料属性
MP,PRXY,1,0.2
TB,CONC,1,1,9,
TBdata,,0.4,1.0,3,-1,, !指定砼的抗压强度'抗拉强度及裂缝张开传递系数
!纵向受拉钢筋
MP,EX,2,2e5
MP,PRXY,2,0.3
TB,BKIN,2,1,2,1
TBdata,,350
!箍筋及受压钢筋的材料属性
MP,EX,3,2e5
MP,PRXY,3,0.25
TB,BKIN,3,1,2,1
TBdata,,200
n,1,
n,9,150,
fill,1,9
ngen,11,9,1,9,1,,30
ngen,19,1000,1,99,1,,,-75
/VIEW, 1 ,1,1,1 !三维显示
/ANG, 1
NPLOT !显示节点
type,2
real,2
mat,3
!建立箍筋单元
*do,ii,11,16,1
e,ii,ii+1
*enddo
*DO,II,83,88,1
E,II,II+1
*ENDDO
*DO,II,11,74,9
E,II,II+9
*ENDDO
*DO,II,17,80,9
E,II,II+9
*ENDDO
EGEN,19,1000,1,28,1 !复制1-28号单元19次,节点编号增量为1000
*DO,I,83,17083,1000
E,I,I+1000
E,I+6,I+1006
*ENDDO
!生成纵向受拉钢筋
type,2
real,1
mat,2
*DO,I,11,17011,1000
E,I,I+1000
E,I+6,I+1006
*ENDDO
!创建砼模型
!创建拉申面
K,1,
K,2,150
K,3,,300
K,4,150,300
A,1,2,4,3
!指定面单元的单元属性
TYPE,3
!划分面单元
LSEL,S,LINE,,2
LSEL,A,LINE,,4
CM,L1,LINE
LESIZE,L1,,,10
CMDELE,L1
LSEL,S,LINE,,1
LSEL,A,LINE,,3
CM,L2,LINE
LESIZE,L2,,,8
CMDELE,L2
AMESH,1
TYPE,1
MAT,1
REAL,3
EXTOPT,ESIZE,18 !拉伸面单元在拉伸方向上均分为18份
EXTOPT,ACLEAR,1 !清除原有面单元
VEXT,ALL,,,,,-1350 !选中所有面单元沿-Z方向生成长度为1350的体单元
!合并压缩重复节点
allsel
nummrg,all !对所有元素进行合并
numcmp,all !对元素编号进行压缩并重新排列
!施工加约束及荷载
ASEL,S,LOC,Z,0 !选择中以点坐标Z=0的所有面
DA,ALL,symm !将选择的所有对象进行对称约束
NSEL,S,LOC,Y,0 !选择Y坐标为0的所有节点
NSEL,R,LOC,Z,-1275 !在以上选择的选择里再选择Z坐标为-1275的点
D,ALL,UX,,,,,UY !约束以上选择的节点的UX,UY
NSEL,S,LOC,Y,300
NSEL,R,LOC,Z,-600
D,ALL,UY,-5 !在所选的所有节点上施工加Y方向上的位移=5
/SOLU
allsel
gplot
nlgeom,on !打开大变形开关
NSUBST,200 !指定子步数为200
OUTRES,ALL,ALL !将每个子步的所有分析内容写入数据库
NEQIT,50 !指定每个子步中的最大平衡迭代次数为50次
pred,on !激活子步预测控制
CNVTOL,F, ,0.05,2,0.5!指定非线性分析的收敛指标为力,其值为0.05;范数选项为2,软件计算依据的允许最小值为0.5
allsel
SOLVE
FINISH
/post1
allsel
/DEVICE,VECTOR,1
PLCRACK,0,1 !显示第一开裂位置
PLCRACK,0,2 !显示第二开裂位置
ESEL,S,TYPE,,2 !选择单元编号为2的所有单元
etable,saxl_i,ls,1 !定义I节点的裁面应力F/A
etable,saxl_j,ls,33
etable,s1_i,nmisc,1 !定义I节点的第一主应力
etable,s1_j,nmisc,41
plls,saxl_i,saxl_j !图形显示单元表内容
plls,s1_i,s1_j
PRETAB,SAXL_I,SAXL_J,S1_I,S1_J !列表显示单元表的内容
AVPRIN,0, , !按实际尺寸显示内容
PLNSOL,S,1,0,1 !显示第一主应力 |
|