wangmingdi 发表于 2011-11-15 06:09
我用inter单元做了,仔细阅读了TBDATA, 但是材料属性一直附加不到单元上去,你是怎么做到的?能否指教? ...
楼主是用命令做的吗?我把我做的一个简单的例子贴上来,看看对你有没有帮助。
FINISH
/CLEAR,START
/TITLE,`PRACTICE`
/PREP7
LOCAL,45,,0,0,0,45,
LOCAL,315,,0,0,0,-45,
LOCAL,90,,0,0,0,90
ET,50,MESH200,7
ET,51,MESH200,11
MP,EX,1,156300
MP,EY,1,8900
MP,EZ,1,8900
MP,PRXY,1,0.34
MP,PRXZ,1,0.34
MP,PRYZ,1,0.45
MP,GXY,1,5600
MP,GXZ,1,5600
MP,GYZ,1,3070
TB,CZM,2
TBDATA,1,20,0.025,0.0086
!make the 2Dmodel
TYPE,50
RECTNG,0,1,0,1
ESIZE,1 !control the size of the elements
MSHKEY,1
AMESH,ALL
!make the 3Dmodel
ASEL,S,,,ALL,,,0
CM,A1,AREA
TYPE,51
ESIZE,1 !control the thickness
VEXT,A1,,,0,0,2, !control the thickness
VSWEEP,ALL,,,
CMSEL,S,A1
ACLEAR,ALL
!add the element type
ET,1,SOLID186
ET,2,SOLID186
ET,102,INTER204
!change the element type
*DO,i,1,2
ALLSEL,ALL
NSEL,S,LOC,Z,i-1
NSEL,A,LOC,Z,i
NSEL,A,LOC,Z,i-0.5
ESLN,R,1
EMODIF,ALL,TYPE,i
EMODIF,ALL,MAT,1
*ENDDO
!create and mesh an interface area by cohesive zone elements.
ALLSEL,ALL
NSEL,S,LOC,Z,1
ESEL,S,TYPE,,1
ESLN,R
CM,TARG,ELEM
ALLSEL,ALL
NSEL,S,LOC,Z,1
ESEL,S,TYPE,,2
ESLN,R
CM,CONT,ELEM
ALLSEL
MAT,2
TYPE,102
CZMESH,TARG,CONT,,,
NUMCMP,ELEM
NUMCMP,NODE
/SOLU
ANTYPE,STATIC
OUTRES,ALL,LAST
ALLSEL,ALL
CSYS,0
NSEL,S,LOC,Z,0
D,ALL,UZ,0
NSEL,S,LOC,X,0
D,ALL,UX,0
NSEL,S,LOC,Y,0
D,ALL,UY,0
ALLSEL,ALL
tim=0
*DO,i,1,200
tim=tim+0.005
TIME,tim
NSEL,S,LOC,Z,2
D,ALL,UZ,0.005*i
OUTRES,ALL,ALL
ALLSEL,ALL
SOLVE
*ENDDO
*DO,i,1,199
tim=tim+0.005
TIME,tim
NSEL,S,LOC,Z,2
D,ALL,UZ,0.95-0.005*i
OUTRES,ALL,ALL
ALLSEL,ALL
SOLVE
*ENDDO
FINISH
/POST1 |