坐标系练习－各向异性材料

feasky

如图，一悬臂梁为各向异性材料，已知材料属性（柔顺常数）为：
S11＝S22=12.3E-12, S12=-4.05E-12, S13=S23=-5.31E-12, S33=15.5E-12, S44=S55=39E-12, S66=32.7E-12

（矩阵对称，其它系数为0）

其中，其中1，2，3，4，5，6方向如图所示，求在曲梁的外表面均布荷载作用下，求端部轴向位移，即θ方向的位移。

练习目的：各向异性材料的建模；坐标系的操作

说明：可以简化为平面问题，比如平面应变，如果不想简化，则梁在Z方向厚度自己随便定。

加分：要求正确无误时。
         1.给出APDL加1-2分；
         2.给出APDL和说明（可以含图），加2-3分；

各位，请为本版繁荣加油！

feaman117

柔顺常数是什么不是nuxy,prxy?是什么,怎么这么小e-12?

feasky

nuxy是泊松比，这个是柔度矩阵是弹性矩阵的逆矩阵，也就是用应力表示应变的系数矩阵。对称的：）

mayaolun

FINI
/CLE

!进入前处理器
/PREP7

!定义单元,支持材料自定义的刚度（柔度）矩阵的平面单元只有四节点182和八节点183，在此选用183
ET,1,183
!分析类型为平面应变
KEYOPT,1,3,2

!定义材料自定义柔度矩阵
TB,ANEL,1,1,21,1
TBTEMP,0
TBDATA,,12.3E-12,-4.05E-12,-5.31E-12,0,0,0
TBDATA,,12.3E-12,-5.31E-12,0,0,0,15.5E-12
TBDATA,,0,0,0,39E-12,0,0
TBDATA,,39E-12,0,32.7E-12

!定义模型并划分网格
CYL4,0,0,2,0,2.2,90
MSHAPE,0,2D
MSHKEY,1
LESIZE,1,0.1
LESIZE,2,,,4

!自定义柱坐标系
CSWPLA,11,1,1,1

!赋予几个模型材料，（划分网格）坐标系
AATT,1,,1,11
AMESH,ALL

!施加载荷
DL,2,,ALL
SFL,1,PRES,-10

!进入求解器并求解
/SOLU
ANTYPE,0
SOLVE

!进入后处理器，并观看结果
/POST1

RSYS,11
PLNSOL,U,Y

feasky

解决该问题的关键在于“坐标系的掌握”，希望有更多的人给出更加精简的代码。重复上面mayaolun 的思路则给分可能少一些或者不给分。

同时还希望有人能提出典型的问题，尽量把问题说清楚和详细，可以给予1分鼓励。

hmily

参照上面，我也做一个

finish
/clear,nostart

!进入前处理器
/prep7

!定义单元
ET,1,182
!分析类型为平面应变
KEYOPT,1,3,2

!定义材料自定义柔度矩阵
TB,ANEL,1,1,21,1
TBTEMP,0
TBDATA,,12.3E-12,-4.05E-12,-5.31E-12,0,0,0
TBDATA,,12.3E-12,-5.31E-12,0,0,0,15.5E-12
TBDATA,,0,0,0,39E-12,0,0
TBDATA,,39E-12,0,32.7E-12

!直接有限元模型，先建立节点
csys,1
n,1,2,,,
n,61,2,90,,
fill
ngen,5,61,1,61,1,0.05

!生成单元
e,1,2,63,62
egen,60,1,1
egen,4,61,1,60,1

!施加载荷
d,61,all,,,605,61
esel,s,elem,,181,240
sfe,all,3,PRES,,-10
esel,all

!进入求解器并求解
/solu

antype,static
solve

!进入后处理器，并观看结果
/post1

rsys,1
plnsol,u,y

pizzachan

mayaolun   和  hmily 的图为什么不同啊？
一个的颜色过渡那么平滑，一个那么粗糙，是需要在哪里设置 吗？

skullsadbones

/GRAPHICS,POWER设置的问题.

请问各向异性材料的实际意义是什么，通过TB,ANEL 对柔度系数的设置的实际物理意义是什么？

wei1012

首先我回答楼上朋友的问题：为什么均匀程度不一样的原因是他们采用的两种单元的节点数不一样，plane183比182多了中节点，所以结果要均匀！
大家注意我给出的例子，结果接近plane183，但是我是采用plane182单元进行分析，分析原理是一样的！
我利用 的是刚度矩阵，我采用了ansys的矩阵求解，求出刚度矩阵，然后利用ansys中的隐含语句直接建立有限元模型，进行分析!下面给出命令流！
备注：命令流中的苦瓜脸不知道怎么删除，苦瓜脸对应的是 ： （
/prep7
！进行矩阵换算，求出对应题目的柔度矩阵的刚度矩阵
*dim,c,,6,6
*do,j,1,6
  *do,i,1,6
   c(i,j)=0
  *enddo
*enddo
c(1,1)=12.3e-12
c(2,2)=12.3e-12
c(1,2)=-4.05e-12
c(2,1)=-4.05e-12
c(1,3)=-5.31e-12
c(2,3)=-5.31e-12
c(3,1)=-5.31e-12
c(3,2)=-5.31e-12
c(3,3)=15.5e-12
c(4,4)=39e-12
c(5,5)=39e-12
c(6,6)=32.7e-12
*moper,c,c,invert   ！求逆矩阵，并将原来的c矩阵覆盖

ET,1,PLANE182   
KEYOPT,1,3,2
！定义刚度矩阵，来实现各项异性
TB,ANEL,1,1,21,0
TBTEMP,0
TBDATA,,c(1,1),c(1,2),c(1,3),c(1,4),c(1,5),c(1,6)   
TBDATA,,c(2,2),c(2,3),c(2,4),c(2,5),c(2,6),c(3,3)   
TBDATA,,c(3,4),c(3,5),c(3,6),c(4,4),c(4,5),c(4,6)   
TBDATA,,c(5,5),c(5,6),c(6,6)
！有限元建模
csys,1
*do,i,0,4
n,,2+0.05*i,(0:90:3)
*enddo
*do,i,0,3
s=31*i
e,((125-s)154-s)),((126-s):(155-s)),((95-s):(124-s)),((94-s):(123-s))
*enddo
!施加载荷
d,31,all,,,155,31
esel,s,elem,,1,30
sfe,all,1,PRES,,-10
!进入求解器并求解
/solu
allsel
solve
!进入后处理器，并观看结果
/post1
rsys,1
plnsol,u,y

--------------
你所说的苦瓜脸，在编辑的时候选中以下两项
禁止在这个帖子中使用 Jute 标记
禁止在这个帖子中使用笑脸标记

maomaoface

可是把mayaolun的命令中关于柱坐标的部分换成默认的笛卡尔坐标系，运行结果与柱坐标下的结果一样。
即运行如下的命令：
/PREP7

ET,1,183
!分析类型为平面应变
KEYOPT,1,3,2

!定义材料自定义柔度矩阵
TB,ANEL,1,1,21,1
TBTEMP,0
TBDATA,,12.3E-12,-4.05E-12,-5.31E-12,0,0,0
TBDATA,,12.3E-12,-5.31E-12,0,0,0,15.5E-12
TBDATA,,0,0,0,39E-12,0,0
TBDATA,,39E-12,0,32.7E-12

!定义模型并划分网格
CYL4,0,0,2,0,2.2,90
MSHAPE,0,2D
MSHKEY,1
LESIZE,1,0.1
LESIZE,2,,,4

!自定义柱坐标系
!CSWPLA,11,1,1,1

!赋予几个模型材料，（划分网格）坐标系
aatt,1,,1
!AATT,1,,1,11
AMESH,ALL

!施加载荷
DL,2,,ALL
SFL,1,PRES,-10

!进入求解器并求解
/SOLU
ANTYPE,0
SOLVE

!进入后处理器，并观看结果
/POST1

!RSYS,11
PLNSOL,U,Y
得到的结果一样，那为什么还要定义柱坐标呢？

whosru

get some preps, thx a lot

raineryoung

平面问题的各向异性常数不是只有6个嘛？？
s11 s12 s16
      s22 s26
            s66

为什么这里给了9个？

另外ansys里要求输入10个？
For 2-D problems, a 4 x 4 matrix relates terms ordered x, y, z, xy via 10 constants (D11, D21, D22, D31, D32, D33, D41, D42, D43, D44).

谁能解答一下 谢谢