[求助+讨论]雨人姐姐快来呀，隧道开挖后不收敛的问题(附全部命令流)

rongzhoutt

一、概况
我做的是隧道上面的一个通风竖井(其断面都是圆)及其联络风道（断面是圆加矩形），总的看起来呈倒T

字形
考虑3种围岩,分别是3,4,5类（从上到下分别是5,4,3）,现在还没采用实际参数
锚杆看做加固区（把围岩的C,FI值提高20%）,加上初衬和二衬的喷射砼,总的物理参数有7类
单元类型用SOLID92
考虑到对称性,模型取一半
采用的是DP模型
由于模型比较大,为节省计算时间围岩的范围取的较小
用了6个坐标系，3个圆柱，3个卡氏
圆和正方体的交接处本来应该是平滑过渡的（用ASKIN）。不过划分网格和参数化操作都比较困难，因此

放弃平滑过渡。

二、建模思路
1、输入参数。包括物理参数，几何模型参数
2、定义DP模型
3、建立几何模型。主要用实体
4、建立组，为方便以后选择实体
5、划分网格。这个见笑了，由于前面的模型建立的不规则，很难划分六面体网格，用的都是四面体网格
6、求解。求初始地应力。可以导入或者不导入初始地应力。不过一旦杀死开挖部分，就不能收敛。
   基本上求解控制里面的东东能用的都用了

三、碰到的问题
1、结果收敛性问题。看了网上很多帖子，关于非线性不收敛的原因很多，总结如下
a，主要结构刚度相差太大。考虑到这个，是否开挖后，开挖部分和围岩部分刚度相差很大，导致不收敛

？这似乎不是问题
b、非线性算法。我用的是稀疏矩阵法，应该关系不大
c、非线性逼近技术。隧道开挖能用弧长法求解么？还没试过
d、非线性求解设置。参数就那么几个。收敛准则（u,f），荷载步，大应变等等。。。试过很多次，还没

收敛过，有没有达人能提供一组较为合理的设置？
e、约束问题。应该没什么
f、网格划分问题。模型已经这个样子，不太好改进
g、物理参数。已经取的较好
2、提取求解后的节点力问题（为了分步释放节点力），我在*VGET和*GET里面都没找到。不知道那个函数

能提取这个节点力（应该是NFORCE,PRRSOL还是PRNLD？这3都只能文本方式显示。值都是一样的）。如果

没有函数能提取节点力，应该有命令可以把选中节点的力存为文件。另外，我算了初始地应力后，发现有

很多节点力为0，这个不知道为什么会这样。
3、主要的error和warning如下
*** WARNING ***   SUPPRESSED MESSAGE    CP =    2635.766   TIME= 12:58:49
There are 210 small equation solver pivot terms.      
还有说单元被扭曲的等等，都是分网的问题。

四、解决思路及下一步打算
目前还是打算再调试一下参数。
如果还是不行的话，只有用solid＋shell单元，这样可以划分部分六面体网格，全部划分六面体还是很困

难。不过我觉得这样看起来就不像真正的隧道模型。

rongzhoutt

FINI
/CLE
/FILNAME,'SHUJING'
/UNIT,SI
/CONFIG,NRES,1E10

!3种围岩类别,二次衬砌C25砼,顶座C25砼,锚杆加固区的C,FI值在围岩类别的基础上提高20%
!壁座是C25砼,则总的材料参数为3+1+(3)

!三种围岩类别
TM_YS3=16*1E9         !3类
MU_YS3=0.24
C_YS3=1.80*1E6
FI_YS3=43
MD_YS3=0.027*1E6/10

TM_YS4=16*1E9        !4类
MU_YS4=0.24
C_YS4=1.80*1E6
FI_YS4=43
MD_YS4=0.027*1E6/10

TM_YS5=16*1E9       !5类
MU_YS5=0.24
C_YS5=1.80*1E6
FI_YS5=43
MD_YS5=0.027*1E6/10

!锚杆加固区
TM_MG3=TM_YS3            !三类
MU_MG3=MU_YS3
C_MG3=1.2*C_YS3
FI_MG3=1.2*FI_YS3
MD_MG3=MD_YS3

TM_MG4=TM_YS4            !四类
MU_MG4=MU_YS4
C_MG4=1.2*C_YS4
FI_MG4=1.2*FI_YS4
MD_MG4=MD_YS4

TM_MG5=TM_YS5            !五类
MU_MG5=MU_YS5
C_MG5=1.2*C_YS5
FI_MG5=1.2*C_YS5
MD_MG5=MD_YS5

!顶座,壁座,二次衬砌C25
TM_C25=16*1E9
MU_C25=0.24
C_C25=1.80*1E6
FI_C25=43
MD_C25=0.027*1E6/10

!建立几何模型相关的常量!!!!!!!!!!!!!!!!!!!!!
LS=13.5      !横向
WD=11.5      !纵向
H1=0         !高度
H2=0
RR=3.05

*DIM,RD,ARRAY,4,30
RD(1,1)=0,3.05,3.5,7.65
RD(1,2)=0,3.05,3.69,6.69
RD(1,3)=0,3.05,3.69,6.69
RD(1,4)=0,3.05,3.6,6.1
RD(1,5)=0,3.05,4,6.1
RD(1,6)=0,3.05,3.6,6.1
RD(1,7)=0,3.05,4,6.1
RD(1,8)=0,3.05,3.6,6.1
RD(1,9)=0,3.05,4,6.1
RD(1,10)=0,3.05,3.6,6.1
RD(1,11)=0,3.05,4,6.1
RD(1,12)=0,3.05,3.6,6.1
RD(1,13)=0,3.05,3.43,5.43
RD(1,14)=0,3.05,3.95,5.43
RD(1,15)=0,3.05,3.43,5.43
RD(1,16)=0,3.05,3.95,5.43
RD(1,17)=0,3.05,3.43,5.43
RD(1,18)=0,3.05,3.95,5.43
RD(1,19)=0,3.05,3.43,5.43
RD(1,20)=0,3.05,3.95,5.43
RD(1,21)=0,3.05,3.43,5.43
RD(1,22)=0,3.05,3.95,5.43
RD(1,23)=0,3.05,3.43,5.43
RD(1,24)=3.05,3.6,6.6       !长方体
RD(1,25)=3.05,3.6,6.6
RD(1,26)=3.05,3.6,6.6
RD(1,27)=0,1.65,2.01,4.51   !左边送风口R
RD(1,28)=0,2.1,2.46,4.96    !右边排风口R
RD(1,29)=2.1,2.1,2.1            !左边长方体
RD(1,30)=2.3,2.3,2.3            !右边长方体

*DIM,H,ARRAY,30,1
H(1,1)=0,3,6,11,23,24,43,44,63,64,83,84,88,103,104
H(16,1)=123,124,143,144,163,164,182.426,183.426,187.426,192.426,207.204,207.654,204.885,200.126,217.654

/PREP7
ET,1,92

!三种围岩
MP,EX,1,TM_YS3      !3类围岩
MP,PRXY,1,MU_YS3
MP,DENS,1,MD_YS3

MP,EX,2,TM_YS4      !4类围岩
MP,PRXY,2,MU_YS4
MP,DENS,2,MD_YS4

MP,EX,3,TM_YS5      !5类围岩
MP,PRXY,3,MU_YS5
MP,DENS,3,MD_YS5

!以下为锚杆加固区
MP,EX,4,TM_MG3
MP,PRXY,4,MU_MG3
MP,DENS,4,MD_MG3

MP,EX,5,TM_MG4
MP,PRXY,5,MU_MG4
MP,DENS,5,MD_MG4

MP,EX,6,TM_MG5
MP,PRXY,6,MU_MG5
MP,DENS,6,MD_MG5

!以下为二次衬砌C25喷砼,包括顶座,壁座,二次衬砌
MP,EX,7,TM_C25
MP,PRXY,7,MU_C25
MP,DENS,7,MD_C25


!DP模型
!以下是3种围岩
TB,DP,1,,,
TBMODIF,1,1,C_YS3
TBMODIF,1,2,FI_YS3
TB,DP,2,,,
TBMODIF,1,1,C_YS4
TBMODIF,1,2,FI_YS4
TB,DP,3,,,
TBMODIF,1,1,C_YS5
TBMODIF,1,2,FI_YS5

!锚杆加固区
TB,DP,4,,,
TBMODIF,1,1,C_MG3
TBMODIF,1,2,FI_MG3
TB,DP,5,,,
TBMODIF,1,1,C_MG4
TBMODIF,1,2,FI_MG4
TB,DP,6,,,
TBMODIF,1,1,C_MG5
TBMODIF,1,2,FI_MG5

!联络风道二次衬砌C25砼
TB,DP,7,,,
TBMODIF,1,1,C_C25
TBMODIF,1,2,FI_C25


!建立圆柱体
LOCAL,11,0,0,0,0,0,90,   !定义局部坐标
WPCSYS,,11
*DO,I,1,23
*DO,J,1,3
CYLIND,RD(J,I),RD(J+1,I),H(I,1),H(I+1,1),180,360
*ENDDO
*ENDDO

!建立长方体
*DO,I,24,26
BLOCK,-RD(1,I),RD(1,I),-RD(1,I),0,H(I,1),H(I+1,1)         !J=1
*ENDDO

*DO,I,24,26
*DO,J,2,3
BLOCK,-RD(J,I),RD(J,I),-RD(J-1,I),-RD(J,I),H(I,1),H(I+1,1)
*ENDDO
*ENDDO

*DO,I,24,26
*DO,J,2,3
BLOCK,RD(J-1,I),RD(J,I),-RD(J-1,I),0,H(I,1),H(I+1,1)
BLOCK,-RD(J-1,I),-RD(J,I),-RD(J-1,I),0,H(I,1),H(I+1,1)
*ENDDO
*ENDDO
!SAVE,SHUJING1,DB             !保存SHUJING1.DB!!!!!!!!!!!!!!!!!!!!!!


CSYS,11                  !加围岩和基岩
WPCSYS,,11
*DO,I,1,23
BLOCK,-LS,0,-WD,0,H(I,1),H(I+1,1)
BLOCK,0,LS,-WD,0,H(I,1),H(I+1,1)
*ENDDO
*DO,I,24,26
BLOCK,-LS,LS,-WD,-RD(3,I),H(I,1),H(I+1,1)
*ENDDO
*DO,I,24,26
BLOCK,-RD(3,I),-LS,0,-RD(3,I),H(I,1),H(I+1,1)
BLOCK,RD(3,I),LS,0,-RD(3,I),H(I,1),H(I+1,1)
*ENDDO

BLOCK,-LS,LS,-WD,0,H(27,1),H(30,1)    !基岩
ALLS
VPTN,ALL
NUMCMP,ALL
!SAVE,SHUJING2,DB       !保存SHUJING2.DB!!!!!!!!!!!!!!!!!!!!!!!!!!!


LOCAL,12,0,-RD(1,25),-H(28,1),0,,,-90
WPCSYS,,12
*DO,I,1,1
CYLIND,RD(I,27),RD(I+1,27),RD(I,25)-RR,LS-RR,90,180
*ENDDO

*DO,I,2,3
CYLIND,RD(I,27),RD(I+1,27),RD(I-1,25)-RR,LS-RR,90,180
*ENDDO

BLOCK,-RD(2,27),0,-RD(1,29),0,0,LS-RR
BLOCK,-RD(2,27),-RD(3,27),-RD(1,29),0,RD(1,25)-RR,LS-RR
BLOCK,-RD(3,27),-RD(4,27),-RD(1,29),0,RD(2,25)-RR,LS-RR

LOCAL,13,0,RD(1,25),-H(29,1),0,,,90
WPCSYS,,13
*DO,I,1,1
CYLIND,RD(I,28),RD(I+1,28),RD(I,25)-RR,LS-RR,0,90
*ENDDO

*DO,I,2,3
CYLIND,RD(I,28),RD(I+1,28),RD(I-1,25)-RR,LS-RR,0,90
*ENDDO

BLOCK,0,RD(2,28),-RD(1,30),0,0,LS-RR
BLOCK,RD(2,28),RD(3,28),-RD(1,30),0,RD(1,25)-RR,LS-RR
BLOCK,RD(3,28),RD(4,28),-RD(1,30),0,RD(2,25)-RR,LS-RR

CSYS,11
WPCSYS,,11
VSEL,S,LOC,Z,H(25,1),H(26,1)
*DO,I,1,3
VSEL,U,LOC,X,(RD(I,25)+LS)/2
VSEL,U,LOC,X,-(RD(I,25)+LS)/2
*ENDDO
CM,V1,VOLU
ALLS

VSEL,S,LOC,Z,H(25,1),H(26,1)
VSEL,U,,,V1
CM,V2,VOLU
ALLS

VSBV,V1,V2,,DELETE,DELETE     !留出风道空隙

!!!!!!!!!!!!!!!!!重复以前建风道的命令!!!!!!!!!!!!!!!!!!!!!!!!!!!!
CSYS,12
WPCSYS,,12
*DO,I,1,1
CYLIND,RD(I,27),RD(I+1,27),RD(I,25)-RR,LS-RR,90,180
*ENDDO

*DO,I,2,3
CYLIND,RD(I,27),RD(I+1,27),RD(I-1,25)-RR,LS-RR,90,180
*ENDDO

BLOCK,-RD(2,27),0,-RD(1,29),0,0,LS-RR
BLOCK,-RD(2,27),-RD(3,27),-RD(1,29),0,RD(1,25)-RR,LS-RR
BLOCK,-RD(3,27),-RD(4,27),-RD(1,29),0,RD(2,25)-RR,LS-RR

CSYS,13
WPCSYS,,13
*DO,I,1,1
CYLIND,RD(I,28),RD(I+1,28),RD(I,25)-RR,LS-RR,0,90
*ENDDO

*DO,I,2,3
CYLIND,RD(I,28),RD(I+1,28),RD(I-1,25)-RR,LS-RR,0,90
*ENDDO

BLOCK,0,RD(2,28),-RD(1,30),0,0,LS-RR
BLOCK,RD(2,28),RD(3,28),-RD(1,30),0,RD(1,25)-RR,LS-RR
BLOCK,RD(3,28),RD(4,28),-RD(1,30),0,RD(2,25)-RR,LS-RR
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ALLS
VGLUE,ALL
NUMCMP,ALL
!SAVE,SHUJING3,DB         !保存SHUJING3.DB!!!!!!!!!!!!!!!!!!!!!!!!

!这里还要把联络风道与二次衬砌交接的地方切断
CSYS,12                     !左边
VSEL,S,LOC,X,-(RD(4,27)+RD(3,27))/2+1,0
VSEL,R,LOC,Z,(LS-RR)/2-2,LS-RR
WPCSYS,,12
WPOFFS,,,RD(2,25)-RD(1,25)
VSBW,ALL,,DELETE

CSYS,13                     !右边
VSEL,S,LOC,Z,(LS-RR)/2-2,(LS-RR)/2
VSEL,R,LOC,X,0,RD(3,29)+0.4
WPCSYS,,13
WPOFFS,,,RD(2,25)-RD(1,25)
VSBW,ALL,,DELETE
ALLS
NUMCMP,ALL

rongzhoutt

!建立组!!!!!!!!!!!!!!!!!!!!!!!!
!1.三种围岩级别
CSYS,11
VSEL,S,LOC,Z,H(1,1),H(3,1)
CM,CM_WY5,VOLU
VSEL,S,LOC,Z,H(3,1),H(11,1)
CM,CM_WY4,VOLU
VSEL,S,LOC,Z,H(11,1),H(30,1)
CM,CM_WY3,VOLU
ALLS
!CMSEL,S,CM_WY5
!CMSEL,A,CM_WY4
!CMSEL,A,CM_WY3
!VPLOT,ALL
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!2.隧道中心部分,分5步开挖,从上到下,从左至右分别为1-5
LOCAL,14,1,0,0,0,0,90,         !局部坐标系14,圆柱
LOCAL,15,1,-RD(1,25),-H(28,1),0,,,-90    !左风道
LOCAL,16,1,RD(1,25),-H(29,1),0,,,90      !右风道

CSYS,14
VSEL,S,LOC,Z,H(1,1),H(11,1)    !这里的hotpoint是形心
VSEL,R,LOC,X,1,2
CM,CM_SD1,VOLU

VSEL,S,LOC,Z,H(11,1),H(24,1)
VSEL,R,LOC,X,1,2
CM,CM_SD2,VOLU

CSYS,11
VSEL,S,LOC,Z,H(24,1),H(26,1)
VSEL,R,LOC,X,0
VSEL,R,LOC,Y,-RR,0
CM,CM_SD3,VOLU

CSYS,12
VSEL,S,LOC,X,0,-RD(2,27)/2
VSEL,R,LOC,Z,0,LS-RR
CM,CM_SD4,VOLU

CSYS,13
VSEL,S,LOC,X,0,RD(2,29)/2
VSEL,R,LOC,Z,0,LS-RR
CM,CM_SD5,VOLU
ALLS
!CMSEL,S,CM_SD1
!CMSEL,A,CM_SD2
!CMSEL,A,CM_SD3
!CMSEL,A,CM_SD4
!CMSEL,A,CM_SD5
!VPLOT,ALL
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!3.二次衬砌!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
CSYS,14
VSEL,S,LOC,Z,H(1,1),H(11,1)    !这里的hotpoint是形心
VSEL,R,LOC,X,2,3
CM,CM_CQ1,VOLU

VSEL,S,LOC,Z,H(11,1),H(24,1)
VSEL,R,LOC,X,2,3
CM,CM_CQ2,VOLU

CSYS,11
VSEL,S,LOC,Z,H(24,1),H(27,1)
VSEL,R,LOC,X,-RD(2,24),RD(2,24)
VSEL,R,LOC,Y,0,-RD(2,24)
VSEL,U,,,CM_SD3
CM,CM_CQ3,VOLU

CSYS,12
VSEL,S,LOC,Y,RD(3,27)/2,-RD(1,29)
VSEL,R,LOC,X,0,-RD(3,27)-1
VSEL,R,LOC,Z,0,LS-RR
VSEL,U,,,CM_SD4
CM,CM_CQ4,VOLU

CSYS,13
ASEL,S,LOC,Y,0
ASEL,R,LOC,Z,0,RD(2,25)-RD(1,25)
ASEL,R,LOC,X,RD(2,28),RD(3,28)
VSLA,S,0
CM,CM_CQ5_1,VOLU
ASEL,S,LOC,Y,0
ASEL,R,LOC,Z,RD(2,25),RD(3,25)
ASEL,R,LOC,X,RD(2,28),RD(3,28)
VSLA,S,0
CM,CM_CQ5_2,VOLU
CMGRP,CM_CQ5,CM_CQ5_1,CM_CQ5_2
!CMSEL,S,CM_CQ1
!CMSEL,A,CM_CQ2
!CMSEL,A,CM_CQ3
!CMSEL,A,CM_CQ4
!CMSEL,A,CM_CQ5
!VPLOT
ALLS
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!交接部位还要单独列出来,以后要改变属性
!5.交接部位
CSYS,12
CMSEL,S,CM_SD4
VSEL,R,LOC,Z,0,RD(2,25)-RD(1,25)
CM,CM_JJ1,VOLU

CSYS,13
CMSEL,S,CM_SD5
VSEL,R,LOC,Z,0,RD(2,25)-RD(1,25)
CM,CM_JJ2,VOLU
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!4.锚杆加固区
!需要知道的数据是H(1,1),H(3,1),H(11,1),H(24,1),H(27,1)
CSYS,14
VSEL,S,LOC,Z,H(1,1),H(3,1)    !这里的hotpoint是形心
VSEL,R,LOC,X,3,5
CM,CM_MG1_1,VOLU

VSEL,S,LOC,Z,H(3,1),H(11,1)
VSEL,R,LOC,X,3,5
CM,CM_MG1_2,VOLU

VSEL,S,LOC,Z,H(11,1),H(24,1)
VSEL,R,LOC,X,3,5
CM,CM_MG2,VOLU

CSYS,11
VSEL,S,LOC,Z,H(24,1),H(27,1)
VSEL,R,LOC,X,-RD(3,24),RD(3,24)
VSEL,R,LOC,Y,0,-RD(3,24)
VSEL,U,,,CM_SD3
VSEL,U,,,CM_CQ3
VSEL,R,LOC,Z,H(24,1),H(26,1)
CM,CM_MG3,VOLU

CSYS,12
ASEL,S,LOC,Y,0
ASEL,R,LOC,X,-RD(3,27),-RD(4,27)
VSLA,S,0
CM,CM_MG4,VOLU

CSYS,13
ASEL,S,LOC,Y,0
ASEL,R,LOC,X,RD(3,28),RD(4,28)
VSLA,S,0
CM,CM_MG5,VOLU
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
SAVE,SHUJING4,DB            !!!!!!!!!!!!!SAVE
ALLS



!!!!!!!!!!!!!开始划分网格!
!!!!!!!!!!!!!!!!!!!!!!!!纵向!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!第一部分
CSYS,11                          !纵向!!!!!!!!!!!!!!
*DO,I,1,1                                  !选择要划分的线
   LSEL,S,LOC,Z,H(I,1)+1E-5,H(I+1,1)-1E-5
*ENDDO
   *DO,I,2,24
       LSEL,A,LOC,Z,H(I,1)+1E-5,H(I+1,1)-1E-5
   *ENDDO
   
*GET,LSNUM,LINE,0,COUNT             !得到总数
*GET,LL,LINE,0,NUM,MIN              !得到最小编号

*DO,I,1,LSNUM
   LSEL,S,,,LL
   KSLL,S
   *GET,KS,KP,0,NUM,MIN
   KM=KPNEXT(KS)
     *IF,DISTKP(KS,KM),LE,2,THEN       !LSINQR(LL,2)查询长度
     LESIZE,ALL,,,1,,1                      !<2m的划一份
     *ELSE
     LESIZE,ALL,4,,,,1                       !>2m的划4m/份
     *ENDIF

      ALLS
       *DO,J,1,1
           LSEL,S,LOC,Z,H(J,1)+1E-5,H(J+1,1)-1E-5
       *ENDDO
          *DO,J,2,24
              LSEL,A,LOC,Z,H(J,1)+1E-5,H(J+1,1)-1E-5
          *ENDDO
     LL=LSNEXT(LL)
*ENDDO
ALLS
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!!!!!!!!!!!!!!!!!!!!弧线!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!第二部分
CSYS,14
LSEL,S,LOC,Y,225                   !弧线，23层
LSEL,A,LOC,Y,315
LSEL,R,LOC,Z,H(1,1)-1E-5,H(23,1)+1E-5
LESIZE,ALL,,,3,,1                            !弧线划3份
ALLS
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!!!!!!!!!!!!!!!!!!!边线!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!第三部分
CSYS,11
LSEL,S,LOC,Z,H(1,1)-1E-7,H(1,1)+1E-7
*DO,I,2,23
LSEL,A,LOC,Z,H(I,1)-1E-7,H(I,1)+1E-7
*ENDDO

*GET,LSNUM,LINE,0,COUNT              !四个最长的边线
*GET,LL,LINE,0,NUM,MIN                    !编号
*DO,I,1,LSNUM                            !LSINQR(LL,2)查询长度
      LSEL,S,,,LL
      KSLL,S
       *GET,KS,KP,0,NUM,MIN
       KM=KPNEXT(KS)
   *IF,DISTKP(KS,KM),LT,LS+1E-7,AND,DISTKP(KS,KM),GT,LS-1E-7,THEN
      LESIZE,ALL,4,,,,1               !4m/份
   *ELSEIF,DISTKP(KS,KM),LT,WD+1E-7,AND,DISTKP(KS,KM),GT,WD-1E-7,THEN
      LESIZE,ALL,4,,,,1               !4m/份
   *ELSE

   *ENDIF
            LSEL,S,LOC,Z,H(1,1)-1E-7,H(1,1)+1E-7
            *DO,J,2,23
            LSEL,A,LOC,Z,H(J,1)-1E-7,H(J,1)+1E-7
            *ENDDO
          LL=LSNEXT(LL)
*ENDDO
ALLS
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!!!!!!!!!!!!!!垂线!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!第四部分
CSYS,14
LSEL,S,LOC,Y,0
LSEL,A,LOC,Y,180
LSEL,A,LOC,Y,270
LSEL,R,LOC,Z,H(1,1)-1E-5,H(23,1)+1E-5
*DO,I,1,24                                 !选择要划分的线
   LSEL,U,LOC,Z,H(I,1)+1E-5,H(I+1,1)-1E-5
*ENDDO

*GET,LSNUM,LINE,0,COUNT
*GET,LL,LINE,0,NUM,MIN
*DO,I,1,LSNUM                            !LSINQR(LL,2)查询长度
      LSEL,S,,,LL
      KSLL,S
       *GET,KS,KP,0,NUM,MIN
       KM=KPNEXT(KS)
   *IF,DISTKP(KS,KM),LT,RR+1E-7,AND,DISTKP(KS,KM),GT,RR-1E-7,THEN
      LESIZE,ALL,,,3,,1                 !中心部分划3份
   *ELSEIF,DISTKP(KS,KM),LE,1,THEN
      LESIZE,ALL,,,1,,1                 !<1m划一份
   *ELSEIF,DISTKP(KS,KM),GE,3.5,THEN
      LESIZE,ALL,,,2,,1
   *ELSE
      LESIZE,ALL,,,2,,1
   *ENDIF
          LSEL,S,LOC,Y,0
          LSEL,A,LOC,Y,180
          LSEL,A,LOC,Y,270
          LSEL,R,LOC,Z,H(1,1)-1E-5,H(23,1)+1E-5
          *DO,J,1,24                                 !选择要划分的线
              LSEL,U,LOC,Z,H(J,1)+1E-5,H(J+1,1)-1E-5
          *ENDDO
              LL=LSNEXT(LL)
*ENDDO
ALLS
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!至此，上部全部划分完毕!!!!!!!!!!!!!!!!!!!!!!!


!!!!!!!!!!!!!!!!!开始下面部分!!!!!!!!!!!!!!!!!!!!!!!
LSEL,S,,,ALL
ESIZE,3
ALLS
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

VSEL,S,,,CM_WY5
VATT,3,1,
MSHKEY,0
MSHAPE,1,3D
VMESH,ALL

VSEL,S,,,CM_WY4
VATT,2,1
MSHKEY,0
MSHAPE,1,3D
VMESH,ALL

VSEL,S,,,CM_WY3
VATT,1,1
MSHKEY,0
MSHAPE,1,3D
VMESH,ALL
FINI
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
SAVE,SHUJING5,DB

!!!!!!!!!!!!!!!!!!!!!开始求解!!!!!!!!!!!!!!!!!!!!!!!!
/SOLU
ACEL,,9.8
ANTYPE,STATIC,NEW
TIME,1
NLGEOM,ON
SSTIF,1
NROPT,FULL
AUTOTS,ON
DELTIM,0.3,0.01,0.5
LNSRCH,ON
PRED,ON
ISWRITE,1              !写初始应力文件
ALLS
!CNVTOL,F,,0.05
OUTRES,ALL,ALL
SOLVE
FINI
SAVE,SHUJING6,DB      !!!!!!!!!!!!!!!SHUJING5.DB原始地应力


!!!!!!!!!!!!!!求解原始地应力!!!!!!!!!!!!!!!
FINI
/CLE
/FILNAM,CALTUN
/PREP7
RESUME,SHUJING5,DB
FINI

/SOLU
ACEL,,9.8
ANTYPE,STATIC,NEW
TIME,1
NLGEOM,ON
SSTIF,1
NROPT,FULL
AUTOTS,ON
DELTIM,0.3,0.01,0.5
LNSRCH,ON
PRED,ON
ISFILE,READ,SHUJING,IST,,0     !写初始应力文件
!CNVTOL,F,,0.05
NCNV,2
ALLS
OUTRES,ALL,ALL
SOLVE
SAVE,SHUJING7,DB       !!!!!!!!!!!!!!保存!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!分布开挖!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!!!!!!!!!!!!!!第一步:开挖第一步并作锚杆加固区!!!!!!!!!!!!!!!!!
ALLS
VSEL,S,,,CM_SD1
VSEL,A,,,CM_CQ1
ESLV,S
EKILL,ALL

ESEL,INVE
NSLE,S,ALL
NSEL,INVE
D,ALL,ALL

VSEL,S,,,CM_MG1_1
ESLV,S
MPCHG,6,ALL

ALLS
TIME,2
SSTIF,1            !打开应力刚化
NLGEOM,ON
NROPT,FULL
AUTOTS,ON
DELTIM,0.3,0.001,0.5
LNSRCH,ON
PRED,ON
NEQIT,30
ALLS
OUTRES,ALL,ALL
SOLV
SAVE,SHUJING8,DB


















!!!!!!!!!!!!!!!!!!!一次全部开挖!!!!!!!!!!!!!!!!!!!!!!
ALLS
VSEL,S,,,CM_SD1
*DO,I,1,4
  VSEL,A,,,CM_SD%I+1%
*ENDDO

*DO,I,1,5
  VSEL,A,,,CM_CQ%I%
*ENDDO
ESLV,S
EKILL,ALL

ESEL,INVE
NSLE,S,ALL
NSEL,INVE
D,ALL,ALL

TIME,2                          !第二个时间步
SSTIF,1                         !打开应力刚化
NLGEOM,ON
NROPT,FULL
AUTOTS,ON
DELTIM,0.3,0.001,0.5
LNSRCH,ON
PRED,ON
NEQIT,30
NCNV,2            !Sets the key to terminate an analysis.
ALLS
CNVTOL,U,,0.08                       !新加的收敛准则
SOLV                !应力完全释放
SAVE,SHUJING9,DB
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

rongzhoutt

版主......你给我分也没用啊............................
怎么没个人来帮我看看这个问题呢??????????
这里高手应该很多的
还是命令流太长了,都不愿意看???

inkey

网格划分有问题,导致NOD1747约束不足

[ 本帖最后由 inkey 于 2007-5-16 16:07 编辑 ]