请教：磁场与电路的耦合问题？！

流星小雨

请问各位大侠：哪位知道磁场和电路该怎么耦合啊？磁场是由某电路给线圈供电时产生的，我现在要把电路部分和线圈耦合到一起来分析，因为该电路的电源是由充放电电容器的储能来提供的，所以这是一个瞬态的分析问题，那么我给怎样把电路和线圈连接到一起呢？
请赐教，非常感谢！

fftwq0912

版上有个计算电机地例子，用的就是场路耦合
看看吧

流星小雨

是啊，我找到了，但是他的模型太复杂了，看起来太费劲，我的模型比他的要简单的多，我只是一个绞线圈和一个电路的耦合，他的参数太多了，我实在是看不明白，请问各位大侠，谁有比较简单的关于场路耦合的例子啊？分享一下，小弟将不胜感激！

laojee

很久以前做的了，计算的是一个变压器的磁场分布。
负载是一个电阻，用到了场路耦合，希望对你有所帮助。
/FILNAME,Load
!Part 1: Initializing the parameter of geometry and properties.
  Ri=395E-03/2            !Radius of iron core ;
  Hi=(1940/2+20)*1E-03    !Height of iron core;
  G1=20E-03               !Gap between core and inner high voltage winding;
  Whv1=80.5E-03           !Width of inner high voltage winding;
  Hw=970E-03              !Height of winding;
  G2=10E-03               !Gap between high and low voltage windings;
  Wlv=69E-03              !Width of low voltage winding;
  Whv2=262E-03            !Outer high winding;
  Wt=1320E-03             !Total width;
  Nlv=132                 !Turns of premary winding;
  Slv=185E-06             !Area of core conductor about premary(low) winding;
  Flv=(Nlv*Slv)/(Wlv*Hw*2) !Fill factor abou premary winding;
  Nhv1=110                 !Turns of inner secondary(high) winding;
  Shv=70E-06               !Areas of core conductor about high winding;
  Fhv1=(Nhv1*Shv)/(Whv1*Hw*2) !Fill factor about inner high winding;
  Nhv2=330                 !Turns of outer high winding;
  Fhv2=(Nhv2*Shv)/(Whv2*Hw*2) !Fill factor about outer high winding;

!Part 2: Creating half FEM model;
  /PREP7
  Rectng,0,Ri,0,Hi                 !Coil area;
  R1=Ri+G1
  Rectng,R1,R1+Whv1,0,Hw           !Inner high voltage winding;
  R2=R1+Whv1+G2
  Rectng,R2,R2+Wlv,0,Hw            !Low winding;
  R3=R2+Wlv+G2
  Rectng,R3,R3+Whv2,0,Hw           !outer high winding;  
  Rectng,0,Wt,0,Hi  
  AOVLAP,ALL
  NumCmp,All
  
!Part 3: Defining the properties.
  ET,1,53,,,1         ! Air and core;
  ET,2,53,2,,1        ! Premary (Low) winding;
  ET,3,53,3,,1        ! Secondary (High) winding;
  MP,MURX,1,1         !No.1= Air;
  Mp,Murx,2,5000      !No.2=Iron core;
  Rsvx_Al=2.6178E-08  
  UIMP,3,MURX,RSVX,,1,Rsvx_Al    !No.3=Aluminium conductor;
  R,1,2*Whv1*Hw,Nhv1,,-11,Fhv1     !Inner high winding;
  R,2,2*Wlv*Hw,Nlv,,1,Flv        !Low winding;
  R,3,2*Whv2*Hw,Nhv2,,-1,Fhv2     !Outer high winding;
  ASEL,S,AREA,,1    !Core;   
  AATT,2,,1         
  ASEL,S,,,2       !Inner high winding;
  AATT,3,1,3      
  ASEL,S,,,3       !Low winding;
  AATT,3,2,2
  Asel,S,,,4       !Outer winding;
  AATT,3,3,3        
  ASEL,S,,,5
  AATT,1,,1
  Allsel,All
  
!Part 4:Meshing model.  
!Part 4.1: Meshing coil
  LSel,S,,,5,11,2
  Lesize,All,,,2
  LSel,s,,,6,8,2
  LSel,A,,,14,16,2
  Lesize,All,,,28
  Lsel,S,,,10,12,2
  Lesize,All,,,33
  Lsel,s,,,13,15,2
  Lesize,All,,,6
  Asel,s,Type,,2,3
  MShape,0,2D        !Qualaterial elements;
  Mshkey,1           !Mapped Meshing;
  Amesh,All
!Part 4.2: Meshing iron core;
  Lsel,s,,,1,3,2
  LEsize,All,,,6
  Lsel,s,,,2,4,2
  Lesize,All,,,30
  MShape,0,2D        !Qualaterial elements;
  Mshkey,1           !Mapped meshing;
  Asel,s,mat,,2
  AMESH,All  
!Part 4.3:Meshing air region;
  Smrt,2
  Mshape,1,2D
  MshKey,0
  ASel,S,mat,,1
  Amesh,All

!Part 5: Creating circuit;
  Allsel,All
  Et,4,Circu124,0   !Resistor;
  Et,5,Circu124,5   !Stranded Coil (To FEM domain);
  R,4,1.0E+03       !Magnitude of load resistor;
  R,5,2             !Symmetry factor for stranded coil
  N                 !No 1. terminal node linked resistor;
  N                 !No.2  terminal node linked resistor;
  *Get,Nmax,Node,0,Num,Max
  Type,4
  Real,4
  E,Nmax,Nmax-1     !Resistor element;
  Type,5
  Real,5
  E,Nmax,Nmax-1,Node(R1,0,0)
  
!Part 6: Applying the boundary conditions.  
  Allsel,All
  ESel,S,Type,,2
  NSLE,S
  CP,1,CURR,ALL         ! Couple Current inside premary winding;
  Esel,s,Type,,3
  NSLE,S               
  Cp,2,Curr,All
  Cp,3,EMF,All
  Allsel,all
  CSYS,0
  NSEL,S,LOC,X,0
  D,ALL,AZ,0
  Allsel,All
  FINISH

!Part 6: Applying the load and solving.
  /SOLU
  Frq=50
  ANTYPE,Harmic
  HarFrq,Frq
  ESEL,S,Type,,2
  BFE,ALL,VLTG,,10500*Sqrt(2),0     ! 10.5kV Voltage Load
  Allsel,ALL
  SOLVE
  Save
  FINISH

流星小雨

好不容易能上论坛了，非常感谢楼上的大侠给予帮助，非常感谢！
我还没试，有什么问题还请多多帮助啊！

philowzx

R,5,2             !Symmetry factor for stranded coil
对称系数怎么给啊
在help里没有看到详细说明