请教各位：UPCOORD与UPGEOM两者的区别在哪里？

sskkrr

Ansys中，在分析具有初始缺陷结构稳定时，常用到UPCOORD与UPGEOM，本人不是太明白，请教两者的具体区别在哪里？各自适用什么情况比较合适？

非常感谢！

sskkrr

望各位大虾告知，感谢

sh_lin30

讨论加分!

sh_lin30

upcoord根据当前DB数据库数据更改节点坐标
upgeom根据RST结果数据文件更改节点坐标

这个两者共同的特点是可以更改节点坐标
但我们知道模型节点坐标之所以可以被更改，是由于受到载荷后，结构本身发生了变形
由此，模型此时不但结构自身发射变形，而且结构内部还存在有内部应力

因此，个人认为在使用这两个命令的时候：一方面利用其更改模型节点坐标，另一方面还应该利用初应力文件添加初始内部应力到结构相应节点；由此，进而展开下一载荷步的分析。

beel

原帖由 sh_lin30 于 2008-5-6 23:22 发表
这个两者共同的特点是可以更改节点坐标
但我们知道模型节点坐标之所以可以被更改，是由于受到载荷后，结构本身发生了变形
由 ...

施加初应力也是这个命令吗？如果我只施加位移的变化呢，该如何处理？

yuzhen

UPGEOM, FACTOR, LSTEP, SBSTEP, Fname, Ext, -- — 将分析所得的位移加到有限元模型的节点上，并更新有限元模型的几何形状。
UPCOORD, FACTOR, Key－UPGEOM命令是仅仅更新了结构的有限元模型而并不更新其计算结果文件，发出该命令后进行下一步有限元求解时ANSYS将重新计算其刚度矩阵后求解。

xyni

yuzheng
     UPGEOM, FACTOR, LSTEP, SBSTEP, Fname, Ext, -- — 将分析所得的位移加到有限元模型的节点上，并更新有限元模型的几何形状。 改变几何形状后，应力是否储存在结构中呢？

sh_lin30

这两个命令只改变节点坐标，
初应力施加另有其法

sh_lin30

命令说明中没有提示有初始应力的存在

而且，计算中也没有考虑初始应力

应该只是一个几何体的改变吧

个人看法，继续讨论

最好给个例子！

wei1012

我做了四个例子，来说明这两个命令的差别，其中还有一些问题没有弄明白，希望大家继续讨论啊。
！！！例子1，upcoord_on
/prep7  
et,1,63
r,1,.3  
rectng,0,10,0,10
lesize,all,.5
mp,ex,1,3e10
mp,prxy,1,.2
amesh,all
SFA,all,1,PRES,-100e3
allsel
/solve
nslk,s
d,all,all
allsel
solve
upcoord,1,on
SFAdele,all,all
allsel
f,all,fz,-100e3
solve
/post1
plnsol,u,z
*get,nsol,plnsol,0,min
!求出nsol=-1.08

！！！例子2，upcoord_off
/clear
!upcoord_off
/prep7  
et,1,63
r,1,.3  
rectng,0,10,0,10
lesize,all,.5   
mp,ex,1,3e10
mp,prxy,1,.2
amesh,all
SFA,all,1,PRES,-100e3
allsel
/solve
nslk,s
d,all,all
allsel
solve
upcoord,1,off
SFAdele,all,all
allsel
f,all,fz,-100e3
solve
/post1
plnsol,u,z
*get,nsol2,plnsol,0,min
！！求出nsol2为-1.08

！！！例子3，将上面两个例子更新后的节点和单元输出，重新建模，施加荷载求解
/prep7
/input,node1,txt
et,1,63
r,1,.3  
mp,ex,1,3e10
mp,prxy,1,.2
/input,elem1,txt
allsel
f,all,fz,-100e3
/solu
d,node(0,0,0),all
d,node(0,10,0),all
d,node(10,10,0),all
d,node(10,0,0),all
allsel
solve
/post1
plnsol,u,z
*get,nsol3,plnsol,0,min
!!!!nsol3=0.629

！！！例子4，upgeom
/prep7  
et,1,63
r,1,.3  
rectng,0,10,0,10
lesize,all,.5   
mp,ex,1,3e10
mp,prxy,1,.2
amesh,all
SFA,all,1,PRES,-100e3
allsel
/solve
nslk,s
d,all,all
allsel
solve
finish
/prep7
UPGEOM,1,LAST,LAST,'www','rst',' '
SFAdele,all,all
allsel
f,all,fz,-100e3
/solu
solve
/post1
plnsol,u,z
*get,nsol4,plnsol,0,min
!!!!!!nsol4=0.78

！！！例子5，将例子4更新后的节点和单元输出，重新建模，施加荷载求解
/prep7
/input,node2,txt
et,1,63
r,1,.3  
mp,ex,1,3e10
mp,prxy,1,.2
/input,elem2,txt
allsel
f,all,fz,-100e3
/solu
d,node(0,0,0),all
d,node(0,10,0),all
d,node(10,10,0),all
d,node(10,0,0),all
allsel
solve
/post1
plnsol,u,z
*get,nsol5,plnsol,0,min
!!!!nsol5=0.6294

根据这个结果大家一起来分析一下这两个命令的区别吧！

beel

说说你明白的地方吧，或者把不明白的说出来，大家讨论讨论！

sh_lin30

例子1和2，的区别体现在，Key
Key for zeroing displacements in the database:

OFF  —  Do not zero the displacements (default).

ON  —  Zero the displacements.

但在结果上好像没有体现出key的影响；upcoord修改节点坐标，key设置位置变形（效果没有体现在1、2差别）

例子3和1、2是不同的吧，单元节点位置是相同的，但是位移变形量是不同吧
就是说1、2节点单元在加载前是不是已有位移？
而3在加载前，没有变形。

例子4upgeom添加位移到节点，更新模型到变形位置，随后加载
同样，最终的变形是两次载荷引起位移之和。

例子5和例子3结果一样，应该正常吧
节点位置相同，也就是说在同样载荷sfa下，upcoord和upgeom所产生的节点坐标或位移增量，产生的模型一样
载荷相同，都是只有fz=-100e3，结果自然相同

wei1012

我一直在思考，如何简单地判断这两个命令的差别，今天我在前面的几个例子基础上又做了一个例子，就叫例子6吧。
/prep7               
et,1,63              
r,1,.3               
rectng,0,10,0,10     
lesize,all,.5        
mp,ex,1,3e10         
mp,prxy,1,.2         
amesh,all            
SFA,all,1,PRES,-100e3
f,all,fz,-100e3
allsel               
/solve               
nslk,s               
d,all,all            
allsel               
solve
/post1
plnsol,u,z
*get,nsol6,plnsol,0,min
注意此时的荷载为nsol6＝-1.08，和例子1、2是相当的吻合。

正是这个例子，我突然想明白这两个命令的区别了，下面简述如下：
1.先说upcoord的on和off的区别
从例子1和2发现激活on或off对后续的分析结果没有影响，但是他们的区别应该是在于当激活on或off，且在进行solve之前再次直接进入后处理查看上次结构的分析结果，如果是on的话那么就没有节点结果，如果是off的话还有节点结果；
2.upcoord和upgeom的区别
例子6和例子1、2相同说明upcoord只是更新了节点的坐标，再次求解时重新组装刚度矩阵；
而upgeom不仅是更新了节点的坐标，而且再次求解时刚度矩阵应该是基于现有应力刚度矩阵的前提上的，即相当于有一个拱的作用，此时平面外刚度较大，所以对于该例子而言，upgeom再次求解的时候结果小于upcoord；
后续的分析：
在这几个例子的基础上通过输出刚度矩阵来验证我的理解，希望大家多参与。

wei1012

补充上面一句：
The UPCOORD command uses displacements stored in the ANSYS database, and not those contained within the results file, Jobname.RST。
似乎可以这么理解：
upcoord后节点的坐标发生变化，但是节点的结果没有更新，即在后续的荷载步中节点结果应该包含了这个结果。
所以不论是激活on还是off，结果都是1.08，同例子六是一样的。

cmca

UPGEOM，在使用前次计算结果更新后，节点的坐标和上次计算的应力都被导入。
UPGEOM后你可以不计算直接到后处理可以看到应力。

cxhhaimen

对于13# 中1upcoord的on和off的区别，如果是on的话那么就没有节点结果。这个表述有问题。应该改为，如果是on的话没有节点的位移结果，其他结果，例如应力结果还是有的。

yjf711

转贴，仅供参考

upcoord更新节点坐标时使用的位移是静力求解下的位移，upgeom更新节点坐标时使用的是线性稳定分析的模态的位移，所以施加初始缺陷时应该用upgeom，但是要指定子步，因为它默认使用的是最后一个失稳模态的。使用这两个命令后查看一下节点的坐标，跟初始的节点坐标做个对比很容易就会发现这两个命令的区别的。

zhengshufei

下面是我的工作，我做了2个算例，其中一个是用初始应力来实现应力的叠加，用upgeom命令来实现节点坐标的更新；另一个算例是只用pgeom命令来实现节点坐标的更新，看看能否实现应力的叠加。
计算的结果发现：只用pgeom命令是不能实现应力的叠加的，也就是前步计算的应力不能作为初始应力来叠加到后续的计算。
命令流如下：


算例1：用初始应力把上一步的求解应力结果作为初始应力加到后续计算上。用upgeom命令更新节点坐标

/PREP7  
ET,1,plane42

MP,EX,1,1e10   
MP,PRXY,1,0.25
MP,DENS,1,2500
TB,BISO,1,1,2,  
TBTEMP,0
TBDATA,,200e6,3.3e9,,,,  

rectng,0,5,0,2

esize,0.1
amesh,all
FINISH

/SOL
iswrite,1
nlgeom,on
acel,0,9.8,0
lsel,,line,,4
dl,all,,all
allsel,all
lsel,,line,,1
dl,all,,uy
allsel,all
lsel,,line,,2
dl,all,,ux,-0.5
allsel,all
SOLVE   
FINISH

/prep7
upgeom,1,,,test,rst
finish

/SOL
ISFILE,READ,test,ist, ,1
nlgeom,on
lsel,,line,,4
dl,all,,all
allsel,all
lsel,,line,,1
dl,all,,uy
allsel,all
lsel,,line,,2
dl,all,,ux,-0.5
allsel,all
SOLVE   
FINISH

/prep7
upgeom,1,,,test,rst
finish

算例2：只用upgeom命令更新节点坐标，看看能否实现应力的叠加

/PREP7  
ET,1,plane42

MP,EX,1,1e10   
MP,PRXY,1,0.25
MP,DENS,1,2500
TB,BISO,1,1,2,  
TBTEMP,0
TBDATA,,200e6,3.3e9,,,,  

rectng,0,5,0,2

esize,0.1
amesh,all
FINISH

/SOL
nlgeom,on
acel,0,9.8,0
lsel,,line,,4
dl,all,,all
allsel,all
lsel,,line,,1
dl,all,,uy
allsel,all
lsel,,line,,2
dl,all,,ux,-0.5
allsel,all
SOLVE   
FINISH

/prep7
upgeom,1,,,test,rst
finish

/SOL
nlgeom,on
lsel,,line,,4
dl,all,,all
allsel,all
lsel,,line,,1
dl,all,,uy
allsel,all
lsel,,line,,2
dl,all,,ux,-0.5
allsel,all
SOLVE   
FINISH

/prep7
upgeom,1,,,test,rst
finish

singyun

原帖由 xyni 于 2008-5-13 13:40 发表
yuzheng
     UPGEOM, FACTOR, LSTEP, SBSTEP, Fname, Ext, -- — 将分析所得的位移加到有限元模型的节点上，并更新有限元模型的几何形状。 改变几何形状后，应力是否储存在结构中呢？

根据下面的例子4，在执行UPGEOM命令之后去后处理查看节点结果：
1、节点的坐标改变了
2、节点有位移，即UPGEOM之前的位移结果
3、节点无应力，
即执行UPGEOM后，重新生产有限元模型，无应力，但节点是有位移的

singyun

和同学一块讨论，来了个总结，不知道能否这样下结论：
UPCOORD命令（不论on或off）执行之后：

1、节点坐标更新，这个无容置疑

2、保留上一步计算结果的应力状态，相当于有预应力，

     这个可以查看例子1、2在UPCOORD之后的后处理的节点应力状态，但节点没有位移结果了。

3、由例子1、2和例子6比较，例子1、2中两个载荷的加载是在UPCOORD前后，

     但计算结果与例子6同时加载相同，而例子6没有执行UPCOORD命令，由此可以说明UPCOORD命令

     不改变结构的刚度矩阵



UPGEOM命令执行后：

1、节点坐标更新

2、抛弃上一步计算结果的应力状态， 这个可以查看例子4在UPGEOM之后的后处理的节点应力状态，

     但节点的位移结果依然存在。

3、由例子4和例子6比较，计算结果不同，由于载荷相同，可以说明UPGEOM后刚度矩阵改变了