【讨论】网壳自振频率计算

zhouqian1

双层柱面网壳，为何模态分析中自振频率为8hz?
正确的结果为2.8hz.
希望诸位大侠指点，小弟不胜感激！！！！！
  
/prep7
local,11,1
cscir,11,1
f=8.892
h=2
r=(f*f+380.25)/(2*f)
b=(atan((380.25-f*f)/(39*f)))*180/3.14159
n,1,r,b
n,14,r,180-b
fill,1,14
/view,1,1,1,1
/ang,1
/rep,fast
local,11,
ngen,22,14,1,14,1,,,3
local,11,1
n,309,r-h,(90+12*b)/13,1.5
ngen,13,1,309,309,,,(180-2*b)/13
local,11
ngen,21,13,309,321,1,,,3
et,1,link8
mp,ex,1,2.06e11
mp,dens,1,7890
mp,nuxy,1,0.3
MP,DAMP,1,0.02
r,1,703e-6
type,1
mat,1
real,1
*do,i,1,14,1
e,i,i+14
*enddo
egen,21,14,1,14,1
*do,i,1,13,1
e,i,i+1
*enddo
egen,22,14,295,307,1
r,2,543e-6
type,1
mat,1
real,2
*do,i,309,321,1
e,i,i+13
*enddo
egen,20,13,581,593,1
*do,i,309,320,1
e,i,i+1
*enddo
egen,21,13,841,852,1
r,3,433e-6
type,1
mat,1
real,3
nx=13
ny=21
nnup=308
*do,i,1,ny
*do,j,1,nx
k1=(i-1)*nx+j+nnup
k2=k1-nnup+i-1
e,k1,k2
e,k1,k2+1
e,k1,k2+nx+1
e,k1,k2+nx+2
*enddo
*enddo
allsel,all
acel,,9.82
local,11,1
nsel,s,loc,x,r
local,11
f,all,fy,-1000
local,11,1
nsel,s,loc,z,0
nsel,a,loc,z,63
nsel,a,loc,y,b
nsel,a,loc,y,180-b
local,11
f,all,fy,-500
/REP
local,11,1
nsel,s,loc,x,r-h
local,11
f,all,fy,-500
local,11,1
nsel,s,loc,z,1.5
nsel,a,loc,z,61.5
nsel,a,loc,y,(90+12*b)/13
nsel,a,loc,y,(2250-12*b)/13
local,11,
f,all,fy,-250
allsel,all
GPLOT                 !进行总绘图
/PBC,ALL, ,1          !显示边界条件及值
/rep
/solu
nsel,s,node,,2,13,1
nsel,a,node,,296,307,1
d,all,uy,0
nsel,all
d,1,all,,,14,13
d,295,all,,,308,13
nsel,s,node,,1,295,14
local,11,1
nsel,a,loc,y,180-b
d,all,ux,0
d,all,uy,0
d,all,uz,0
allsel
fini

curtain

看了一下,没什么问题啊>

zhouqian1

普通网架和网壳的自振频率为0.3-3hz之间。
下面这两个命令流，大家可能熟悉不过了
1、!-------------------------------------------------------------  
!典型六角星型穹顶非线性全过程分析  
!可参考 沈世钊等著,《网壳结构稳定性》,科学出版社,1999,P39~P41  
!此例可查看子步及弧长法之作用  
!可分别打开与关闭弧长法进行计算  
!-------------------------------------------------------------  
!建立几何模型，定义几个关键点，并利用复制命令；  
!线采用直接生成，没有采用拷贝等命令  
/prep7  
csys,1  
k,1,500,30  
kgen,6,1,1,,,60  
k,7,250,,62.16  
kgen,6,7,7,,,60  
k,13,,,82.16  
csys,0  
*do,i,1,5,1  
l,i,i+6  
l,i,i+7  
*enddo  
l,6,7  
l,6,12  
*do,i,7,11,1  
l,i,i+1  
*enddo  
l,12,7  
*do,i,7,12,1  
l,i,13  
*enddo  
/view,1,1,1,1  
/ang,1,-150,xs,1  
gplot  
!------------------------------  
!定义单元类型、实常数及材料性质  
!每根线为一个单元  
!------------------------------  
et,1,link8  
r,1,317  
mp,ex,1,3030.0  
mp,prxy,1,1096/3030  
lesize,all,,1  
lmesh,all  
finish  
!======================================  
!这里插入了静力及特征值屈曲分析,当然可不进行了！  
!/solu  
!*do,i,1,6,1  
!dk,i,all  
!*enddo  
!fk,13,fz,-100.0  
!pstres,on  
!solve  
!finish  
!/solu  
  
按照这个算例建立的模型进行模态分析时，其自振频率为2.8hz，原则上是对的，但是，link8一般为钢结构材料，其弹模应该为10e5（n/mm2）级别，也就是说，作者的弹模选择是不是有失误？(3030)，我的弹模取
2.06e5级别，如果把我的弹模值带入该算例，则得出的自振频率也为8hz,请诸位大虾分析一下原因在哪里；
2、!昨天设计一个平板网架，正放四角锥，一时之间找不到软件，所以只好用ANSYS的A  
!DPL写了一个程序  
!    功能：  
!    1.方便的进行正方四角锥网架的建模  
!    2.可以自动选杆件截面  
!    计算中假设杆件均为铰接，压杆采用钢结构设计规范GBJ17-88的a曲线验算  
!    注：本文纯属个人资料，如采用本文进行网架设计出现问题，概不负责  
/prep7  
!-------------------------------------------  
!定义截面类型（共6种钢管）  
*dim,DOUT,,6 !外径  
*dim,DIN,,6 !内径  
DOUT(1)=45 !管45X4  
DIN(1)=37  
DOUT(2)=63 !管63X4  
DIN(2)=55  
DOUT(3)=89 !管89X5  
DIN(3)=79  
DOUT(4)=113 !管113X6  
DIN(4)=101  
DOUT(5)=140 !管140X6  
DIN(5)=128  
DOUT(6)=159 !管159X8  
DIN(6)=143  
*dim,AREA,,6 !截面积  
*dim,RI,,6 !回转半径  
*do,i,1,6  
AREA(i)=3.1415926*(DOUT(i)*DOUT(i)-DIN(i)*DIN(i))/4  
RI(i)=0.25*sqrt((DOUT(i)*DOUT(i)+DIN(i)*DIN(i)))  
*enddo  
!------------------------------------------  
!结构基本参数输入  
DX=2000 !横向网格尺寸  
DY=2000 !纵向网格尺寸  
DZ=2000 !网架截面高度  
NX=30 !横向网格数量  
NY=28 !纵向网格数量  
DLOAD=1.06e-3 !屋面均布荷载设计值  
FD=215 !钢材强度设计值  
FY=235 ! 植 屈服强度  
RATIO1=0.85 !应力比上限  
RATIO2=0.7 !应力比下限  
EE=2.06e5 !弹性模量  
NEALL=8*NX*NY !单元总数  
!------------------------------------------  
!定义实常数  
*do,i,1,6  
r,i,AREA(i)  
*enddo  
!------------------------------------------  
!定义单元类型-杆单元  
ET,1,LINK8  
!-----------------------------------------------------  
!定义材料特性  
MP, EX, 1, EE !钢材  
MP, NUXY, 1, 0.3  
MP, DENS, 1, 7.85e-6  
!------------------------------------------  
!节点定义  
!上弦节点  
*do,i,1,NY+1  
*do,j,1,NX+1  
k=(i-1)*(NX+1)+j  
n,k,(j-1)*DX,(i-1)*DY  
*enddo  
*enddo  
NNUP=k !记录上弦节点总数  
!下弦节点  
*do,i,1,NY  
*do,j,1,NX  
k=(i-1)*NX+j+NNUP  
n,k,(j-1)*DX+DX/2,(i-1)*DY+DY/2,-DZ  
*enddo  
*enddo  
NNALL=k !记录节点总数  
NNBOT=NNALL-NNUP !记录下弦节点总数  
!------------------------------------------  
!单元定义，最初定义为1号截面  
!横向上弦杆件  
NEUP1=0 !记录横向上弦杆件总数  
*do,i,1,NY+1  
*do,j,1,NX  
k=(i-1)*(NX+1)+j  
e,k,k+1  
NEUP1=NEUP1+1  
*enddo  
*enddo  
!纵向上弦杆件  
NEUP2=0 !记录纵向上弦杆件总数  
*do,i,1,NY  
*do,j,1,NX+1  
k=(i-1)*(NX+1)+j  
e,k,k+NX+1  
NEUP2=NEUP2+1  
*enddo  
*enddo  
!横向下弦杆件  
NEBOT1=0 !记录横向下弦杆件总数  
*do,i,1,NY  
*do,j,1,NX-1  
k=(i-1)*NX+j+NNUP  
e,k,k+1  
NEBOT1=NEBOT1+1  
*enddo  
*enddo  
!纵向下弦杆件  
NEBOT2=0 !记录纵向下弦杆件总数  
*do,i,1,NY-1  
*do,j,1,NX  
k=(i-1)*NX+j+NNUP  
e,k,k+NX  
NEBOT2=NEBOT2+1  
*enddo  
*enddo  
!斜腹杆  
NEMID=0 !记录纵向下弦杆件总数  
*do,i,1,NY  
*do,j,1,NX  
k1=(i-1)*NX+j+NNUP  
k2=k1-NNUP+(i-1)  
e,k1,k2  
e,k1,k2+1  
e,k1,k2+NX+1  
e,k1,k2+NX+2  
NEMID=NEMID+4  
*enddo  
*enddo  
!------------------------------------------  
!施加节点约束  
!这一步宜在GUI界面中进行,然后将边界条件写入文件load1.txt  
/input,load1,txt  
!------------------------------------------  
!施加节点约束  
!这一步宜在GUI界面中进行,然后将边界条件写入文件boundary.txt  
/input,boundary,txt  
!------------------------------------------  
!求解  
/solu  
solve  
  
这是同济大学郭小农同学用adpl语言写的双层网架的设计程序，不知道有没有人提出过怀疑，我算了一下网架的自振频率，其值为0.26hz，也就是说，这是不正常的网架。奇怪的是，当我把我的单位制和郭同学的单位制统一时，我算出的我的双层柱壳自振频率为0.2hz!不知道原因在哪里，请诸位大虾帮忙找一下；
  
3、我估计本论坛的成员中肯定有用ansys做空间结构的，我有一个问题，即lin8模拟杆件时，对于空间结构，杆件按以上三个程序的连接形式是不是默认铰接？另外，有没有同仁用ansys算过空间结构而且基频在0.3-3hz的；希望能提出良好建议；
  
4、附上我的网壳建模资料：BXL:39*63m;
f/B:0.228
h:2m
杆件规格：上弦：114*4
          下弦：88.5*4
          腹杆：75.5*3.75
  
e=2.06e11n/m2
密度：7890kg/m3
网格布置为正放四角锥，支座考虑为两纵边上弦节点铰支，两端部上弦节点设竖向约束。
  
5、以上是本人课题，实在没办法了，才向各位求助。希望能得到答复，不胜感激！！！！！！

curtain

看了你的贴子,很好的命令流,尤其是文档做的很好,看样子经常写程序哦.
偶觉得做网架的频响问题要无非是先做出架子,然后加好约束并定义好材料就可以了.你的贴子说你采用别人的命令流文件换成你的材料得到的结果是合理的,那偶就搞不懂你为什么怀疑自己的结果了,仅仅是因为频率不在0.3~3hz之间?

curtain

另外,link8本身就可以用做珩架单元,每个节点3个自由度,也就是说单元与单元之间为绞接