!Y=-5.50/7500**2*(X-7500)**2-2.50
FINISH
/CLEAR,START
!建模
!单位:米
X1=0
L=75
X3=1
TT=L/X3
T1=0.30
T2=0.50
T3=0.35
T4=0.80
T5=(T4-T3)/TT
/PREP7
/TITLE,BOX GIRDER WITH VARYING DEPTH
!定义顶板关键点
*DO,Z,-3,3,6
*DO,X,X1,L,X3
k,,X,0,Z
*ENDDO
*ENDDO
CM,TK,KP
KSEL,NONE
!定义底板关键点
*DO,Z,3,-3,-6
*DO,X,X1,L,X3
Y=-5.50/L**2*(X-L)**2-2.50
K,,X,Y,Z
*ENDDO
*ENDDO
CM,BK,KP
ALLSEL,ALL
*DO,I,1,TT+1,1
L,I,I+TT+1
L,I+TT+1,I+2*(TT+1)
L,I+2*(TT+1),I+3*(TT+1)
L,I+3*(TT+1),I
*ENDDO
*DO,I,1,TT,1
L,I,I+1
L,I+TT+1,I+TT+2
L,I+2*(TT+1),I+2*(TT+1)+1
L,I+3*(TT+1),I+3*(TT+1)+1
*ENDDO
*DO,I,1,4*(TT-1)+1,4
AL,I,I+4*(TT+1)+1,I+4,I+4*(TT+1)
AL,I+1,I+4*(TT+1)+2,I+5,I+4*(TT+1)+1
AL,I+2,I+4*(TT+1)+3,I+6,I+4*(TT+1)+2
AL,I+3,I+4*(TT+1)+3,I+7,I+4*(TT+1)
*ENDDO
*DO,Z,-6,6,12
*DO,X,X1,L,X3
k,,X,0,Z
*ENDDO
*ENDDO
*DO,I,1,(TT+1),1
L,I,I+4*(TT+1)
L,I+(TT+1),I+5*(TT+1)
*ENDDO
*DO,I,1,TT,1
L,I+4*(TT+1),I+4*(TT+1)+1
L,I+5*(TT+1),I+5*(TT+1)+1
*ENDDO
*DO,I,1,4*(TT-1)+1,4
AL,(I-1)/2+8*(TT+1)-3,I+4*(TT+1),(I-1)/2+8*(TT+1)-1,(I-1)/2+10*(TT+1)-3
AL,(I-1)/2+8*(TT+1)-2,(I-1)/2+10*(TT+1)-2,(I-1)/2+8*(TT+1),I+4*(TT+1)+1
*ENDDO
!定义材料
ET,1,SHELL63
MP,EX,1,34.5E9
MP,PRXY,1,0.1667
MP,DENS,1,2600
R,1,T1
R,2,T2
*DO,I,1,TT,1
R,I+2,T4-(I-1)*T5,T4-(I-1)*T5,T4-I*T5,T4-I*T5
*ENDDO
!对顶板划分
ASEL,S,LOC,Y,0
LSEL,S,LOC,Y,0
LESIZE,ALL,X3,,,,,,,1
AATT,1,1,1
AMESH,ALL
CM,TBOARD,ELEM !顶板单元分组
ALLSEL,ALL
!对侧板划分
CMSEL,S,BK
LSLK,S
KSEL,ALL
CMSEL,S,TK
LSLK,U
CM,BL,LINE
LSEL,R,LOC,Z,-3
LESIZE,ALL,,,1,,,,,1
ALLSEL,ALL
CMSEL,S,BL
LSEL,R,LOC,Z,3
LESIZE,ALL,,,1,,,,,1
ALLSEL,ALL
CMSEL,S,TK
LSLK,S
LSEL,U,LOC,Y,0
LESIZE,ALL,X3,,,,,,,1
ALLSEL,ALL
LSEL,S,LOC,Z,-3
LSEL,A,LOC,Z,3
ASEL,S,LOC,Z,-3
ASEL,A,LOC,Z,3
CM,LA,AREA
AATT,1,2,1
AMESH,ALL
CMSEL,S,LA !侧板面分组
ESLA,S
CM,LBOARD,ELEM !侧板单元分组
ALLSEL,ALL
!对底板划分
CMSEL,S,BL
LSEL,U,LOC,Z,-3
LSEL,U,LOC,Z,3
LESIZE,ALL,X3,,,,,,,1
ALLSEL,ALL
ASEL,U,LOC,Y,0
ASEL,U,LOC,Z,-3
ASEL,U,LOC,Z,3
CM,BA,AREA !底板面分组
*DO,I,1,TT,1
ASEL,S,AREA, ,I*4-1
AATT,1,I+2,1
AMESH,ALL
ALLSEL,ALL
*ENDDO
CMSEL,S,BA
ESLA,S
CM,BBOARD,ELEM !底板单元分组 |