/TITLE,transform3d2
/PREP7
emunit,mks
ET,1,SOLID97,0 !AZ自由度
ET,2,SOLID97,2 !AZ、CURR自由度
MP,MURX,1,1000
MP,RSVX,1,25e-8
!铁芯材料属性
MP,MURX,2,1
MP,RSVX,2,1.79e-8 !低压绕组材料属性
MP,MURX,3,1
MP,RSVX,3,1.79e-8 !高压绕组材料属性
MP,MURX,4,1
!变压器油材料属性
*SET,Hc,0.285 !铁芯窗高
*SET,dh1,0.07
*SET,D,0.060 !铁芯直径
*SET,M0,0.310 !两铁芯柱间距
*SET,H1,0.145 !低压包线圈高度
*SET,D10,0.072 !低压绕组内直径
*SET,D11,0.136 !低压绕组外直径
*SET,B1,0.0181 !低压绕组幅向厚度
*SET,B11,0.0093 !低压绕组内层幅向厚度
*SET,B12,0.0088 !低压绕组外层幅向厚度
turn1=58 !低压包匝数
sperturn1=23.25e-6 !低压包每匝截面积
*SET,H2,0.145 !高压包线圈高度
*SET,D21,0.190 !高压绕组内直径
*SET,D22,0.290 !高压绕组外直径
*SET,B2,0.0358 !高压绕组幅向厚度
*SET,B21,0.0132 !高压绕组内层幅向厚度
*SET,B22,0.0226 !高压绕组外层幅向厚度
turn2=5816 !高压包匝数
sperturn2=0.2206e-6 !高压包每匝截面积
vperturn=6.3135 !每匝电压
dLs1=0.16 !长度方向上空间
dLs2=0.16 !宽度方向上空间
dLs3=0.32 !高度方向上空间
hfeet=0.015 !铁芯踮脚高度
CYLIND,D/2, ,-(Hc+2*D)/2,(Hc+2*D)/2,0,360, !铁芯柱
VGEN, ,1, , ,-M0, , , , ,1
VGEN,3,1, , ,M0, , , ,1 !移动铁芯柱，并复制两份
WPAVE,0,0,(Hc+D)/2
wprot,0,0,90 !旋转坐标系90度
CYLIND,D/2, ,-(M0+D/2),(M0+D/2),0,360, !上铁轭
WPAVE,0,0,-(Hc+D)/2
CYLIND,D/2, ,-(M0+D/2),(M0+D/2),0,360, !下铁轭
wprot,0,0,-90
WPAVE,0,0,0
NUMCMP,AREA
*get,nnum,kp,,num,max
K,nnum+1,-(M0+D/2),D/2,Hc/2+D,
K,nnum+2,-(M0+D/2),-D/2,Hc/2+D,
K,nnum+3,-(M0-D/2),-D/2,Hc/2,
K,nnum+4,-(M0-D/2),D/2,Hc/2,
A,nnum+1,nnum+2,nnum+3,nnum+4
K,nnum+5,-(M0+D/2),D/2,-(Hc/2+D),
K,nnum+6,-(M0+D/2),-D/2,-(Hc/2+D),
K,nnum+7,-(M0-D/2),-D/2,-Hc/2,
K,nnum+8,-(M0-D/2),D/2,-Hc/2,
A,nnum+5,nnum+6,nnum+7,nnum+8
K,nnum+9,(M0+D/2),D/2,Hc/2+D,
K,nnum+10,(M0+D/2),-D/2,Hc/2+D,
K,nnum+11,(M0-D/2),-D/2,Hc/2,
K,nnum+12,(M0-D/2),D/2,Hc/2,
A,nnum+9,nnum+10,nnum+11,nnum+12
K,nnum+13,(M0+D/2),D/2,-(Hc/2+D),
K,nnum+14,(M0+D/2),-D/2,-(Hc/2+D),
K,nnum+15,(M0-D/2),-D/2,-Hc/2,
K,nnum+16,(M0-D/2),D/2,-Hc/2,
A,nnum+13,nnum+14,nnum+15,nnum+16
K,nnum+17,D/2,D/2,Hc/2+D,
K,nnum+18,D/2,-D/2,Hc/2+D,
K,nnum+19,-D/2,-D/2,Hc/2,
K,nnum+20,-D/2,D/2,Hc/2,
A,nnum+17,nnum+18,nnum+19,nnum+20
K,nnum+21,D/2,D/2,-(Hc/2+D),
K,nnum+22,D/2,-D/2,-(Hc/2+D),
K,nnum+23,-D/2,-D/2,-Hc/2,
K,nnum+24,-D/2,D/2,-Hc/2,
A,nnum+21,nnum+22,nnum+23,nnum+24
K,nnum+25,0,D/2,Hc/2+D/2,
K,nnum+26,0,-D/2,Hc/2+D/2,
K,nnum+27,D/2,-D/2,Hc/2,
K,nnum+28,D/2,D/2,Hc/2,
A,nnum+25,nnum+26,nnum+27,nnum+28
K,nnum+29,0,D/2,-(Hc/2+D/2),
K,nnum+30,0,-D/2,-(Hc/2+D/2),
K,nnum+31,D/2,-D/2,-Hc/2,
K,nnum+32,D/2,D/2,-Hc/2,
A,nnum+29,nnum+30,nnum+31,nnum+32
*get,anum,area,,num,max
asel,s,,,anum
asel,a,,,anum-1
asel,a,,,anum-2
asel,a,,,anum-3
asel,a,,,anum-4
asel,a,,,anum-5
asel,a,,,anum-6
asel,a,,,anum-7
cm,subarea,area
allsel,all
vsba,all,subarea
ALLSEL,ALL
asel,s,loc,x,-(M0+D/2)
vsla,s
vdele,all
ALLSEL,ALL
asel,s,loc,x,M0+D/2
vsla,s
vdele,all
ALLSEL,ALL
asel,s,loc,z,-(Hc/2+D)
vsla,s
vdele,all
ALLSEL,ALL
asel,s,loc,z,Hc/2+D
vsla,s
vdele,all
ALLSEL,ALL
NUMCMP,VOLU
vdele,3,6
ALLSEL,ALL
vglue,all
vplot !显示切割后的体
CYLIND,D10/2,D11/2,-H1/2,H1/2,0,360, !低压绕组
ASEL,S,LOC,Y,D10/2,D11/2
VSLA,s
CM,lowA,VOLU !移动低压包，并复制两份
VGEN, ,all, , ,-M0, , , , ,1 !复制到X坐标为-MO位置
VGEN,3,all, , ,M0, , , ,1
ALLSEL,ALL
ASEL,S,LOC,y,D10/2,D11/2
ASEL,r,LOC,x,0
VSLA,s
CM,lowB,VOLU
ASEL,S,LOC,y,D10/2,D11/2
ASEL,r,LOC,x,M0
VSLA,s
CM,lowC,VOLU
CYLIND,D21/2,D22/2,-H2/2,H2/2,0,360, !高压绕组
ASEL,S,LOC,Y,D21/2,D22/2
VSLA,s
CM,highA,VOLU
VGEN, ,all, , ,-M0, , , , ,1
VGEN,3,all, , ,M0, , , ,1 !移动高压包，并复制两份
ALLSEL,ALL
vplot
ASEL,S,LOC,y,D21/2,D22/2
ASEL,r,LOC,x,0
VSLA,s
CM,highB,VOLU
ASEL,S,LOC,y,D21/2,D22/2
ASEL,r,LOC,x,M0
VSLA,s
CM,highC,VOLU
BLOCK,-(2*M0+D22+dLs1)/2,(2*M0+D22+dLs1)/2,-(D22+dLs2)/2,(D22+dLs2)/2,-(Hc/2+D+hfeet),(Hc/2+D+dLs3-hfeet), !变压器油建模
allsel,all
VOVLAP,all
care1=B1*H1 !低压包截面积
CSYM1=1 !绕组对称系数
FILL1=sperturn1*turn1/care1 !绕组填充系数
r,21,care1,turn1,vperturn,0,1,0, !低压包实常数
RMORE,CSYM1,FILL1,
care2=B2*H2 !高压包截面积
CSYM2=1 !绕组对称系数
FILL2=sperturn2*turn2/care2 !绕组填充系数
r,22,care2,turn2,vperturn,0,1,0, !高压包实常数
RMORE,CSYM2,FILL2,
LOCAL,111,1,-M0,0,0, , , ,1,1, !建立柱坐标系
CSYS,111,
cmsel,s,lowA,volu
vatt,2,21,2,111 !给所选择的体设置划分网格单元属性
LOCAL,112,1,0,0,0, , , ,1,1, !建立柱坐标系
CSYS,112,
cmsel,s,lowB,volu
vatt,2,21,2,112
LOCAL,113,1,+M0,0,0, , , ,1,1, !建立柱坐标系
CSYS,113,
cmsel,s,lowC,volu
vatt,2,21,2,113
LOCAL,114,1,-M0,0,0, , , ,1,1, !建立柱坐标系
CSYS,114,
cmsel,s,highA,volu
vatt,3,22,2,114
LOCAL,115,1,0,0,0, , , ,1,1, !建立柱坐标系
CSYS,115,
cmsel,s,highB,volu
vatt,3,22,2,115
LOCAL,116,1,+M0,0,0, , , ,1,1, !建立柱坐标系
CSYS,116,
cmsel,s,highC,volu
vatt,3,22,2,116
ALLSEL,ALL
CSYS,0, !变压器油
asel,s,loc,x,(2*M0+D22+dLs1)/2
VSLA,s
vatt,4,,1,0
cm,oil,volu
ALLSEL,ALL
cmsel,u,lowA
cmsel,u,lowB
cmsel,u,lowC
cmsel,u,highA
cmsel,u,highB
cmsel,u,highC
cmsel,u,oil
vatt,1,,1,0
cm,core,volu
!划分网格
cmsel,s,lowA,volu
cmsel,a,lowB,volu
cmsel,a,lowC,volu
cmsel,a,highA,volu
cmsel,a,highB,volu
cmsel,a,highC,volu
SMRTsize,4
vsweep,all,,1 !高低压包划分网格
cmsel,s,core,volu !铁心网格划分
cmsel,a,oil,volu
SMRTsize,10
MSHAPE,1,3D !设置网格和单元为四面体单元
MSHKEY,0 !设置自由网格划分
VMESH,ALL
et,4,circu124,5 !绞线圈电流源
et,5,circu124,2 !电容
et,6,circu124,4,1 !独立电压源
et,7,circu124,4,1 !独立电压源
et,13,circu124,0 !连线电阻
r,4,1
r,5,1/25981.58/2/3.1415/400 !电容值
r,6,,353.6,400,,-120, !(lowA)幅值，频率和相位
r,7,,353.6,400,,0,
r,8,,353.6,400,,+120,
r,9,,36722,400,,-120,
r,10,,36722,400,,0,
r,11,,36722,400,,+120,
r,13,1e-10 !连线电阻
N,,-M0,D10/2,Hc/2-dh1
*get,naff,node,,num,max
N,,-M0,-D11/2,Hc/2-dh1
*get,nafs,node,,num,max
N,,0,D10/2,Hc/2-dh1
*get,nbff,node,,num,max
N,,0,-D11/2,Hc/2-dh1
*get,nbfs,node,,num,max
N,,+M0,D10/2,Hc/2-dh1
*get,ncff,node,,num,max
N,,+M0,-D11/2,Hc/2-dh1 !低压包6个接头节点
*get,ncfs,node,,num,max
N,,-M0,-D22/2,-(Hc/2-dh1)
*get,nass,node,,num,max
N,,0,-D22/2,-(Hc/2-dh1)
*get,nbss,node,,num,max
N,,+M0,-D22/2,-(Hc/2-dh1)
*get,ncss,node,,num,max
N,,0,-D21/2,Hc/2-dh1 !高压包4个接头节点
*get,nn0,node,,num,max
D,nn0,volt,0 !副边中性点接地
type,13
real,13
e,nafs,nbff
e,nbfs,ncff
e,ncfs,naff
cmsel,s,lowA,volu
nslv,s,1
*get,nafmin,node,,num,min
cp,next,CURR,all
N,,-M0,(D10-D11)/4,Hc/2+2*D
*get,nan,node,,num,max
type,6
real,6
e,naff,nafs,nan !独立电压源
type,4
real,4
e,naff,nafs,nafmin !绞线圈电流源
cmsel,s,lowB,volu
nslv,s,1
*get,nbfmin,node,,num,min
cp,next,CURR,all
N,,0,(D10-D11)/4,Hc/2+2*D
*get,nbn,node,,num,max
type,6
real,7
e,nbff,nbfs,nbn
type,4
real,4
e,nbff,nbfs,nbfmin
cmsel,s,lowC,volu
nslv,s,1
*get,ncfmin,node,,num,min
cp,next,CURR,all
N,,+M0,(D10-D11)/4,Hc/2+2*D
*get,ncn,node,,num,max
type,6
real,8
e,ncff,ncfs,ncn
type,4
real,4
e,ncff,ncfs,ncfmin
cmsel,s,highA,volu
nslv,s,1
*get,nasmin,node,,num,min
cp,next,CURR,all
type,5
real,5
e,nass,nn0
type,4
real,4
e,nass,nn0,nasmin
cmsel,s,highB,volu
nslv,s,1
*get,nbsmin,node,,num,min
cp,next,CURR,all
type,5
real,5
e,nbss,nn0
type,4
real,4
e,nbss,nn0,nbsmin
cmsel,s,highC,volu
nslv,s,1
*get,ncsmin,node,,num,min
cp,next,CURR,all
type,5
real,5
e,ncss,nn0
type,4
real,4
e,ncss,nn0,ncsmin
finish
/solu
ANTYPE,TRANS
eqslv,sparse !选择系数矩阵求解器
allsel,all
time,0.001
deltim,0.0005
OUTRES,ALL,ALL,
solve
/post1
finish
/POST26
NSOL,2,1,CURR, ,CurrA
NSOL,3,241,CURR, ,CurrB
PLVAR,2,3,,, |
IP卡
狗仔卡
发表于 2008-10-22 09:20:07
提升卡
沉默卡
喧嚣卡
变色卡
抢沙发
千斤顶
显身卡