[原创]应用CFD模块求解温度场

freefly_123

问题描述：分析求解自然对流下多个恒定热源的稳态温度分布
模型特征：轴对称
分析结果：

freefly_123

分析结果：

freefly_123

分析结果

freefly_123

局部结果：

freefly_123

命令流（未经许可勿转载www.simwe.com）：
!ANSYS初始化
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
/units,si
/COM,  FLOTRAN CFD
/UIS,MSGPOP,3
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
!结构参数初始化
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
*SET,MAX_VALUE,1E+8
*SET,MIN_VALUE,1E-8
*SET,FLUID_XMAX,0.405
*SET,FLUID_YMAX,2.7
*SET,DIS_GROUND,0.5
*SET,SOLID_HEIGHT,1
*SET,SOLID_ENDINS,0.05
*SET,COLUMN_ROUT,0.1
*SET,SOLID_RIN,0.115
*SET,SOLID_ROUT,0.135
*SET,SOLID_INSIN,0.004
*SET,SOLID_INSOUT,0.004
*SET,DOWN_MESH_NUM,53
*SET,DOWN_TIMES,0.079096351
*SET,RIGHT_MESH_NUM,42
*SET,RIGHT_TIMES,0.135281602
*SET,UP_MESH_NUM,70
*SET,UP_TIMES,0.034509476
*SET,HGEN_COLUMN,800
*SET,HGEN_SOLID,150000
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
/PREP7
!定义单元类型及单元属性设置
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
ET,1,FLUID141
KEYOPT,1,1,0
KEYOPT,1,3,1
KEYOPT,1,4,0
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
!定义材料导热系数
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,KXX,2,,30
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,KXX,3,,300
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,KXX,4,,0.3
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
!建立流体模型
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
RECTNG,0,FLUID_XMAX,0,FLUID_YMAX,
RECTNG,0,COLUMN_ROUT,0,FLUID_YMAX,
RECTNG,SOLID_RIN,SOLID_ROUT,0,FLUID_YMAX,
RECTNG,(SOLID_RIN+SOLID_INSIN),(SOLID_ROUT-SOLID_INSOUT),0,FLUID_YMAX,
RECTNG,0,FLUID_XMAX,DIS_GROUND,(DIS_GROUND+SOLID_HEIGHT),
RECTNG,0,FLUID_XMAX,(DIS_GROUND+SOLID_ENDINS),(DIS_GROUND+SOLID_HEIGHT-SOLID_ENDINS),
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
ALLSEL,ALL
AOVLAP,ALL
!
!删除内部面
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
ALLSEL,ALL
ASEL,S,LOC,X,(SOLID_RIN+SOLID_INSIN),(SOLID_ROUT-SOLID_INSOUT)
ASEL,R,LOC,Y,(DIS_GROUND+SOLID_ENDINS),(DIS_GROUND+SOLID_HEIGHT-SOLID_ENDINS)
ADELE,ALL
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
ALLSEL,ALL
CM,FLUID_WHOLE,AREA
!
!网格设置
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
ALLSEL,ALL
CM,ALL_LINES,LINE
LESIZE,ALL_LINES,0.01, , , , , , ,1
LSEL,S,LOC,X,COLUMN_ROUT,SOLID_ROUT
LSEL,U,LOC,X,(COLUMN_ROUT-MIN_VALUE),(COLUMN_ROUT+MIN_VALUE)
LSEL,U,LOC,X,(SOLID_RIN-MIN_VALUE),(SOLID_RIN+MIN_VALUE)
LSEL,U,LOC,X,(SOLID_ROUT-MIN_VALUE),(SOLID_ROUT+MIN_VALUE)
LSEL,U,LOC,X,(SOLID_RIN+SOLID_INSIN-MIN_VALUE),(SOLID_RIN+SOLID_INSIN+MIN_VALUE)
LSEL,U,LOC,X,(SOLID_ROUT-SOLID_INSOUT-MIN_VALUE),(SOLID_ROUT-SOLID_INSOUT+MIN_VALUE)
CM,LINES_LOCAL,LINE
LESIZE,LINES_LOCAL,0.002,,,,,,,1
CMSEL,S,LINES_LOCAL
LSEL,R,LENGTH,,0,0.005
CM,LINES_SHORTEST,LINE
LESIZE,LINES_SHORTEST,0.0007,,,,,,,1
ALLSEL,ALL
LSEL,S,LOC,Y,0,DIS_GROUND
LSEL,U,LOC,Y,(0-MIN_VALUE),(0+MIN_VALUE)
LSEL,U,LOC,Y,(DIS_GROUND-MIN_VALUE),(DIS_GROUND+MIN_VALUE)
CM,LINES_DOWN,LINE
LESIZE,LINES_DOWN,,,DOWN_MESH_NUM,DOWN_TIMES,,,,1
ALLSEL,ALL
LSEL,S,LOC,X,SOLID_ROUT,FLUID_XMAX
LSEL,U,LOC,X,(SOLID_ROUT-MIN_VALUE),(SOLID_ROUT+MIN_VALUE)
LSEL,U,LOC,X,(FLUID_XMAX-MIN_VALUE),(FLUID_XMAX+MIN_VALUE)
CM,LINES_RIGHT,LINE
LESIZE,LINES_RIGHT,,,RIGHT_MESH_NUM,RIGHT_TIMES,,,,1
ALLSEL,ALL
LSEL,S,LOC,Y,(DIS_GROUND+SOLID_HEIGHT),FLUID_YMAX
LSEL,U,LOC,Y,(DIS_GROUND+SOLID_HEIGHT-MIN_VALUE),(DIS_GROUND+SOLID_HEIGHT+MIN_VALUE)
LSEL,U,LOC,Y,(FLUID_YMAX-MIN_VALUE),(FLUID_YMAX+MIN_VALUE)
CM,LINES_UP,LINE
LESIZE,LINES_UP,,,UP_MESH_NUM,UP_TIMES,,,,1
ALLSEL,ALL
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
!指定材料属性
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
ALLSEL,ALL
ASEL,S,LOC,X,0,COLUMN_ROUT
ASEL,R,LOC,Y,DIS_GROUND,(DIS_GROUND+SOLID_HEIGHT)
AATT,2
ALLSEL,ALL
ASEL,S,LOC,X,SOLID_RIN,SOLID_ROUT
ASEL,R,LOC,Y,DIS_GROUND,(DIS_GROUND+SOLID_HEIGHT)
AATT,4
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
!网格划分
ALLSEL,ALL
AMESH,ALL
!流体建模完毕
!
!建立固体模型
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
RECTNG,  .119,  .121,  .55,  .648,
RECTNG,  .119,  .121,  .65025,  .74825,
RECTNG,  .119,  .121,  .7505,  .8485,
RECTNG,  .119,  .121,  .85075,  .94875,
RECTNG,  .119,  .121,  .951,  1.049,
RECTNG,  .119,  .121,  1.05125,  1.14925,
RECTNG,  .119,  .121,  1.1515,  1.2495,
RECTNG,  .119,  .121,  1.25175,  1.34975,
RECTNG,  .119,  .121,  1.352,  1.45,
RECTNG,  .1215,  .1235,  .55,  .648,
RECTNG,  .1215,  .1235,  .65025,  .74825,
RECTNG,  .1215,  .1235,  .7505,  .8485,
RECTNG,  .1215,  .1235,  .85075,  .94875,
RECTNG,  .1215,  .1235,  .951,  1.049,
RECTNG,  .1215,  .1235,  1.05125,  1.14925,
RECTNG,  .1215,  .1235,  1.1515,  1.2495,
RECTNG,  .1215,  .1235,  1.25175,  1.34975,
RECTNG,  .1215,  .1235,  1.352,  1.45,
RECTNG,  .124,  .126,  .55,  .648,
RECTNG,  .124,  .126,  .65025,  .74825,
RECTNG,  .124,  .126,  .7505,  .8485,
RECTNG,  .124,  .126,  .85075,  .94875,
RECTNG,  .124,  .126,  .951,  1.049,
RECTNG,  .124,  .126,  1.05125,  1.14925,
RECTNG,  .124,  .126,  1.1515,  1.2495,
RECTNG,  .124,  .126,  1.25175,  1.34975,
RECTNG,  .124,  .126,  1.352,  1.45,
RECTNG,  .1265,  .1285,  .55,  .648,
RECTNG,  .1265,  .1285,  .65025,  .74825,
RECTNG,  .1265,  .1285,  .7505,  .8485,
RECTNG,  .1265,  .1285,  .85075,  .94875,
RECTNG,  .1265,  .1285,  .951,  1.049,
RECTNG,  .1265,  .1285,  1.05125,  1.14925,
RECTNG,  .1265,  .1285,  1.1515,  1.2495,
RECTNG,  .1265,  .1285,  1.25175,  1.34975,
RECTNG,  .1265,  .1285,  1.352,  1.45,
RECTNG,  .129,  .131,  .55,  .648,
RECTNG,  .129,  .131,  .65025,  .74825,
RECTNG,  .129,  .131,  .7505,  .8485,
RECTNG,  .129,  .131,  .85075,  .94875,
RECTNG,  .129,  .131,  .951,  1.049,
RECTNG,  .129,  .131,  1.05125,  1.14925,
RECTNG,  .129,  .131,  1.1515,  1.2495,
RECTNG,  .129,  .131,  1.25175,  1.34975,
RECTNG,  .129,  .131,  1.352,  1.45,
ALLSEL,ALL
CMSEL,U,FLUID_WHOLE
CM,SOLID_LEAD,AREA
RECTNG,  .119,  .131,  .55,  1.45,
RECTNG,  .121,  .1215,  .55,  1.45,
RECTNG,  .1235,  .124,  .55,  1.45,
RECTNG,  .126,  .1265,  .55,  1.45,
RECTNG,  .1285,  .129,  .55,  1.45,
RECTNG,  .119,  .131,  .648,  .65025,
RECTNG,  .119,  .131,  .74825,  .7505,
RECTNG,  .119,  .131,  .8485,  .85075,
RECTNG,  .119,  .131,  .94875,  .951,
RECTNG,  .119,  .131,  1.049,  1.05125,
RECTNG,  .119,  .131,  1.14925,  1.1515,
RECTNG,  .119,  .131,  1.2495,  1.25175,
RECTNG,  .119,  .131,  1.34975,  1.352,
ALLSEL,ALL
CMSEL,U,FLUID_WHOLE
AOVLAP,ALL
ALLSEL,ALL
CMSEL,U,FLUID_WHOLE
CM,SOLID,AREA
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
!网格设置
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
ALLSEL,ALL
CMSEL,U,FLUID_WHOLE
ALLSEL,BELOW,AREA
CM,ALLLINES_SOLID,LINE
LESIZE,ALLLINES_SOLID,0.005,,,,,,,1
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
!指定材料属性
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
AATT,4
ALLSEL,ALL
CMSEL,S,SOLID_LEAD
AATT,3
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
!网格划分
ALLSEL,ALL
CMSEL,U,FLUID_WHOLE
AMESH,ALL
!固体建模完毕
!
FINI
ALLSEL,ALL
/SOLU
!
!施加边界条件
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
NSEL,S,LOC,X,0
CM,SYM_NODES,NODE
D,SYM_NODES,VX,0
NSEL,S,LOC,X,FLUID_XMAX
CM,OUTER_NODES,NODE
D,OUTER_NODES,PRES,0
D,ALL,,20,,,,TEMP,,,,,
NSEL,S,LOC,Y,0
CM,DOWN_NODES,NOD
D,DOWN_NODES,VX,0
D,DOWN_NODES,VY,0
D,ALL,,20,,,,TEMP,,,,,
NSEL,S,LOC,Y,FLUID_YMAX
CM,UP_NODES,NODE
D,UP_NODES,PRES,0
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
ALLSEL,ALL
!施加辐射边界条件
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
ASEL,S,MAT,,2
ASEL,A,MAT,,4
LSEL,S,EXT
CM,RADIATION_LINES,LINE
LSEL,R,LOC,Y,(DIS_GROUND-MIN_VALUE),(DIS_GROUND+MIN_VALUE)
CM,RAD_DOWN_LINES,LINE
SFL,RAD_DOWN_LINES,RAD,0.9,,20
ALLSEL,ALL
CMSEL,S,RADIATION_LINES
LSEL,R,LOC,X,(SOLID_ROUT-MIN_VALUE),(SOLID_ROUT+MIN_VALUE)
CM,RAD_RIGHT_LINES,LINE
SFL,RAD_RIGHT_LINES,RAD,0.9,,20
ALLSEL,ALL
CMSEL,S,RADIATION_LINES
LSEL,R,LOC,Y,(DIS_GROUND+SOLID_HEIGHT-MIN_VALUE),(DIS_GROUND+SOLID_HEIGHT+MIN_VALUE)
CM,RAD_UP1_LINES,LINE
SFL,RAD_UP1_LINES,RAD,0.9,,20
ALLSEL,ALL
CMSEL,S,RADIATION_LINES
LSEL,R,LOC,X,(COLUMN_ROUT-MIN_VALUE),(COLUMN_ROUT+MIN_VALUE)
SFL,ALL,RDSF,0.9,,-1,
CMSEL,S,RADIATION_LINES
LSEL,R,LOC,X,(SOLID_RIN-MIN_VALUE),(SOLID_RIN+MIN_VALUE)
SFL,ALL,RDSF,0.9,,-1,
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!
!施加体积生热率
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
ALLSEL,ALL
ASEL,S,MAT,,2
BFA,ALL,HGEN,HGEN_COLUMN
ALLSEL,ALL
CMSEL,S,SOLID_LEAD
BFA,ALL,HGEN,HGEN_SOLID
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!边界条件施加完毕
!
FINI
ALLSEL,ALL
/PREP7
!
!耦合结点
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
CMSEL,S,FLUID_WHOLE
ALLSEL,BELOW,AREA
NSEL,S,EXT
NSEL,U,LOC,X,0
NSEL,U,LOC,Y,0
NSEL,U,LOC,X,FLUID_XMAX
NSEL,U,LOC,Y,FLUID_YMAX
NSEL,R,LOC,X,SOLID_RIN,SOLID_ROUT
CM,FLUID_SOLID_CPNODES,NODE
!
*GET,FLUID_SOLID_CPNUM,NODE,,COUNT,,,,
*GET,NUMLOW_FLUID_SOLID_CPNODES,NODE,,NUM,MIN,,,
*DIM,ARRAY_FLUID_SOLID_CPNODES,ARRAY,FLUID_SOLID_CPNUM,3,1,,,
*SET,TEMP_NODE_NUM,NUMLOW_FLUID_SOLID_CPNODES
*SET,ARRAY_FLUID_SOLID_CPNODES(1,1,1),TEMP_NODE_NUM
*SET,ARRAY_FLUID_SOLID_CPNODES(1,2,1),NX(TEMP_NODE_NUM)
*SET,ARRAY_FLUID_SOLID_CPNODES(1,3,1),NY(TEMP_NODE_NUM)
*DO,I,2,FLUID_SOLID_CPNUM
*SET,ARRAY_FLUID_SOLID_CPNODES(I,1,1),NDNEXT(TEMP_NODE_NUM)
*SET,ARRAY_FLUID_SOLID_CPNODES(I,2,1),NX(NDNEXT(TEMP_NODE_NUM))
*SET,ARRAY_FLUID_SOLID_CPNODES(I,3,1),NY(NDNEXT(TEMP_NODE_NUM))
*SET,TEMP_NODE_NUM,NDNEXT(TEMP_NODE_NUM)
*ENDDO
!
ALLSEL,ALL
CMSEL,U,FLUID_WHOLE
ALLSEL,BELOW,AREA
NSEL,S,EXT
NSEL,R,LOC,X,SOLID_RIN,SOLID_ROUT
CM,SOLID_SOLID_CPNODES,NODE
!
*GET,SOLID_SOLID_CPNUM,NODE,,COUNT,,,,
*GET,NUMLOW_SOLID_SOLID_CPNODES,NODE,,NUM,MIN,,,
*DIM,ARRAY_SOLID_SOLID_CPNODES,ARRAY,SOLID_SOLID_CPNUM,3,1,,,
*SET,TEMP_NODE_NUM,NUMLOW_SOLID_SOLID_CPNODES
*SET,ARRAY_SOLID_SOLID_CPNODES(1,1,1),TEMP_NODE_NUM
*SET,ARRAY_SOLID_SOLID_CPNODES(1,2,1),NX(TEMP_NODE_NUM)
*SET,ARRAY_SOLID_SOLID_CPNODES(1,3,1),NY(TEMP_NODE_NUM)
*DO,I,2,SOLID_SOLID_CPNUM
*SET,ARRAY_SOLID_SOLID_CPNODES(I,1,1),NDNEXT(TEMP_NODE_NUM)
*SET,ARRAY_SOLID_SOLID_CPNODES(I,2,1),NX(NDNEXT(TEMP_NODE_NUM))
*SET,ARRAY_SOLID_SOLID_CPNODES(I,3,1),NY(NDNEXT(TEMP_NODE_NUM))
*SET,TEMP_NODE_NUM,NDNEXT(TEMP_NODE_NUM)
*ENDDO
!
*DIM,TEMP_ROW,ARRAY,1,2,1,,,
*SET,N,1
*DO,I,1,FLUID_SOLID_CPNUM
*SET,TEMP_ROW(1,2,1),1E+8
*DO,J,1,SOLID_SOLID_CPNUM
*IF,ARRAY_FLUID_SOLID_CPNODES(I,2,1),EQ,ARRAY_SOLID_SOLID_CPNODES(J,2,1),THEN
*IF,ABS(ARRAY_FLUID_SOLID_CPNODES(I,3,1)-ARRAY_SOLID_SOLID_CPNODES(J,3,1)),LT,TEMP_ROW(1,2,1),THEN
*SET,TEMP_ROW(1,1,1),ARRAY_SOLID_SOLID_CPNODES(J,1,1)
*SET,TEMP_ROW(1,2,1),ABS(ARRAY_FLUID_SOLID_CPNODES(I,3,1)-ARRAY_SOLID_SOLID_CPNODES(J,3,1))
*ENDIF
*ELSEIF,ARRAY_FLUID_SOLID_CPNODES(I,3,1),EQ,ARRAY_SOLID_SOLID_CPNODES(J,3,1),THEN
*IF,ABS(ARRAY_FLUID_SOLID_CPNODES(I,2,1)-ARRAY_SOLID_SOLID_CPNODES(J,2,1)),LT,TEMP_ROW(1,2,1),THEN
*SET,TEMP_ROW(1,1,1),ARRAY_SOLID_SOLID_CPNODES(J,1,1)
*SET,TEMP_ROW(1,2,1),ABS(ARRAY_FLUID_SOLID_CPNODES(I,2,1)-ARRAY_SOLID_SOLID_CPNODES(J,2,1))
*ENDIF
*ENDIF
*ENDDO
ALLSEL,ALL
NSEL,S,,,ARRAY_FLUID_SOLID_CPNODES(I,1,1)
NSEL,A,,,TEMP_ROW(1,1,1)
CP,N,ALL,ALL
N=N+7
*ENDDO
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
!结点耦合完毕
!
ALLSEL,ALL
FINI
!
!设置参考温度为摄氏温度
/PREP7
TOFFST,273
FINI
!
/SOL
!热分析
FLDATA1,SOLU,TEMP,1
!
!每20步分析计算一次，每10步记录结果一次
FLDATA2,ITER,EXEC,20,
FLDATA2,ITER,OVER,10,
FLDATA2,ITER,APPE,10,
!
!设置空气属性
FLDATA12,PROP,DENS,4
FLDATA13,VARY,DENS,1
FLDATA12,PROP,VISC,4
FLDATA13,VARY,VISC,0
FLDATA12,PROP,COND,4
FLDATA13,VARY,COND,0
FLDATA12,PROP,SPHT,4
FLDATA13,VARY,SPHT,0
FLDATA7,PROT,DENS,AIR-SI
FLDATA7,PROT,VISC,AIR-SI
FLDATA7,PROT,COND,AIR-SI
FLDATA7,PROT,SPHT,AIR-SI
!
!重力加速度
ACEL,0,9.81,0,
FINI
!
/AUX12
!设置辐射参数
STEF,0.567E-07
!
!Auto Legend
/PLOPTS,INFO,2
ALLSEL,ALL
FINI
!建模完毕

simwe

鼓励原创，加为精华贴！

nwpuyl

来晚了，期待楼主多发好帖！

pank

好东西！谢谢！

tomatoylm

楼住真是牛人,但是为什么运行不了呢?大家看看有什么问题

tripstones

楼上的，你加上下面这段就行了，是楼主告诉我的，谢谢楼主！
没经过楼主的同意就把下面的贴出来了，楼主见谅！


在源代码后面加上下面的代码应该就可以了：

!设置环境温度
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
FLDATA14,TEMP,NOMI,20,                                        !  
FLDATA14,TEMP,TTOT,20,                                        !  
FLDATA14,TEMP,BULK,20,                                        !
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!

!设置初始人工粘性
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
FLDATA26,STAB,VISC,0.01,                                      !
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!

/AUX12
!设置辐射参数
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!
STEF,0.567E-07                                                                  !   
RADOPT,0.10000000149,0.999999974738E-04,0,100,0.10000000149,0.10000000149       !   
SPCTEMP,1,20                                                                    !
V2DOPT,1,360,0,500                                                              !
!*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*-----*!

然后分析的时候不是一步完成的，因为最初设置的人工粘性为0.01，到不断地改变它（每20步缩小10倍），直到0（一共分析150步左右就可以了），这时收敛的结果才与现实比较吻合。

在分析过程中如果出现不收敛的情况（通常会报错），要改变分析策略，如由层流分析变为湍流，或反过来（最初是层流分析），最后通常使用下面的方法（改变收敛参数的设置）加快收敛：

FLDATA34，MIR，MOME，1，

FLDATA34，MIR，TEMP，1，

FLDATA34，MIR，TURB，1，

hanqigang

在云图中如何做到分析部件局部放大？？？？
         谢谢！！！

tripstones

你可以框选你要放大区域的单元
然后加上下面的命令
set,last
etable,,erase,1
etable,tt,temp
pletab,tt,avg

neiep

我的一些疑问如下，希望多指教：
楼主在初始化中，用了
/units,si
也就是说分析采用了国际单位制，温度的单位也就是K了
之后的施加辐射边界条件时
SFL,RAD_DOWN_LINES,RAD,0.9,,20
环境温度自然默认为是20K
注意到楼主之后的程序用了以下的语句
//////////////////////////////////
!设置参考温度为摄氏温度
/PREP7
TOFFST,273
FINI
/////////////////////////////////
    相信楼主的本意是设定辐射环境温度是20摄氏度，通过TOFFST指定其与绝对温度的差别
但按我的理解，TOFFST命令指定的是分析所采用温度制零点与开氏温度零点的差异，既然已经指定的系统的单位制为国际单位制系统，那么系统的温度制与开氏温度毫无二致，也就用不上这个命令了吧。TOFFST命令的其作用在于方便系统进行热辐射等需要用到绝对零度的计算。
附：帮助文件中TOFFST命令介绍
TOFFST, VALUE
Specifies the temperature offset from absolute zero to zero.

VALUE
Degrees between absolute zero and zero of temperature system used (should be positive).

Notes
Specifies the difference (in degrees) between absolute zero and the zero of the temperature system used. Absolute temperature values are required in evaluating certain expressions, such as for creep, swelling, radiation heat transfer, MASS71, etc. (The offset temperature is not used in evaluating emissivity.) Examples are 460° for the Fahrenheit system and 273° for the Centigrade system. The offset temperature is internally included in the element calculations and does not affect the temperature input or output. If used in SOLUTION, this command is valid only within the first load step.

This command is also valid in PREP7.

可乐鸡翅

谢谢楼主的原创，顶顶