基于ansys的可靠性分析（完整命令流有点错误请高手修改下）

西风独自凉

FINISH
/CLEAR
!环境设置
/FILN,RELIABILITY
/TITLE,RELIABILITY DESIGN OF QUNZUO   
!定义参数
*SET,R1,1406.5                  !筒体内半径
*SET,T1,87                      !筒体壁厚
*SET,R2,1424                    !球封头内半径
*SET,T2,52                      !球封头壁厚
*SET,T3,22                      !裙座壁厚
*SET,R,20                       !过渡圆角半径
*SET,H,568                      !锻造高度
*SET,P,8.83                     !内压值
P1=P*R1*R1/((R1+T1)**2-R1*R1)   !端部面力
*SET,YIES,190                   !屈服强度
!前处理
/PREP7  
ET,1,PLANE82                    !定义PLANE82单元
KEYOPT,1,3,1                    !设定轴对称选项
MP,EX,1,1.75E5                  !材料的弹性模量
MP,PRXY,1,0.3                   !材料的泊松比
*AFUN,DEG                       !设定角度单位为度
ANGLE=ASIN(H/R2)                !构造段角度
PCIRC,R2,R2+T2,270,(360-ANGLE)  !球封头圆弧段
BLC4,R1,0,T1,R1                 !筒体直线段
*GET,XLOC,KP,2,LOC,X            !获得关键点2的X坐标（为支撑段矩形角点X坐标）
*GET,YLOC,KP,2,LOC,Y            !获得关键点2的Y坐标（为支撑段矩形角点Y坐标）
BLC4,R1+T1-T3,YLOC,T3,H-R2      !裙座支撑段
!建立H型锻件
K,,XLOC,YLOC+R                  !以2号关键点X坐标为基，Y坐标+过渡半径R建立关键点
K,,R1+T1-T3,YLOC+R              !以支撑段左角点X坐标为基，Y坐标+过渡半径R建立关键点
!找出圆弧与直线过渡段交点
ANGLE2=ACOS(R1/R2)              !过渡段角度
CSYS,1                          !激活极坐标系
K,,R2,-ANGLE2                   !定义过渡段位置关键点
L,3,15                          !连接过渡圆弧段
CSYS,0                          !激活直角坐标系
!连线构成H面
L,2,13,11                                             
L,13,14,1
L,14,12,2
L,6,11,5
L,5,15,10
LFILLT,14,15,R,,                !在14与15两线段建立倒角(H型构件)
LFILLT,15,16,R,,                !在15与16两线段建立倒角(H型构件)
KDELE,13                        !删除辅助点
AL,5,13,15,2,19,14,11,18,17     !通过线段定义面
AADD,ALL                        !面叠加
!采用坐标平面化分面
NUMMRG,ALL                      !对各元素重新编号
NUMCMP,ALL                      !对编号压缩
KWPAVE,13                       !将坐标系原点移位于13号关键点
WPROT,0,-90,0                   !将平面按照X轴旋转-90度
ASBW,ALL,                       !采用坐标平面剖分面
KWPAVE,2                        !将坐标系原点移位于2号关键点
ASBW,ALL,                       !采用坐标平面剖分面
!划分网格
ASEL,S,AREA,,4,5,1              !选择4,5号面(即构造段)
ESIZE,10,0                      !设定单元大小为10
MSHAPE,0,2D                     !采用四边形单元划分网格
MSHKEY,0                        !采用自由网格划分
AMESH,ALL                       !划分面4，5
ASEL,ALL                        !选中所有的面
ASEL,U,AREA,,4,5,1              !除去4，5号面，即构造段之外面
ESIZE,16,0                      !设定单元大小为16
AMESH,ALL                       !划分面
FINISH  
!求解模块
/SOLU   
!施加约束
NSEL,S,LOC,X,0                       !选择X坐标为0的节点
DSYM,SYMM,X                          !施加X方向对称约束
LSEL,S,LINE,,7                       !选择编号为7线段（支撑段底端）
NSLL,S,1                             !选中依附在选段上的节点
D,ALL,UY,0                           !将其Y方向位移限制为0
!施加载荷
!对内壁6，10，14，21，19五条线段上的节点施加压力P
LSEL,S,LINE,,6,14,4                  
LSEL,A,LINE,,19,21,2
NSLL,S,1                              !选中依附在选段上的节点
SF,ALL,PRES,P                         !施加均布载荷
LSEL,S,LINE,,5                         !选择线段5（即筒体端部）
NSLL,S,1                               !选中依附在选段上的节点
SF,ALL,PRES,-P1                        !对其施加压力为-P1
ALLSEL                                 !选中所有元素
SOLVE                                  !求解
SAVE,RELIABILITY_RESULT                !保存DB文件  
FINISH                                 !退出求解器
!后处理
/POST1
NSORT,S,EQV                        !等效应力按降序排列
*GET,MAXSTR,SORT,,MAX              !取出最大等效应力
Z=YIES-MAXSTR                      !定义极限状态方程Z(X)=σS-σEMAX
LGWRITE,RELIABILITY,TXT            !定义概率分析文件
FINISH
/PDS                               !进入概率分析模块
PDANL,'RELIABILITY','TXT',' '      !选定分析文件
PDVAR,P,GAUS,8.83,0.6,0,0           !载荷为高斯分布，均值为8.83MPA，标准差为0.6MPA
PDVAR,R1,UNIF,1403,1410             !筒体内半径为均匀分布，最小1403，最大1410
PDVAR,R2,UNIF,1420,1428             !球封头内半径为均匀分布，最小1420，最大1428
PDVAR,T1,GAUS,87,0.35,0,0           !筒体壁厚为高斯分布，均值为87MM，标准差为0.35MM
PDVAR,T2,GAUS,52,0.3,0,0            !球封头壁厚为高斯分布，均值为52MM，标准差为0.3MM
PDVAR,T3,GAUS,22,0.2,0,0            !裙座壁厚为高斯分布，均值为22MM，标准差为0.2MM
PDVAR,R,GAUS,20,0.18,0,0            !过渡圆角半径为高斯分布，均值为20MM，标准差为0.18MM
PDVAR,H,GAUS,568,3,0,0              !锻造高度为高斯分布，均值为568MM，标准差为3MM
PDVAR,YIES,GAUS,190,12,0,0          !材料屈服极限为高斯分布，均值为190MPA，标准差为12MPA
PDVAR,Z,RESP                        !定义Z为输出随机变量
PDVAR,MAXSTR,RESP                   !定义MAXSTR为输出随机变量
PDMETH,MCS,LHS                      !选择分析方法为M.C.方法
PDLHS,500,1,RAND, ,'ALL ', , , ,CONT !定义抽样50,000次
PDEXE
PDPROB,SOLU01,Z,LT,0,'    ',0.95,   !查看Z小于0、置信度为95%时的概率
PDPROB,SOLU01,MAXSTR,GT,190,'    ',0.95,
PDCDF,,Z,EMP,0.95,100               !绘图显示Z的分布函数
PDCDF,,MAXSTR,EMP,0.95,100          !绘图显示MAXSTR的分布函数
PDSHIS,,MAXSTR,MEAN,0.95            !抽样过程显示
PDHIST,,MAXSTR,                     !绘制MAXSTR取值分布柱状图
PDSENS,,MAXSTR                      !输出变量MAXSTR灵敏度显示
PDHIST,,P,                          !绘制P取值分布柱状图
PDCMAT,,IO,,,RANK,,1                !列表显示相关系数和概率

cccjob699

支持原创，谢谢分享

少林野狼

正好在做可靠性这块的课题，学习一下

翎姿展翅

感谢楼主的分享，让我学习了！

刘彭

还是可以的:)

yingwuluo1989

概率分析，目前很值得研究哦

cumtjnly

小弟受教了！！！！