我的是结合命令流和gui做的，在创建几何模型是基本上是GUI的，具体操作如下：
首先，输入命令流：
/filenam,induction
/prep7
/title, induction heating 3D
!选择磁场单元
et,1,97 !non-steel region
et,2,97,1 !steel region
et,3,97,1 !coil
!参数设置
*set,freq,25000 ! frequency (Hz.)
*set,pi,4*atan(1) ! pi
*set,cond,.392e7 ! maximum conductivity
*set,muzero,4e-7*pi ! free-space permeability
*set,mur,200 ! maximum relative permeability
*set,skind,sqrt(1/(pi*freq*cond*muzero*mur)) ! skin depth
*set,ftime,30 ! final time
*set,tinc,1 ! time increment for harmonic analysis
*set,time,0 !initialize time
*set,delt,1 !maximum delta time step
!定义材料特性
emunit,mks ! 设置电磁场分析单位
mp,murx,1,1 ! 定义空气相对磁导率
mp,murx,3,1 ! 定义线圈相对磁导率
mp,dens,3,8960
mp,rsvx,3,1.7e-8
mptemp,1,25.5,160,291.5,477.6,635,698 ! temps for relative permeability
mptemp,7,709,720.3,742,761,1000
mpdata,murx,2,1,200,190,182,161,135,104 ! steel relative permeability
mpdata,murx,2,7,84,35,17,1,1
mptemp
mptemp,1,0,125,250,375,500,625 ! temps for resistivity
mptemp,7,750,875,1000
mpdata,rsvx,2,1,.184e-6,.272e-6,.384e-6,.512e-6,.656e-6,.824e-6
mpdata,rsvx,2,7,1.032e-6,1.152e-6,1.2e-6 ! steel resistivity
mptemp
mptemp,1,0,730,930,1000 ! temps for conductivity
mpdata,kxx,2,1,60.64,29.5,28,28
mptemp ! temps for enthalpy
mptemp,1,0,27,127,327,527,727
mptemp,7,765,765.001,927
mpdata,enth,2,1,0,91609056,453285756,1.2748e9,2.2519e9,3.3396e9
mpdata,enth,2,7,3.548547e9,3.548556e9,4.3520e9
mp,emis,2,.68 ! emissivity
mp,c,2,465
mp,dens,2,7850
接着是建几何模型，我先输入建齿轮的命令流：
m=3.0 !定义模数
z=21.0 !齿数
!齿轮相关数据计算
pi=3.14159265358979
angle1=20*pi/180.0 !压力角
ha=1.0 !正常齿制的齿顶高系数
*if,m,LT,1,then !正常齿制的顶隙系数选择
c=0.35
*else
c=0.25
*endif
r=0.5*m*z !分度圆半径
rb=r*cos(angle1) !基圆半径
ra=0.5*(z+2*ha)*m !齿顶圆半径
rf=0.5*(z-2*ha-2*c)*m !齿根圆半径
zz=2*(ha+c)/(1-cos(angle1)) !以次判断用何种方法(基于对rf、rb大小的判断)
*if,z,GE,zz,then
rff=0.38*m !齿根圆角半径
*else
rff=(2.0*pi*rb/z-m*cos(angle1)*(pi/2.0+z*(tan(angle1)-angle1)))/2.0 !同上
*endif
angle2=180.0/z !镜像旋转角
angle3=(pi/2.0/z+tan(angle1)-angle1)*180.0/pi !初始的偏转角(其值不能改变）
angle4=(pi/2.0/z+tan(angle1)-angle1)*180.0/pi !对称偏转角
/prep7
csys,4 !激活工作坐标系
wprot,-angle3,0,0 !初始偏转角度
K,1,0,0 !绘制原点 （编号为1）
*do,t,0,1,0.01 !描点
*SET,x,rb*(cos(t)+t*sin(t)) !渐开线方程
*SET,y,rb*(sin(t)-t*cos(t))
k,,x,y,0 !开始描点
*enddo
flst,3,101,3 !连点成线
*do,t,2,102
fitem,3,t
*enddo
bsplin,,p51x !用多意线连点成线
KDELE,3,101,1 !删多余点
NUMCMP,KP !重排点号
wprot,angle4,0,0 !X轴旋转angle4度 对称偏转角
LSYMM,Y,1, , , ,0,0 !镜像渐开线
circle,1,ra !画出齿顶圆线
LSBL,1,6 !对渐开线进行分割
LSBL,2,3
ldele,4 !删除多余的线与点
ldele,5
ldele,6
ldele,8
kdele,6,9,1
kdele,3
kdele,5
NUMCMP,line !重排线号、点号
NUMCMP,KP
*if,z,GE,zz,then !判断是否进行第二次分割
circle,1,rf
LSBL,1,3 !对渐开线进行分割
LSBL,2,6
ldele,4 !删除多余的线与点
ldele,5
ldele,1
ldele,7
kdele,7,9,1
kdele,2
kdele,3
NUMCMP,line
NUMCMP,KP
larc,2,3,1,ra !联接齿顶
*else
larc,4,5,1,ra !联接齿顶
FLST,3,3,4,ORDE,2
FITEM,3,1
FITEM,3,-3
LGEN,2,P51X, , , , , , ,0 !复制，重排线号
ldele,1,3,1,1
NUMCMP,line
NUMCMP,KP
*endif
*do,t,1,z-1,1 !开始旋转镜像以上所形成的齿廓曲线
wprot,angle2,0,0
FLST,3,3,4,ORDE,2
FITEM,3,1
FITEM,3,-3
LSYMM,Y,P51X, , , ,0,0
*enddo
WPCSYS,-1,0 !重新对齐工作坐标并开始做齿根圆圆弧
*if,z,GE,zz,then !方法选择
larc,4,9,1,rf !当rb<rf时，直接连接rf，并倒0.38m圆角
*do,t,7,4*z-5,4
larc,t,t+6,1,rf
*enddo
larc,4*z-1,5,1,rf
lfillt,1,4*z,rff
*do,t,0,z-2,1
lfillt,5+3*t,3*z+1+t,rff
lfillt,4+3*t,3*z+2+t,rff
*enddo
lfillt,2,3*z+1,rff
*else
csys,2 !当rb>rf时，用计算圆角倒齿根圆角
*do,t,1,2*z,2
k,,rf*1.1,angle2*t,0
*enddo
csys,0
larc,2,6,4*z+2,rff
*do,t,0,z-3,1
larc,8+4*t,10+4*t,4*z+3+t,rff
*enddo
larc,4,4*z,5*z+1,rff
*endif
finish
save
接着我这样操作的，先显示齿轮的线，再由它建一个面，再由面扩展为体，接着创建线圈，在创建空气。具体过程如附件的图片，接着的命令流如下：
vplot
csys,1 !柱面坐标系
cswpla,11,1 !建立一个局部坐标系定义了圆柱坐标系，
local,11,1
!赋特性
vsel,s,,,3 !线圈
vatt,3,1,3,11
vsel,s,,,1 !gangban
vatt,2,1,2,11
vsel,s,,,2 !kongqi
vatt,1,1,1,11
vsel,all
alls
网格划分是通过GUI的meshtool，自由划分的，接着就是命令流了
asel,s,,,95
nsla,s,1 !选择1号面上所有的节点
nplot !显示节点
cp,1,volt,all !将线圈节点上的电流自由度进行耦合
!nsel,s,,,119
f,ndnext(0),amps,200
asel,s,,,100
nsla,s,1
nplot
d,all,volt,0
alls
vplot !显示选择的体
nsel,s,ext,,,,,1
d,all,az,0
alls
/solu
antyp,harm
harfrq,25000
!hropt,full
!hrout,on
eqslv,,1e-6, !才用波前法，误差是1e-008
physics,write,emag
solve
save
finish
!热场分析
/prep7
lsclear,all ! clear all b.c.'s and options
et,1,0 ! non-steel
et,2,solid90 ! steel
et,3,0
nsel,s,ext
sf,all,conv,100,25
nsel,all
finish
/solu
antype,trans
toffst,273
tunif,25 ! initial uniform temperature
!spctemp,1,25 !环境温度
cnvtol,heat,1 ! convergence tolerance
kbc,1 ! step loads
trnopt,full
autos,on ! auto time-stepping
deltim,1e-1,1e-2,delt,on ! time step control
outres,basic,all ! save all load step information
physics,write,thermal ! write thermal physics file
finish
*do,i,1,ftime/tinc ! solution *do loop
*set,time,time+tinc ! increment time
physics,read,emag ! read emag physics file
/solu
*if,i,eq,1,then
tunif,25 ! initial temperature
*else
ldread,temp,last,,,,,rth ! read thermal analysis temperatures
*endif
solve ! solve harmonic analysis
finish
physics,read,thermal ! read thermal physics file
/assign,esav,therm,esav ! redirect files for use in thermal
/assign,emat,therm,emat
/solu
*if,i,gt,1,then
antype,trans,rest ! thermal restart
*endif
time,time ! time at end of thermal run
esel,s,mat,,2 ! select billet region
ldread,hgen,,,,2,,rst ! apply coupled joule heating load from emag，2是求平均的hgen
esel,all
solve
finish
/assign,esav ! reassign files to default
/assign,emat
*enddo ! end of solution
save
finish
/post1
set,last ! Solution at 3 seconds
esel,s,mat,,2 ! select thermal elements
plns,temp ! plot temperature
还有你能不能把你的qq号给我，我们讨论起来比较方便！请多多指教！
|
IP卡
狗仔卡
发表于 2013-11-5 16:00:50
显身卡
