[共建]＜ANSYS命令流实例库＞敬请您的加盟

fpemail

目标：建立一个集结构静力分析、结构动力学分析、结构非线性分析、动力学分析、热分析、电磁场分析、计算流体动力学分析、声场分析、压力分析、多物理场耦合分析、优化设计、拓扑优化、单元生死、可扩展功能（UPF）等多学科、全方位、完善的ANSYS命令流库。
本人想法：在学习与应用ANSYS一年多的工作中，最苦脑的事情一是无人交流、二是找不到实例学习。如今在网上发现了仿真论坛，就好像拜了名师一样让我兴奋不止。但在一个月的帖贴生活中感觉到对于工程软件仅靠在BBS上帖几个贴子学习，不但不系统，而且问题零散。所以想起借仿真论坛为ANSYS使用学习者建造一个＜ANSYS命令流实例库＞，这样即可以有实例供大家学习讨论，又可以建立一个论坛自己的数据库。
要求：1、注明命令流属于何种功能分析（写在标题处）；
　　　2、注明基本问题描述（最好附图）；
　　　3、命令流经发贴人调试合格后帖入；
　　　4、希望能在命令流中加入注释；
　　　5、如果是原创，请在后面标明＜原创＞字样；
　　　6、对在其它软件中建立的复杂模型，请把接口文件传上来；
　　　7、命令流有疑问的地方请用红字标示；
　　本贴意在抛砖引玉，希望能得到站长的支持。希望斑竹能制止灌水现象并为原创作者和积极提供实例者加分。希望广大ANSYS学习使用者能抽出一点宝贵时间对自己的成果做个小总结，供大家交流学习。谢谢！
　　:I 希望大家能多提意见！多多帮助！

[ 本帖最后由 fpemail 于 2006-5-12 06:25 编辑 ]

fpemail

/PREP7                 !进入前处理器
ET,1,BEAM3             !定义单元类型
R,1,0.25,0.0052,0.5　　!定义实常数
MP,EX,1,210E6
MP,PRXY,1,0.3　　　　　!定义材料属性
N,1,0
N,2,1
N,3,5
N,4,7
N,5,7
N,6,9
N,7,11
N,8,11
N,9,13
N,10,14　　　　　　　　!定义节点
E,1,2
E,2,3
E,3,4
E,5,6
E,6,7
E,8,9
E,9,10　　　　　　　　 !生成单元
CP,1,UX,4,5
CP,2,UY,4,5
CP,3,UX,7,8
CP,4,UY,7,8　　　　　　!耦合节点
FINISH
/SOLU　　　　　　　　　!进入求解器
D,2,UX
D,2,UY
D,3,UY
D,6,UY
D,9,UY　　　　　　　　 !施加位移约束
F,10,FY,-4　　　　　　　!施加集中约束
SFBEAM,1,1,PRES,4,4
SFBEAM,2,1,PRES,4,4　　　!施加均布力
SOLVE　　　　　　　　　!求解
/POST1　　　　　　　　　!进入后处理器
PLDISP　　　　　　　　　!绘制结构变形图
PRDISP　　　　　　　　　!列出各节点的位移
ETABLE,IMOMENT,SMISC,6
ETABLE,JMOMENT,SMISC,12
ETABLE,ISHEAR,SMISC,2
ETABLE,JSHEAR,SMISC,8　　　!将节点弯矩、剪力制表
PRETAB　　　　　　　　　　　!列表显示单元的弯矩、剪力
/TITLE,SHEAR FORCE DISTRIBUTION　　　　　!设置剪力分布图的标题
PLLS,ISHEAR,JSHEAR　　　　　　　　　　　　!绘制剪力分布图
/TITLE,BENDING MOMENT IDSTRIBUTION　　　　!设置弯矩分布图的标题
PLLS,IMOMENT,JMOMENT　　　　　　　　　　　!绘制弯矩分布图

fpemail

RAD=0.8  !底面半径
H=1
G=9.8
OMEGAR=2
ROU=1000　　　!定义参数变量
/PREP7　　　　!进入前处理器
ET,1,FLUID79    !选择单元类型
KEYOPT,1,3,1　　!设置单元关键字
MP,EX,1,2E9　　　　!设置杨氏模量
MP,DENS,1,ROU　　　　!设置材料密度
K,1
K,2,RAD
K,3,RAD,H
K,4,,H　　　　　　　!生成关键点
A,1,2,3,4　　　　　　!连接关键点生成面积
LESIZE,ALL,,,10　　　!设置网格划分精度
AMESH,ALL　　　　!将面积划分网络
/SOLU　　　　　　!进入求解器
DL,2,,UX
DL,1,,UY
NSEL,S,LOC,X
DSYM,SYMM,X
D,ALL,UX
NSEL,ALL　　　　!施加位移约束
ACEL,,G
OMEGA,,OMEGAR　　　!施加惯性力
SOLVE　　　　　　　　!求解
/POST1
SET,LAST　　　　　　!进入通用后处理器
PLNSOL,U,X,0,1　　　!绘制应力云图
UCENT=UY(22)
UEDGE=UY(12)
UELEV=UEDGE-UCENT　!提取节点位移

mix

LESEZE,ALL,,,10　　　!设置网格划分精度
这句应该改为
LESIZE,ALL,,,10　　　!设置网格划分精度
最后三句的结果值怎么看？？
这个看的好像是两侧边的Y值

fpemail

/PREP7 !进入前处理器
ET,1,LINK1　　　!选择单元
R,1,0.1　　　!定义实常数
MP,EX,1,30E6
MP,PRXY,1,0.3　　　!定义材料属性
N,1,0
N,2,4
N,3,8
N,4,12
N,5,0,3
N,6,4,3
N,7,8,3　　　　　　!生成节点
E,1,2
E,2,3
E,3,4
E,4,7
E,3,7
E,2,7
E,2,6
E,2,5
E,1,5
E,5,6
E,6,7　　　　　　!生成单元
FINISH
/SOLU　　　　　!进入求解器
D,1,UX
D,1,UY
D,5,UX　　　　　!实加位移约束
F,2,FY,-15
F,3,FY,-15
F,4,FY,-15　　　　　!施加集中力
SOLVE　　　　　　!求解
/POST1　　　　　!进入能用后处理器
PRESOL,FORC　　　　!列表显示反力

fpemail

LENGTH=100
YOUNG=200000
THICKNESS=2
FORCE=1000
DENSITY=9E-6   !将材质、载荷、板的几何尺寸等参数化
/PREP7　　　　　!进入前处理器
MP,EX,1,YOUNG
MP,NUXY,1,0.3
MP,DENS,1,DENSITY　　　!定义材质
ET,1,SHELL63　　　　　!定义单元类型
R,1,THICKNESS,THICKNESS,THICKNESS,THICKNESS　　!定义实常数
!构建结构的几何模型
K,1,0,0
K,2,LENGTH,0
K,3,LENGTH,LENGTH
K,4,0,LENGTH　　　!定义关键点
A,1,2,3,4　　　　!通过关键点生成面
LSEL,ALL
LESIZE,ALL,,,16
AMESH,ALL　　　　　!设定网格划分参数，划分网格
FINISH
/SOLU　　　　!进入求解器
NSEL,S,LOC,X,0,0
D,ALL,ALL,0　　　　　!选择X＝0的节点将其固定
NSEL,S,LOC,X,LENGTH,LENGTH
D,ALL,ALL,0　　　　　!选择X＝LENGTH的节点将其固定
NSEL,S,LOC,X,0.5*LENGTH,0.5*LENGTH
NSEL,R,LOC,Y,0.5*LENGTH,0.5*LENGTH
F,ALL,FZ,FORCE
ALLSEL　　　　　　　　!捕捉板的中心点并在中心点处施加集中力荷载
SOLVE　　　!求解
FINISH
/POST1　　　!进入后处理器
/DSC,,10
PLNSOL,U,Z,0,1   !绘图显示板的竖向变形
NSEL,ALL　　　　　!提取板的最大竖向变形
NSORT,U,Z,1,1　　　!将节点的位移绝对值以升序排序
*GET,MAXDEFLECTION,SORT,0,MAX　　!提取位移最大值并赋给变量
NSEL,S,LOC,X,0
NSEL,A,LOC,X,LENGTH,LENGTH　　　!选择固定边节点
NSORT,S,EQV,1,1  　　　　　　　!将节点等效应力的绝对值以升序排序
*GET,MAXSTRESS,SORT,0,MAX　　　!提取等效应力最大值并赋给变量

fpemail

fini
/cle
/prep7
*afun,deg
n_beam=20
start_ang=0
end_ang=360
length=1
amplitude=5

*do,iter,1,n_beam+1
tmp=start_ang+((iter-1)*(end_ang-start_ang)/n_beam)
n,iter,iter-1*(length/n_beam),amplitude*cos(tmp)
*enddo
et,1,4
r,1,10 !beam area
*do,iter,1,n_beam
e,iter,iter+1
*enddo

fpemail

在实际工程中，特别是土木结构，常会遇到这一类的问题。
要合理的施加这类载荷，必须灵活应用APDL所提供的嵌入函数。
对于管、梁单元上所作用的风载荷，可以这样处理：
1、获得相应管、梁单元迎风面的投影长度，结合单元实常数即可得到投影面积；
2、继而将风载荷简化作用到节点上去。

pa=100 ! X方向风载荷面集度
*afun,deg

*do,i,1,20,1
esel,s,ename,,pipe16
*if,esel(i ),eq,1,them!注意：前面的条件i后面没有空格
esel,,,,i,
*get,nreal,elem,i,attr,real
*get,d,rcon,nreal,const,1, !获得单元实常数
n1=nelem(i,1)
n2=nelem(i,2) !节点座标
length=distnd(n1,n2) !单元长度
dx=abs(nx(n1)-nx(n2))
theta=acos(dx/length) !计算单元与X轴夹角
fnode=0.5*pa*length*d*sin(theta) !面载荷等效简化为节点载荷
f,n1,fx,fnode
f,n2,fx,fnode
*else
n1=0
n2=0
*endif
*enddo

fpemail

/PREP7!进入前处理器
MP,EX,1,30E6
MP,PRXY,,0.3!定义材料属性
ET,1,BEAM54!选择单元
R,1,23,44,2.5,2.5
RMODIF,1,16,1515.15!定义实常数
N,1
N,14,286
FILL　　　　!生成节点
E,1,2
EGEN,13,1,1!生成单元
D,1,UX
F,1,FY,-1000
F,1,MZ,10000!施加边界条件
OUTPR,,1
FINISH
/SOLU
SOLVE
*GET,UY,NODE,1,U,Y!提取节点位移
*STATUS,PARM　　!列表显示结果

fpemail

mix wrote:
LESEZE,ALL,,,10　　　!设置网格划分精度
这句应该改为
LESIZE,ALL,,,10　　　!设置网格划分精度
最后三句的结果值怎么看？？
这个看的好像是两侧边的Y值

UCENT=UY(22)　　　
UEDGE=UY(12)
UELEV=UEDGE-UCENT
uy()是在线取值函数！和＊get一样！你可以看看相关的材料！

fpemail

/prep7!进入前处理
et,1,shell99,,,,,2,4!选择单元
r,1,4,1
rmore
rmore,1,,0.5,1,,0.5!定义实常数
mp,ex,1,30e6
mp,nuxy,1,0!定义材料属性
tb,fail,1
tbtemp,,crit!定义材料模型
tbdata,1,0,0,1
tbtemp,0
tbdata,10,25000
tbdata,12,3000
tbdata,14,5000
tbdata,16,500!使用TSAI－WU失效准则
n,1
n,3,,1
fill
ngen,11,3,1,3,1,1!生成节点
e,1,7,9,3,4,8,6,2
egen,5,6,-1!生成单元
nsel,s,loc,x
d,all,all!施加DOF
nsel,s,loc,x,10
cp,1,uz,all!定义耦合
nsel,r,loc,y
f,all,fz,10000!施加集中力
nsel,all
outpr,,1!设置求解输出
finish
/solu
solve
finish
/post1
etable,nx,smisc,7
etable,fc,nmisc,1
etable,fcmx,nmisc,2
etable,fcln,nmisc,3
etable,ilmx,nmisc,4
etable,illn,nmisc,5
!定义表格
pretab,nx,illn,ilmx
pretab,fc,fcln,fcmx!列表显示表格内容
etable,sxz,s,xz
etable,ilsxz,smisc,11!定义表格
*get,sigxz1,elem,4,etab,sxz
*get,sigxz2,elem,1,etab,ilsxz
*get,sigxz3,elem,1,etab,ilmx
*get,fc3,elem,1,etab,fcmx!从表格中提取结果

希望大家多提意见！谢谢！

szg_1999_1999

/PREP7
/TITLE,THE ANALYSIS OF A REINFORCED CONCRETE BEAM
ANTYPE,STATIC
ET,1,SOLID65,,,,,2
ET,2,LINK8
ET,3,PIPE16,,,,,,,1
R,1
R,2,0.0006
R,3,1,0.5
MP,EX,1,3E10
MP,NUXY,1,0
TB,CONCR,1
TBDATA,3,0.0,-1
MP,EX,2,2.1E11
MP,NUXY,2,0.3
N,1
N,2,0.05
NGEN,9,2,1,2,1,,0.05
NGEN,2,18,1,18,1,,,0.2
E,1,2,4,3,19,20,22,21
TYPE,3
REAL,3
E,4,2
E,22,20
EGEN,8,2,1,3
TYPE,2
MAT,2
REAL,2
E,1,2
E,19,20
CE,1,, 2,UX,-1,10,UX,1,10,ROTZ,0.2
CE,2,,20,UX,-1,28,UX,1,28,ROTZ,0.2
CE,3,,18,UX,-1,10,UX,1,10,ROTZ,-0.2
CE,4,,36,UX,-1,28,UX,1,28,ROTZ,-0.2
CE,5,, 4,UX,-1,10,UX,1,10,ROTZ,0.15
CE,6,,22,UX,-1,28,UX,1,28,ROTZ,0.15
CE,7,,16,UX,-1,10,UX,1,10,ROTZ,-0.15
CE,8,,34,UX,-1,28,UX,1,28,ROTZ,-0.15
CE,9,, 6,UX,-1,10,UX,1,10,ROTZ,0.1
CE,10,,24,UX,-1,28,UX,1,28,ROTZ,0.1
CE,11,,14,UX,-1,10,UX,1,10,ROTZ,-0.1
CE,12,,32,UX,-1,28,UX,1,28,ROTZ,-0.1
CE,13,, 8,UX,-1,10,UX,1,10,ROTZ,0.05
CE,14,,26,UX,-1,28,UX,1,28,ROTZ,0.05
CE,15,,12,UX,-1,10,UX,1,10,ROTZ,-0.05
CE,16,,30,UX,-1,28,UX,1,28,ROTZ,-0.05
NSEL,S,LOC,X
D,ALL,ALL
NSEL,ALL
D,ALL,ROTY
D,ALL,ROTX
F,10,MZ,400,,28,18
/SOLU
AUTOTS,ON
NSUBST,10
OUTPR,,LAST
SOLVE
混凝土受弯的例题

河砂

!本文件计算成桥3年后恒荷载+活荷载工况1作用下的结构
/prep7
!--------------------------------------------------------------
ET,1,SOLID187   !定义单元类型,采用10节点四面体单元
!混凝土C40
MP,EX,1,3.25e4
MP,NUXY,1,0.2
MP,DENS,1,2.5e-6
!钢材
MP,EX,2,2.06e5
MP,NUXY,2,0.3
MP,DENS,2,7.85e-6
!--------------------------------------------------------------
!下面开始实体建模
!--------------------------------------------------------------
!桩承台
k,1,0,    0,0
k,2,11000,0,0
k,3,11000, 3500,0
k,4,    0, 3500,0
k,5,0,    0,2000
k,6,11000,0,2000
k,7,11000, 3500,2000
k,8,    0, 3500,2000
V,1,2,3,4,5,6,7,8
k,15,1000 ,0,3000
k,16,10000,0,3000
k,17,10000, 2500,3000
k,18,1000 , 2500,3000
V,5,6,7,8,15,16,17,18
k,21,3200 ,0   , 3000
k,22,6850 ,0   , 3000
k,23,6850 ,0   ,10920
k,24,3200 ,0   ,10920
k,25,3200 ,1500, 3000
k,26,6850 ,1500, 3000
k,27,6850 ,1100,10920
k,28,3200 ,1100,10920
V,21,22,23,24,25,26,27,28
!--------------------------------------------------------------
!主杆牛腿以下部分
k,31,4200 ,0   , 3000
k,32,4200 ,0   , 9120
k,33,4200 ,1500, 9120
k,34,4200 ,1500, 3000
A,31,32,33,34
k,35,3200 ,0   ,10320
k,36,3200 ,1500,10320
A,32,33,36,35
k,41,5592 ,0   , 6220
k,42,5200 ,0   ,10920
k,43,5592 ,1500, 6200
k,44,5200 ,1500,10920
A,41,42,44,43
k,45,6850 ,0   , 5065
k,46,6850 ,1500, 5065
L,45,46
LARC,41,45,23,1260,
LARC,43,46,27,1260,
AL,43,45,44,46
ASEL,,,,18,21
V***A,3,all
ALLSEL,ALL
VDELE,4
VDELE,5
NUMCMP,VOLU
!--------------------------------------------------------------
!主杆牛腿以上部分
k,51,4200 ,0    ,10920
k,52,5200 ,0    ,10920
k,53,5200 ,0    ,26600
k,54,4200 ,0    ,26600
k,55,4200 ,1100 ,10920
k,56,5200 ,1100 ,10920
k,57,5200 ,1100 ,26600
k,58,4200 ,1100 ,26600
V,51,52,53,54,55,56,57,58
!--------------------------------------------------------------
!附杆牛腿以上部分
k,61,5200 ,0    ,10920
k,62,9050 ,0    ,10920
k,63,9050 ,0    ,28000
k,64,5200 ,0    ,28000
k,65,5200 ,400  ,10920
k,66,9050 ,400  ,10920
k,67,9050 ,400  ,28000
k,68,5200 ,400  ,28000
V,61,62,63,64,65,66,67,68
k,69,5700 ,0    ,28000
k,70,5700 ,400  ,28000
L,69,70
k,71,6798.82,0,25000
k,72,6798.82,400,25000
L,71,72
LARC,69,71,61,45566,
LARC,70,72,65,45566,
AL,79,81,80,82
k,73,8122.9,0,20000
k,74,8122.9,400,20000
L,73,74
LARC,71,73,61,45566,
LARC,72,74,65,45566,
AL,80,84,83,85
k,75,8861.8,0,15000
k,76,8861.8,400,15000
L,75,76
LARC,73,75,61,45566,
LARC,74,76,65,45566,
AL,83,87,86,88
LARC,75,62,61,45566,
LARC,76,66,65,45566,
AL,86,89,46,90
k,81,8300,0,10920
k,82,8300,400,10920
k,83,8108.6,0,15000
k,84,8108.6,400,15000
L,81,82
LARC,81,83,61,44086
L,83,84
LARC,82,84,65,44086
AL,91,92,93,94
k,85,7357.1,0,20000
k,86,7357.1,400,20000
L,85,86
LARC,83,85,61,44086
LARC,84,86,65,44086
AL,93,96,95,97
k,87,6374.2,0,23850
k,88,6374.2,400,23850
L,87,88
LARC,85,87,61,44086
LARC,86,88,65,44086
AL,95,98,99,100
k,89,5200,0,23675
k,90,5200,400,23675
L,89,90
LARC,87,89,61,600
LARC,88,90,65,600
AL,98,101,102,103
ASEL,,,,42,49
V***A,5,all
ALLSEL,ALL
VDELE,6
VDELE,7
NUMCMP,VOLU
ALLSEL,ALL
!--------------------------------------------------------------
!附杆牛腿以下部分
k,101,6850,0,3000
k,102,9050,0,3000
k,103,9050,0,10920
k,104,6850,0,10920
k,105,6850,400,3000
k,106,9050,400,3000
k,107,9050,400,10920
k,108,6850,400,10920
V,101,102,103,104,105,106,107,108
k,201,6850,0,5065
k,202,8106.4,0,6272.2
k,203,8300,0,10920
k,204,6850,800,5065
k,205,8106.4,800,6272.2
k,206,8300,800,10920
k,207,6850,0,6320
k,208,6850,800,6320
NUMCMP,LINE
L,201,204
L,202,205
L,203,206
LARC,201,202,207,1260
L,202,203
LARC,204,205,208,1260
L,205,206
NUMCMP,AREA
AL,122,127,123,125
AL,123,128,124,126
ASEL,,,,63,64
V***A,6,all
VDELE,7
NUMCMP,AREA
NUMCMP,LINE
k,301,6850,700,3000
k,302,6850,700,5065
k,303,7150,400,3000
k,304,7150,400,5101.8
k,305,6850,400,3000
k,306,6850,400,5065
V,301,303,305,302,304,306
ALLSEL,ALL
VPLOT
!--------------------------------------------------------------
!钢索垫
k,401,4200,0,28000
k,402,4200,0,26600
k,403,4200,1100,26600
k,404,4200,1500,27413
k,405,5200,0,28000
k,406,5200,0,26600
k,407,5200,1100,26600
k,408,5200,1500,27413
k,409,4200,400,28000
k,410,5200,400,28000
V,409,402,403,404,410,406,407,408
V,401,402,409,405,406,410
!--------------------------------------------------------------
!将各块合成一个volumn
VADD,5,8
VADD,ALL              !将各块合成一个块
VSYMM,Y,ALL,,,,0,0    !镜像得到模型的另一半
VADD,ALL              !再合成
NUMMRG,ALL, , , ,LOW  !消除重复的点线面
NUMCMP,ALL            !重新编号
!--------------------------------------------------------------
!将钢材和混凝土分开
A,46,47,88,87
A,21,117,92,86
ASEL,,,,105,106
V***A,1,ALL
ALLSEL,ALL
NUMMRG,ALL, , , ,LOW  !消除重复的点线面
NUMCMP,ALL            !重新编号
VSEL, , , ,2
VATT,1, , 1, 0
VSEL, , , ,1
VATT,2, , 1, 0
ALLSEL,ALL
!--------------------------------------------------------------
!合并一些面,以便优化网格的划分
AADD,95,76
AADD,52,50
NUMMRG,ALL, , , ,LOW  !消除重复的点线面
NUMCMP,ALL            !重新编号
!--------------------------------------------------------------
!找出牛腿处的加载面
k,301,3700,0,10920
k,302,3375,0,10920
k,303,4025,0,10920
k,304,3700,375,10920
k,305,3700,-375,10920
LARC,302,304,301,375
LARC,302,305,301,375
LARC,303,304,301,375
LARC,303,305,301,375
FLST,3,2,4,ORDE,2
FITEM,3,215
FITEM,3,217
A***L,      96,P51X
FLST,3,2,4,ORDE,2
FITEM,3,216
FITEM,3,218
A***L,      54,P51X
!--------------------------------------------------------------
!找出顶点的关键点
k,201,4700,-400,28000
k,202,4700,0,28000
k,203,4700,400,28000
L,201,202
L,202,203
A***L,93,222
A***L,50,167
NUMMRG,ALL, , , ,LOW  !消除重复的点线面
NUMCMP,ALL            !重新编号
!--------------------------------------------------------------
!施加位移约束及荷载
DA,7,ALL
DA,74,ALL
ACEL,0,0,1                    !自重
FK,119,FZ,-2.3845e7            !顶点恒载+活载
FK,119,FY,2.138e5             !顶点恒载+活载
SFA,95,1,PRES,8.377776         !牛腿上恒载+活载
SFA,104,1,PRES,8.377776        !牛腿上恒载+活载
!--------------------------------------------------------------
!网格划分
SMRT,1
VMESH,ALL
!--------------------------------------------------------------
!求解
finish
/solu
solve!---------------------------------------------------------
!观察结果
FINISH
/POST1
PLNSOL,U,Y,0,1

chenshi2003

真是好贴，希望大家共同努力，不论转载还是自己的创作的，只要是通过自己实际用过的觉得不错的命令流都可以贴出来，最好能加上自己的分析，为扩大完善命令流实例库而奋斗吧！！！希望斑竹、大侠们多多支持。
下面是我以前看过也算过的决定很不错的一个命令流，采用单元生死技术来分析隧道开挖问题，在网格的划分等处理上也非常好。不过后面为什么用循环来求解还不是很理解呢，或许并没有这个必要而直接杀死开挖的岩土。
/com
fini
/cle
*set,x1,-12
*set,y1,-12
*set,w1,28.9
*set,h1,30.15

*set,x2,-25
*set,y2,-12
*set,w2,13
*set,h2,30.15

*set,x3,16.9
*set,y3,-12
*set,w3,13
*set,h3,30.15

*set,x4,-25
*set,y4,-30
*set,w4,54.9
*set,h4,18

*set,th,0.4     !厚度
*set,length_z,50  !洞的进深
/prep7
et,1,mesh200,2    !用于3-D的2节点线
et,2,mesh200,6    !用于3-D的4节点四边形
et,3,shell63
et,4,solid45

r,1,th       !壳的厚度

mp,ex,1,3.0e10     !壳的材料,C30混凝土
mp,prxy,1,0.2
mp,dens,1,2500
mp,ex,2,4.5e8     !保留岩石的材料
mp,prxy,2,0.32
tb,dp,2
tbdata,1,20,30,
mp,dens,2,2700
mp,ex,3,4.51e8     !挖去岩石的材料
mp,prxy,3,0.32
tb,dp,3
tbdata,1,20,30,
mp,dens,3,2700

k,,0,0
k,,0,3.85
k,,0.88,5.5
k,,2.45,6.15
k,,4.02,5.5
k,,4.9,3.85
k,,4.9,0

larc,1,2,6,8.13 !定义两点之间的圆弧线，larc,p1,p2,pc,rad
larc,2,3,6,3.21
larc,3,4,6,2.22
larc,4,5,2,2.22
larc,5,6,2,3.21
larc,6,7,2,8.13
larc,7,1,4,6

a,1,2,3,4,5,6,7     !产生面1

blc4,x1,y1,w1,h1    !产生面2
blc4,x2,y2,w2,h2    !产生面3
blc4,x3,y3,w3,h3    !产生面4
blc4,x4,y4,w4,h4      !产生面5
/pnum,area,1

aovl,1,2,3,4,5   !布尔操作重叠，得到面3
nummrg,all,,,,low
numcmp,all

l,1,8      !从四个角点上连接出四条线
l,7,9
l,6,10
l,2,11

lsel,s,line,,21,22,1  !用线分割面
lsel,a,line,,7
a***l,5,all

lsel,s,line,,21,24,3
lsel,a,line,,1
a***l,7,all

lsel,s,line,,22,23,1
lsel,a,line,,6
a***l,8,all

nummrg,all,,,,low
numcmp,all

lsel,s,line,,2,5,1
LCCAT,all
lesize,all,,,3

lsel,s,line,,9,11,2
lsel,a,line,,6
lsel,a,line,,1
lesize,all,,,8

lsel,s,line,,8,10,2
lsel,a,line,,7
lesize,all,,,12

lsel,s,line,,21,24,1
lesize,all,,,10,2

type,2
asel,s,area,,5,8,1
amesh,all

asel,s,area,,1
amesh,1

lsel,s,line,,12,13,1
lesize,all,,,8
lsel,s,line,,15,18,1
lesize,all,,,6,2
asel,s,area,,2,3,1
amesh,all

lsel,s,line,,14
lesize,all,,,24
lsel,s,line,,19,20,1
lesize,all,,,6,2
lsel,s,line,,15,17,2
lsel,a,line,,8
LCCAT,all
asel,s,area,,4
amesh,all
LSEL,s,LCCA
LDELE,all
nummrg,all,,,,low
numcmp,all
allsel

!以下开始拉伸成实体单元
!首先拉伸成壳单元
k,1000,,,-length_z
l,1,1000
/view,1,1,1,1
/replot
EXTOPT,ESIZE,10,0,
LSEL,S,LINE,,1,7,1
ADRAG,all,,,,,,25
gplot
type,3
real,1
mat,1
ASEL,S,loc,z,-25
APLOT
lsel,s,loc,z,-25
lesize,all,,,10
MSHAPE,0,2D
MSHKEY,1
amesh,all

!拉伸岩石的实体
ASEL,invert
aplot
EXTOPT,ESIZE,10,0,  
EXTOPT,ACLEAR,1
TYPE,4
MAT,2
asel,r,area,,2,8,1
VDRAG,all,,,,,,25
allsel

!挖去部分岩石的实体
MAT,3
VDRAG,1,,,,,,25
EPLOT

nummrg,all,,,,low
numcmp,all

!约束两侧面的X方向的约束
asel,s,loc,x,x2
asel,a,loc,x,x2+w4
da,all,ux,0
alls

!约束地面的Y方向的约束
asel,s,loc,y,y4
da,all,uy,0
alls

asel,s,loc,z,-length_z
asel,a,loc,z,0
da,all,uz,0
allsel
acel,,10
fini

/solu
antype,static

deltim,0.1,0.05,0.2
autots,on     !使用自动时间步
pred,on     !打开时间步长预测器
lnsrch,on     !打开线性搜索
nlgeom,on     !打开大位移效果
nropt,full     !设定牛顿-拉普森选项
cnvtol,f,,0.02,2,0.5

esel,s,type,,3     !选择梁单元，杀死
ekill,all
esel,all
esel,s,live     !选择活的单元
nsle,s       !选择活单元上的节点
nsel,invert     !反向选择，即选择了死单元上的节点
d,all,all,0     !将死单元上的节点约束所有位移，使其不参与矩阵运算
nsel,all
esel,all
/PBC,ALL,,1
gplot
solve

*do,ii,1,10,1     
    esel,s,mat,,3     !选择挖去的岩石，杀死
    nsle,s
    nsel,r,loc,z,0.1-(ii-1)*5,-(5.1+(ii-1)*5)
    esln,r,1   
    ekill,all     
   
    esel,s,type,,3     !激活挖去的岩石对应的壳单元,并将其节点上的约束删除
    nsle,s
    nsel,r,loc,z,0.1-(ii-1)*5,-(5.1+(ii-1)*5)
    esln,r,1
    ealive,all

    nsle,s
    ddele,all,all
    esel,all
    esel,s,live    !选择活单元，此时应该包含两部份，一是梁单元，二是未挖去的岩石单元
    nsle,s
    nsel,invert     !反向选择，将死单元上的节点约束所有自由度
    d,all,all,0
    nsel,all
    esel,all
solve
*enddo

fq8301

支持楼主，大家都来为论坛发展和会员水平的提高作贡献。

/PREP7  !进入前处理模块PREP7

ET, 1, BEAM3 !定义第一类单元为平面梁单元BEAM3

ET, 2, MASS21, , ,4 !定义第二类单元为质量阻尼单元MASS21

R, 1, 0.003, 6.25e-7, 0.05  !定义单元的第一类实常数:Area,Inertia,Height

R, 2, 0.1   !定义单元的第二类实常数:集中质量

MP, EX, 1, 207e9    !定义第一类材料的弹性模量EX

N, 1, 0, 0  !定义各个结点

N, 2, 0.04, 0

N, 3, 0.08, 0

N, 4, 0.12, 0

TYPE, 1 !使用第一类单元

REAL, 1 !使用第一类实常数

MAT, 1  !使用第一类材料

E, 1, 2 !按上面设置定义单元

E, 2, 3

E, 3, 4

TYPE, 2 !使用第二类单元

REAL, 2 !使用第二类实常数

E, 4    !定义四号单元(集中质量)

FINISH      !退出后模块

/SOLU   !进入求解模块SOLUTION   

ANTYPE, MODAL   !申明求解类型是模态分析

MODOPT,LANB,5   !使用Block Lanczos方法求解前5阶振型和频率

D, 1, ALL, 0    !固定1号结点

M, 2, UY, 4, 1  !定义2号到4号结点的三个结点的Y方向为主自由度

SOLVE   !开始求解   

FINISH      !退出后模块

/POST1  !进入后处理模块POST1        

SET, 1, 1   !读入第一阶频率和振型

PLDISP       ! 在图形窗口显示结构变形      

ANMODE,10,0.05  !用10帧每隔0.05秒钟的动画显示振型

fq8301

实体及其建模
三维实体模型是建模最麻烦的一类工程计算，好在Ansys提供了许多实体建模的功能和与其他CAD系统的接口。三维问题的分析除了建模上的麻烦外，其余的分析过程和前面完全一样。Ansys中使用最过的实体单元是Solid45，它有8个结点，每个结点有三个线位移。

下面是在实体建模时最常用到的命令：

实体建模

1） 定义关键点（Key point）：K, NPT, X, Y, Z

2） 定义直线(Line)：L, P1, P2, NDIV, SPACE, XV1, YV1, ZV1, XV2, YV2, ZV2 – 过两点定义直线

3） 定义平面(Area)：A, P1, P2, P3, P4, P5, P6, P7, P8, P9, P10, P11, P12, P13, P14, P15, P16, P17, P18 – 连关键点定义面

4） 定义体(Volume)：V, P1, P2, P3, P4, P5, P6, P7, P8 – 过关键点定义体

5） 定义矩形块或者体（Block）：BLC4, XCORNER, YCORNER, WIDTH, HEIGHT, DEPTH

6） 定义圆或者圆柱（Cylinder）：CYL4, XCENTER, YCENTER, RAD1, THETA1, RAD2, THETA2, DEPTH



下面几个实例的代码均在Ansys5.6的ED版中调试通过。



5.1  PlanWing.txt  机翼模型的振动分析（Ansys算例）
这是Ansys实体模态分析中的一个机翼模型，首先它采用关键点定义形成了机翼轮廓，对该轮廓单元划分后，通过拉伸操作形成了一个三维机翼实体，最后采用模态分析计算得到了前5阶频率和振型。

这是通过指定5 个关键点后形成的轮廓：



这是通过对划分后的平面单元拉伸，所形成的机翼实体：



这是第一阶振型，上下弯曲振动，对应的频率是3.628Hz：





这是第二阶振型，水平面内弯曲振动，对应的频率是17.42Hz：





这是第三阶振型，上下弯曲振动，对应的频率是22.92Hz：



这是第四阶振型，扭转振动，对应的频率是36.017Hz：





这是第五阶振型，上下弯曲振动，对应的频率是65.72Hz：



以下是全部指令：

FINISH      !退出以前模块

/CLEAR   !清除内存中的所有数据

/FILENAME,PlanWing

/title,PlanWing.txt, Modal analysis of Airplane Wing Model

/PREP7  !进入前处理模块PREP7  

k,1     !定义机翼截面的控制关键点

k,2,2   

k,3,2.3,.2  

k,4,1.9,.45

k,5,1,.25   

l,1,2   !定义直线

l,5,1   

spline,2,3,4,5,,,-1,,,-1,-0.25,0    !定义过2,3,4,5的SPLINE

a,1,2,3,4,5     !定义用线1,2,3,4和5围起来的面积

mp,ex,1,38000   !定义第一类材料的弹性模量EX=38000

mp,dens,1,0.001033      !定义第一类材料的密度DENS=0.001033

mp,nuxy,1,0.3   !定义第一类材料的泊桑比NUXY=0.3

et,1,plane42    !定义第一类单元为四结点平面单元PLANE42

et,2,solid45    !定义第二类单元为八结点实体单元SOLID45

esize,.3  !指定单元划分尺寸0.3

AMESH,ALL       ! 对所有面积进行单元划分   

TYPE,   2   !切换单元类型为2

EXTOPT,ESIZE,10,0,  !拉伸生成选项,10个

EXTOPT,ACLEAR,0

EXTOPT,ATTR,0,0,0   

VEXT,1, , ,0,0,10,,,,   !体拉伸

FINISH      !退出后模块  

/SOLU   !进入求解模块SOLUTION   

ESEL,U,TYPE,,1  !取消选择单元类型是1的单元

NSEL,S,LOC,Z,0  !选择Z坐标为0的所有结点

D,all, , , , , ,ALL, , , , ,  !对选择集中的所有结点施加固定点条件  

ALLSEL,ALL  !选择所有对象

ANTYPE,2    !申明求解类型是模态分析

MODOPT,LANB,5,0,0, ,OFF, ,2 !使用Block Lanczos方法求解前5阶振型和频率

SOLVE   !开始求解   

FINISH      !退出后模块  

/POST1  !进入后处理模块POST1  

SET,FIRST   !读入第一阶频率和振型

/view,1,1,1,1   !切换观察方向为(1,1,1)

PLDI, ,     !显示振型

ANMODE,6,0.15, ,0   !用6帧每隔0.15秒钟的动画显示振型





5.2  SpngBas1.txt  立体斜支座的实体建模
这个例子只是演示如何建立一个斜支座，支座样子如图：



首先，我们定义了地面上的轮廓线和小孔（小孔采用面积相减的方法得到），然后对该面采用拉伸后形成底部的体。

底面形成后的样子如图：



然后通过三个关键点，将工作平面移到斜支座面的方向。

采用类似的方法得到斜向的部分，最后的突起轴座使用两个圆柱的相减得到的。



下面是全部代码：

FINISH      !退出以前模块

/CLEAR   !清除内存中的所有数据

/FILENAME,SPNGBAS1

/TITLE,SPNGBAS1.txt, SOLID MODEL OF SPINDLE BASE.(Simplified Version)

/PREP7  !进入前处理模块PREP7

BLC4,0,0,109,102    !定义底座主矩形区域

K,5,-20,82  !定义倒角位置的四个控制点

K,6,-20,20

K,7,0,82

K,8,0,20

LARC,4,5,7,20   !定义倒角圆弧

LARC,1,6,8,20

L,5,6   !定义过5,6点的直线

AL,4,5,6,7  !定义用4,5,6,7围成的面积

AADD,1,2        ! 将1,2面积相加,得到3号面积

CYL4,0,20,10        ! 定义圆孔位置,编号为1

AGEN,2,1, , ,69     ! 生成第二个圆孔,编号为2

AGEN,2,1,2, , ,62   ! 生成其余的二个圆孔

A***A,3,ALL  ! 从3号面积中减去四个圆孔,生成6号面积

VOFFST,6,26 !将6号面积平行移动26,生成体

K,60,109,102,0  !定义关键点60

K,61,109,2,0

K,62,159,102,sqrt(3)/0.02

KWPLAN,-1,60,61,62  !过关键点60,61,62定义工作面

BLC4,0,0,102,180    !在当前工作面方位建立矩形

CYL4,51,180,51  !在当前工作面方位建立圆

AADD,25,26  !面积相加

VOFFST,27,26    !将面积27平移26,生成体

VADD,1,2    !体相加

AADD,33,34,38   !面相加

AADD,32,36,37

CYL4,51,180,32, , , ,60     !定义凸起的圆柱

VADD,1,3    !体相加

CYL4,51,180,18.5, , , ,60   !定义凸起的圆柱中的圆孔

V***V,2,1    !体相减

/VIEW, 1, -0.157696856347, -0.629983293323,  0.760429320602  !改变视角

/ANG,  1,  6.14867656545   !旋转模型

/AUTO, 1    !以最佳比例显示模型

vplot   !绘制体模型





5.3  Wheel1.txt  四分之一车轮实体建模
该例向通过回转操作生成回转体部件，受ED版限制，这里只生成1／4部分，且略去了许多细部构造。

首先定义的截面，如图：



然后，定义了关键点21和22，过这两个点为轴，将该截面旋转90度，就可以得到1／4轮子部分。然后旋转工作面，定义圆柱后，将其从轮子上减去，就得到轮子上的小圆孔了。最后支座的1／4轮子如图：





FINISH      !退出以前模块

/CLEAR   !清除内存中的所有数据

/FileName,Wheel1

/TITLE, WHEEL1.txt, SOLID MODELING SAMPLE: A WHEEL BY ROTATION.(Simplified Version)

/PREP7  !进入前处理模块PREP7

BLC4,2,0,1,5.5  !内侧截面A1

BLC4,3,2,5,1    !中部端面A2

BLC4,8,0,0.5,5  !边沿截面A3

AADD,ALL    !上面3块面积相加,得到面积4

K,21,0,0,0  !定义关键点21

K,22,0,5,0  !定义关键点22

VROTAT,4, , , , , ,21,22,90, ,  !将面积4绕21,21定义的轴转90度生成体

K,43,0,3,0  !定义关键点43,44和45

K,44,1,3,0

K,45,0,3,1

KWPLAN,1,43,44,45   !过关键点43,44和45定义工作面  

CSYS,0      !切换坐标系

CYL4,5.5*cos(-45*3.14159/180),5.5*sin(-45*3.14159/180),0.5, , , ,1   !定义轮上的小圆孔

v***v,all,2   !减去小圆孔

/VIEW, 1 ,1,1,1 !改变观察方向

/ANG, 1     !旋转模型

vplot   !重绘体积

fq8301

再来一篇，改天再贴
杆系问题
杆系结构是指结构由许多细长杆件构成的结构系统,且杆件的弯曲刚度较小,或者弯曲产生的应力和轴力相比较小,每个杆件的主要变形时轴向变形。对于这一类问题，有限元模型可以利用杆单元模型（LINK）来处理。在Ansys中，二维杆单元是Link1，三维杆单元是Link8。它们的单元两端的广义位移分析有两个和三个线位移。对于许多杆系空间结构需要利用Link8单元求解。计算结构除了我们关心的结点位移，最主要的我们关心各个杆件的内力和应力。在Ansys中杆件的内力需要利用单元表（ETABLE）定义的方法获得，而无法直接得到。求解一个有限元问题的基本过程是一样的：第一步是建立模型并施加力和位移边界条件，然后就可以求解了，在求解之后可以直接得到结点的位移，其余的力学量需要通过适当的定义或者运算才可以得到。并且许多计算的结果由于模型的简化原因会造成和实际模型之间的不一致，这些都需要计算这对计算结果进行是适当的修正和解释，才可以得出合理的计算结论。

杆系结构的计算主要得到桁架结构的变形和内力，反力。即使对于复杂的杆系结构，目前还没有简便的建模方法，通常还是需要利用结点和单元的定义指令N和E来定义。它的优点是直观。边界条件：荷载有命令F和位移约束有命令D。求解有命令solve。显示结果：变形图通常用PLDISP来显示。内力和应力用PLNSOL完成。不同单元具有不同的内力和应力约定。动态求解的目的是要得到结构的前几阶振动频率和振型。这里主要使用的命令有：



1） 建立模型(/Prep7模块)

定义结点：N, NODE, X, Y, Z, THXY, THYZ, THZX

定义单元：E, I, J, K, L, M, N, O, P

2） 定义边界条件(/Solu模块)

定义位移约束：D, NODE, Lab, VALUE, VALUE2, NEND, NINC, Lab2, Lab3, Lab4, Lab5, Lab6

定义力：F, NODE, Lab, VALUE, VALUE2, NEND, NINC

3） 求解方程(/Solu模块)

开始求解计算：solve

4） 查看结果(/post1模块)

显示结构变形图：pldisp,2

显示结点结果：PLNSOL, Item, Comp



下面几个实例的代码均在Ansys5.6的ED版中调试通过。

1.1  Ex-36c.txt  人字形屋架的分析
右图所示的屋架，几何尺寸和边界条件如图（图1），现在要分析在三个集中力所作用下的变形和内力。首先将这个结构在杆件相交的地方，设置结点，结点之间用单元相连接（图2）。利用命令行通过建立模型，求解和后处理得到整个结构的变形和内力。最后一个图是用色度图表示的杆件内力。





下面是全部指令：

FINISH  !退出以前的模块

/CLEAR,START    !清除系统中的所有数据,读入启动文件的设置

/FILNAME,EX3-36 !指定所有数据的文件名

/UNITS, SI  !申明采用国际单位制

/TITLE, EX3-35.txt, Plane Roof Tuss Model.

/PREP7  !进入前处理模块: 定义模型

N, 1, 0, 0 !定义各个结点

N, 2, 2, 0

N, 3, 4, 0

N, 4, 6, 0

N, 5, 8, 0

N, 6, 2, 1

N, 7, 4, 2

N, 8, 6, 1

ET, 1, LINK1    !定义第一类单元为二维杆单元LINK1

MP, EX, 1, 207E9   !定义第一类材料弹性模量EX

R, 1, 0.01  !定义杆件第一类实常数--截面积

E, 1, 2     !定义各个单元

E, 2, 3

E, 3, 4

E, 4, 5

E, 1, 6

E, 6, 7

E, 2, 6

E, 2, 7

E, 3, 7

E, 4, 7

E, 4, 8

E, 7, 8

E, 8, 5

FINISH  !退出前处理模块

/SOLU   !进入求解模块:定义力和位移边界条件,并求解

ANTYPE, STATIC  !申明分析类型是静力分析

OUTPR, BASIC, ALL   !在输出结果中，列出元素的结果

D, 1, ALL, 0, , 5, 4    !约束1号结点的所有结点位移分量,并按增量4循环到5号结点

NSEL, U, NODE, , 1, 5, 1    !对1到5号的所有结点取消选择   

F, ALL, FY, -1000       !对当前选择集中的所有结点施加Y方向的集中力

ALLSEL      !选择所有项目

SOLVE       !发出求解指令

FINISH      !退出求解模块

/POST1      !进入一般后处理模块:显示变形和内力计算结果

PLDISP,2    !显示结构变形图(保留未变形结构的轮廓)

PRDISP      !列出结点位移值计算结果

ETABLE, MFORX,SMISC,1   ! 建立元素结果表，杆单元的轴向力

ETABLE, SAXL, LS, 1 ! 建立元素结果表，杆单元的轴向应力

ETABLE, EPELAXL, LEPEL, 1   ! 建立元素结果表，杆单元的轴向应变

PRETAB              ! 显示单元表资料

PLETAB, MFORX   !用色度图显示杆件轴力图

FINISH  !退出后处理模块





1.2  PSTRU4-5.TXT 四角锥平板网架模态分析



如图四角锥平板网架就是利用N和E命令定义的，命令中使用了大量的结点和单元定义, 该模型在四个角点处固定,仿照前面的指令添加位移约束,并指定截面特性,质量特性,按照模态分析的基本步骤,就可以得到它的前5阶模态。

下面是完成该结构前5阶模态分析的全部指令:

FINISH  !退出以前的模块

/CLEAR,START    !清除系统中的所有数据,读入启动文件的设置

/FileName,PSTRU4-5

/TITLE,PSTRU4-5.txt, Plate Truss Model created by direct method.

/PREP7  !进入前处理模块: 定义模型

ET, 1, LINK8    !定义第一类单元为三维杆单元LINK8

MP, EX, 1, 207E3    !定义第一类材料弹性模量EX

MP, DENS, 1, 7.8e-6  !材料密度

R, 1, 100   !定义杆件第一类实常数--截面积. 该问题的长度单位为毫米

N, 1 ,-20000 ,-20000 , 0    !定义网架的所有结点,单位毫米

N, 2 ,-12000 ,-20000 , 0

N, 3 ,-4000 ,-20000 , 0

N, 4 , 4000 ,-20000 , 0

N, 5 , 12000 ,-20000 , 0

N, 6 , 20000 ,-20000 , 0

N, 7 ,-16000 ,-15000 ,-4000

N, 8 ,-8000 ,-15000 ,-4000

N, 9 , 0 ,-15000 ,-4000

N, 10 , 8000 ,-15000 ,-4000

N, 11 , 16000 ,-15000 ,-4000

N, 12 ,-20000 ,-10000 , 0

N, 13 ,-12000 ,-10000 , 0

N, 14 ,-4000 ,-10000 , 0

N, 15 , 4000 ,-10000 , 0

N, 16 , 12000 ,-10000 , 0

N, 17 , 20000 ,-10000 , 0

N, 18 ,-16000 ,-5000 ,-4000

N, 19 ,-8000 ,-5000 ,-4000

N, 20 , 0 ,-5000 ,-4000

N, 21 , 8000 ,-5000 ,-4000

N, 22 , 16000 ,-5000 ,-4000

N, 23 ,-20000 , 0 , 0

N, 24 ,-12000 , 0 , 0

N, 25 ,-4000 , 0 , 0

N, 26 , 4000 , 0 , 0

N, 27 , 12000 , 0 , 0

N, 28 , 20000 , 0 , 0

N, 29 ,-16000 , 5000 ,-4000

N, 30 ,-8000 , 5000 ,-4000

N, 31 , 0 , 5000 ,-4000

N, 32 , 8000 , 5000 ,-4000

N, 33 , 16000 , 5000 ,-4000

N, 34 ,-20000 , 10000 , 0

N, 35 ,-12000 , 10000 , 0

N, 36 ,-4000 , 10000 , 0

N, 37 , 4000 , 10000 , 0

N, 38 , 12000 , 10000 , 0

N, 39 , 20000 , 10000 , 0

N, 40 ,-16000 , 15000 ,-4000

N, 41 ,-8000 , 15000 ,-4000

N, 42 , 0 , 15000 ,-4000

N, 43 , 8000 , 15000 ,-4000

N, 44 , 16000 , 15000 ,-4000

N, 45 ,-20000 , 20000 , 0

N, 46 ,-12000 , 20000 , 0

N, 47 ,-4000 , 20000 , 0

N, 48 , 4000 , 20000 , 0

N, 49 , 12000 , 20000 , 0

N, 50 , 20000 , 20000 , 0

E, 1 , 2    !定义各个单元

E, 2 , 3

E, 3 , 4

E, 4 , 5

E, 5 , 6

E, 12 , 13

E, 13 , 14

E, 14 , 15

E, 15 , 16

E, 16 , 17

E, 23 , 24

E, 24 , 25

E, 25 , 26

E, 26 , 27

E, 27 , 28

E, 34 , 35

E, 35 , 36

E, 36 , 37

E, 37 , 38

E, 38 , 39

E, 45 , 46

E, 46 , 47

E, 47 , 48

E, 48 , 49

E, 49 , 50

E, 1 , 12

E, 2 , 13

E, 3 , 14

E, 4 , 15

E, 5 , 16

E, 6 , 17

E, 12 , 23

E, 13 , 24

E, 14 , 25

E, 15 , 26

E, 16 , 27

E, 17 , 28

E, 23 , 34

E, 24 , 35

E, 25 , 36

E, 26 , 37

E, 27 , 38

E, 28 , 39

E, 34 , 45

E, 35 , 46

E, 36 , 47

E, 37 , 48

E, 38 , 49

E, 39 , 50

E, 7 , 1

E, 8 , 2

E, 9 , 3

E, 10 , 4

E, 11 , 5

E, 18 , 12

E, 19 , 13

E, 20 , 14

E, 21 , 15

E, 22 , 16

E, 29 , 23

E, 30 , 24

E, 31 , 25

E, 32 , 26

E, 33 , 27

E, 40 , 34

E, 41 , 35

E, 42 , 36

E, 43 , 37

E, 44 , 38

E, 7 , 2

E, 8 , 3

E, 9 , 4

E, 10 , 5

E, 11 , 6

E, 18 , 13

E, 19 , 14

E, 20 , 15

E, 21 , 16

E, 22 , 17

E, 29 , 24

E, 30 , 25

E, 31 , 26

E, 32 , 27

E, 33 , 28

E, 40 , 35

E, 41 , 36

E, 42 , 37

E, 43 , 38

E, 44 , 39

E, 7 , 12

E, 8 , 13

E, 9 , 14

E, 10 , 15

E, 11 , 16

E, 18 , 23

E, 19 , 24

E, 20 , 25

E, 21 , 26

E, 22 , 27

E, 29 , 34

E, 30 , 35

E, 31 , 36

E, 32 , 37

E, 33 , 38

E, 40 , 45

E, 41 , 46

E, 42 , 47

E, 43 , 48

E, 44 , 49

E, 7 , 13

E, 8 , 14

E, 9 , 15

E, 10 , 16

E, 11 , 17

E, 18 , 24

E, 19 , 25

E, 20 , 26

E, 21 , 27

E, 22 , 28

E, 29 , 35

E, 30 , 36

E, 31 , 37

E, 32 , 38

E, 33 , 39

E, 40 , 46

E, 41 , 47

E, 42 , 48

E, 43 , 49

E, 44 , 50

E, 7 , 8

E, 8 , 9

E, 9 , 10

E, 10 , 11

E, 18 , 19

E, 19 , 20

E, 20 , 21

E, 21 , 22

E, 29 , 30

E, 30 , 31

E, 31 , 32

E, 32 , 33

E, 40 , 41

E, 41 , 42

E, 42 , 43

E, 43 , 44

E, 7 , 18

E, 8 , 19

E, 9 , 20

E, 10 , 21

E, 11 , 22

E, 18 , 29

E, 19 , 30

E, 20 , 31

E, 21 , 32

E, 22 , 33

E, 29 , 40

E, 30 , 41

E, 31 , 42

E, 32 , 43

E, 33 , 44

!接下来可以利用命令定义边界条件

D,1,all,0   !完全固定结点1，6，45和50

D,6,all,0

D,45,all,0

D,50,all,0

FINISH  !退出前处理模块

/SOLU   !进入求解模块SOLUTION   

AnType,Modal    !分析类型是模态分析

ModOpt,LANB,5   !模态分析选项:Block Lanczos方法,前5阶振型和频率

MXPAND,5    !展开前5结振型

SOLVE   !开始求解   

FINISH      !退出后模块

/POST1  !进入后处理模块POST1        

SET, 1, 1   !读入第一阶频率和振型

PLDISP,2         ! 在图形窗口显示结构变形      

ANMODE,10,0.05  !用10帧每隔0.05秒钟的动画显示振型

FINISH





1.3  WQ5-5.TXT  镂空柱面网壳




上图是利用N和E指令建立的镂空柱面网壳模型。对该模型仿照前面的指令添加位移和力的边界条件后求解，可以得到整个网架的变形和各个杆件的内力。该模型在中部的几个集中力作用下，产生如图的变形：





建模的全部指令：

FINISH  !退出以前的模块

/CLEAR,NOSTART  !清除系统中的所有数据,不读入启动文件的设置

/FileName,WQ5-5

/TITLE,WQ5-5,Cylinder Shell Truss Model.

/PREP7  !进入前处理模块

ET,1,LINK8  !定义第一类单元是空间杆件LINK8

MP, EX, 1, 207E3    !定义第一类材料弹性模量EX

MP,DENS,1,7.8e-6  !材料密度

R, 1, 100   !定义杆件第一类实常数--截面积. 该问题的长度单位为毫米

N, 1 ,-20000 , 22000 , 0    !定义各个结点位置信息,单位:毫米

N, 2 ,-12000 , 22000 , 0

N, 3 ,-4000 , 22000 , 0

N, 4 , 4000 , 22000 , 0

N, 5 , 12000 , 22000 , 0

N, 6 , 20000 , 22000 , 0

N, 7 ,-20000 , 20098 , 8948.206

N, 8 ,-12000 , 20098 , 8948.206

N, 9 ,-4000 , 20098 , 8948.206

N, 10 , 4000 , 20098 , 8948.206

N, 11 , 12000 , 20098 , 8948.206

N, 12 , 20000 , 20098 , 8948.206

N, 13 ,-20000 , 14720.87 , 16349.19

N, 14 ,-12000 , 14720.87 , 16349.19

N, 15 ,-4000 , 14720.87 , 16349.19

N, 16 , 4000 , 14720.87 , 16349.19

N, 17 , 12000 , 14720.87 , 16349.19

N, 18 , 20000 , 14720.87 , 16349.19

N, 19 ,-20000 , 6798.374 , 20923.24

N, 20 ,-12000 , 6798.374 , 20923.24

N, 21 ,-4000 , 6798.374 , 20923.24

N, 22 , 4000 , 6798.374 , 20923.24

N, 23 , 12000 , 6798.374 , 20923.24

N, 24 , 20000 , 6798.374 , 20923.24

N, 25 ,-20000 ,-2299.626 , 21879.48

N, 26 ,-12000 ,-2299.626 , 21879.48

N, 27 ,-4000 ,-2299.626 , 21879.48

N, 28 , 4000 ,-2299.626 , 21879.48

N, 29 , 12000 ,-2299.626 , 21879.48

N, 30 , 20000 ,-2299.626 , 21879.48

N, 31 ,-20000 ,-11000 , 19052.56

N, 32 ,-12000 ,-11000 , 19052.56

N, 33 ,-4000 ,-11000 , 19052.56

N, 34 , 4000 ,-11000 , 19052.56

N, 35 , 12000 ,-11000 , 19052.56

N, 36 , 20000 ,-11000 , 19052.56

N, 37 ,-16000 , 17606.66 , 3742.41

N, 38 ,-8000 , 17606.66 , 3742.41

N, 39 , 0 , 17606.66 , 3742.41

N, 40 , 8000 , 17606.66 , 3742.41

N, 41 , 16000 , 17606.66 , 3742.41

N, 42 ,-16000 , 14562.31 , 10580.13

N, 43 , 0 , 14562.31 , 10580.13

N, 44 , 16000 , 14562.31 , 10580.13

N, 45 ,-16000 , 9000 , 15588.46

N, 46 ,-8000 , 9000 , 15588.46

N, 47 , 0 , 9000 , 15588.46

N, 48 , 8000 , 9000 , 15588.46

N, 49 , 16000 , 9000 , 15588.46

N, 50 ,-16000 , 1881.512 , 17901.39

N, 51 , 0 , 1881.512 , 17901.39

N, 52 , 16000 , 1881.512 , 17901.39

N, 53 ,-16000 ,-5562.306 , 17119.02

N, 54 ,-8000 ,-5562.306 , 17119.02

N, 55 , 0 ,-5562.306 , 17119.02

N, 56 , 8000 ,-5562.306 , 17119.02

N, 57 , 16000 ,-5562.306 , 17119.02

E, 1 , 2        !定义各个杆件连接信息

E, 2 , 3

E, 3 , 4

E, 4 , 5

E, 5 , 6

E, 7 , 8

E, 8 , 9

E, 9 , 10

E, 10 , 11

E, 11 , 12

E, 13 , 14

E, 14 , 15

E, 15 , 16

E, 16 , 17

E, 17 , 18

E, 19 , 20

E, 20 , 21

E, 21 , 22

E, 22 , 23

E, 23 , 24

E, 25 , 26

E, 26 , 27

E, 27 , 28

E, 28 , 29

E, 29 , 30

E, 31 , 32

E, 32 , 33

E, 33 , 34

E, 34 , 35

E, 35 , 36

E, 1 , 7

E, 2 , 8

E, 3 , 9

E, 4 , 10

E, 5 , 11

E, 6 , 12

E, 7 , 13

E, 8 , 14

E, 9 , 15

E, 10 , 16

E, 11 , 17

E, 12 , 18

E, 13 , 19

E, 14 , 20

E, 15 , 21

E, 16 , 22

E, 17 , 23

E, 18 , 24

E, 19 , 25

E, 20 , 26

E, 21 , 27

E, 22 , 28

E, 23 , 29

E, 24 , 30

E, 25 , 31

E, 26 , 32

E, 27 , 33

E, 28 , 34

E, 29 , 35

E, 30 , 36

E, 37 , 7

E, 38 , 8

E, 39 , 9

E, 40 , 10

E, 41 , 11

E, 45 , 19

E, 46 , 20

E, 47 , 21

E, 48 , 22

E, 49 , 23

E, 53 , 31

E, 54 , 32

E, 55 , 33

E, 56 , 34

E, 57 , 35

E, 37 , 8

E, 38 , 9

E, 39 , 10

E, 40 , 11

E, 41 , 12

E, 45 , 20

E, 46 , 21

E, 47 , 22

E, 48 , 23

E, 49 , 24

E, 53 , 32

E, 54 , 33

E, 55 , 34

E, 56 , 35

E, 57 , 36

E, 37 , 1

E, 38 , 2

E, 39 , 3

E, 40 , 4

E, 41 , 5

E, 45 , 13

E, 46 , 14

E, 47 , 15

E, 48 , 16

E, 49 , 17

E, 53 , 25

E, 54 , 26

E, 55 , 27

E, 56 , 28

E, 57 , 29

E, 37 , 2

E, 38 , 3

E, 39 , 4

E, 40 , 5

E, 41 , 6

E, 45 , 14

E, 46 , 15

E, 47 , 16

E, 48 , 17

E, 49 , 18

E, 53 , 26

E, 54 , 27

E, 55 , 28

E, 56 , 29

E, 57 , 30

E, 42 , 13

E, 43 , 15

E, 44 , 17

E, 50 , 25

E, 51 , 27

E, 52 , 29

E, 42 , 14

E, 43 , 16

E, 44 , 18

E, 50 , 26

E, 51 , 28

E, 52 , 30

E, 42 , 7

E, 43 , 9

E, 44 , 11

E, 50 , 19

E, 51 , 21

E, 52 , 23

E, 42 , 8

E, 43 , 10

E, 44 , 12

E, 50 , 20

E, 51 , 22

E, 52 , 24

E, 37 , 38

E, 38 , 39

E, 39 , 40

E, 40 , 41

E, 45 , 46

E, 46 , 47

E, 47 , 48

E, 48 , 49

E, 53 , 54

E, 54 , 55

E, 55 , 56

E, 56 , 57

E, 42 , 37

E, 43 , 39

E, 44 , 41

E, 50 , 45

E, 51 , 47

E, 52 , 49

E, 42 , 45

E, 43 , 47

E, 44 , 49

E, 50 , 53

E, 51 , 55

E, 52 , 57

!定义位移约束

D,1,All,0,,6,1  !固定1到6号结点

D,31,All,0,,36,1    !固定31到36号结点

F,42,FY,-1,,44,1    !在42到44号结点施加-FY方向的集中力,大小为1

F,45,FZ,-1,,49,1    !在45到49号结点施加-FZ方向的集中力,大小为1

/Solu   !进入求解模块

Solve   !开始求解

Finish  !退出求解模块

/Post1  !进入后处理模块

Set,1   !读入第一步求解结果

/VIEW, 1,  0.996146881450 , -0.482657957009E-01,  0.732243370896E-01  !改变视角

/ANG,  1,  -59.7457281417   !旋转模型

/REPLO

Pldisp,2   !绘制变形图

FINISH  !退出后处理模块

fpemail

我想哭，因为我激动！
我想笑，因为我感动！
我想大声的喊：我爱你们！是因为我们心中的共鸣！
建议：为了大家日后查找帖子方便请您花点时间把标题内容改为分析类型好吗？谢谢！
致谢：knospe、nbirdwp
:) 加盟致谢：szg_1999_1999、河砂、chenshi2003、fq8301

hugzq

/units,user
/prep7
n,1,0,0
n,2,4,0
n,3,4,2
n,4,0,2              !定义节点
et,1,8               !选择单元
mp,ex,1,200e9        !定义材料属性
r,1,4e-3             !定义实常数
e,1,2
e,2,3
e,3,4
e,4,1
e,1,3                 !生成单元
finish
/solu
antype,static
d,2,all
d,3,ux                !施加位移约束
f,4,fy,-50000         !施加集中约束
solve
finish
/post1
pldisp                !绘制结构变形图
prdisp                !列出各节点的位移
etable,mforx,smisc,1
etable,saxl,ls,1
etable,epelaxl,lepel,1        !将单元轴力，应力，应变制表
pretab                        !列表显示单元的轴力，应力，应变
pletb,mforx                  
pletb,saxl
pletb,epelaxl                 !求轴向应变最大最小的单元     
finish