瞬态热应力分析例子

wswftwswft01

1．1．2 分析问题简介

分析问题为一3层3跨连续框架，层高3米，柱间距5.5米。所有柱脚固定，右侧右侧向支撑。柱顶受集中荷载，荷载值为外侧柱75.5kN, 内侧柱151kN. 所有横梁受均布荷载25.4kN/m。梁和柱均为标准工型截面，其尺寸如下：
  高 宽 翼缘厚度 腹板厚度
梁 0.3038 0.165 0.0102 0.0061
柱 0.2062 0.2039 0.0125 0.0083
假定底层左端一防火间发生火灾，该防火间内温度随时间按标准火模型上升。分析结构的变形。
防火间具有防止火灾蔓延和隔绝热量传递的作用。因此，仅防火间内部的结构构件会有明显的温度上升。 ANSYS的梁单元仅能模拟沿截面线性温度分布。为了能准确模拟截面的非均匀温度分布和捕捉局部屈曲等现象，构成防火间的梁和柱将采用壳或体单元，其余部分采用梁单元。两者接合处采用约束方程以保证变形协调。
在进行传热学分析时，假定梁和柱的构造形式如下图所示：柱的腹部有砖墙，因此，仅朝防火间的翼缘受到热作用。梁上部托混凝土楼板，因此，除上翼缘上表面外的所有表面均受到热作用（如图中虚线所示为受热边界）。热量以对流和辐射的形式从热空气传递到结构表面，又以传导的形式在结构内部传播。

！首先进行传热学分析
/PREP7
/TITLE,Part 1:heat transfer analysis
ET,1,SOLID70 ！定义单元类型
！-----------------------------------------------------------------
！定义参数
！-----------------------------------------------------------------
W_col=0.2039 ！柱截面宽度
H_col=0.2062 ！柱截面高度
tf_col=0.0125 ！柱翼缘厚度
tw_col=0.0083 ！柱腹板厚度
B_col=(W_col-tw_col)/2 ！柱翼缘伸出长度
D_col=H_col-2*tf_col ！柱腹板净高
W_beam=0.165 ！梁截面宽度
H_beam=0.3038 ！梁截面高度
tf_beam=0.0102 ！梁翼缘厚度
tw_beam=0.0061 ！梁腹板厚度
B_beam=(W_beam-tw_beam)/2 ！梁翼缘伸出长度
D_beam=H_beam-2*tf_beam ！梁腹板净高
Dis_hor=5.5 ！框架水平跨间距
Dis_ver=3.0 ！框架竖向层高
pp=(W_col-W_beam)/2
！----------------------------------------------------------------------------------
！定义热分析材料特性
！----------------------------------------------------------------------------------
！热分析需要定义的材料特性包括导热性，比热，密度等
MPTEMP,,20,800,900,1000 ！定义随温度变化的钢材的导热性
MPDATA,KXX,1,,53.334,27.36,27.36,27.36
MPTEMP ！清除温度场
MPTEMP,,20,100,180,260,380 ！定义随温度变化的钢材的比热
MPDATA,C,1,,439.8,487.62,522.33,550.75,596.52
MPTEMP,,500,600,640,720,735
MPDATA,C,1,,666.5,759.92,798.67,1388,5000
MPTEMP,,750,830,900,1000
MPDATA,C,1,,1483,725,650,650
MP,DENS,1,7850 ！定义钢材的密度
！---------------------------------------------------------------------------------
！建立分析模型
！---------------------------------------------------------------------------------
！采用直接生成节点和单元的办法建立实体模型。框架除防火间以外的部分不参与传热
！反应。因此，仅建立防火间的分析模型
！生成第一根柱
N,1,-H_col/2,,-W_col/2 ！产生构成柱截面的节点
N,2,-H_col/2,,-W_col/2+pp
NGEN,4,1,2,,,,,(B_col-pp)/3
N,6,-H_col/2,,tw_col/2
NGEN,4,1,6,,,,,(B_col-pp)/3
N,10,-H_col/2,,W_col/2
NGEN,2,10,1,10,1,tf_col
NGEN,10,6,15,16,1,D_col/10
NGEN,2,60,11,20,1,D_col
NGEN,2,10,71,80,1,tf_col
NGEN,2,100,all,,,,(Dis_ver-H_beam/2)/60 ！将已生成的节点沿y方向偏移
！(Dis_ver-H_beam/2)/60拷贝一层
！节点号加100
E,1,2,12,11,101,102,112,111 ！生成第一层单元
EGEN,9,1,1
E,15,16,22,21,115,116,122,121
EGEN,10,6,10
E,71,72,82,81,171,172,182,181
EGEN,9,1,20
EGEN,60,100,1,28,1,,,,,,0,(Dis_ver-H_beam/2)/60 ！将第一层单元沿y方向拷贝60层
！生成第一根柱
！将柱的模型继续向上延伸梁的截面高度，生成梁柱节点。
！节点处单元尺寸尽量与梁的截面单元尺寸一致。
NSEL,S,NODE,,6001,6090,1 ！沿梁的翼缘厚度生成一层单元
NGEN,2,100,ALL,,,,tf_beam
EGEN,2,100,1653,1680,1
NSEL,ALL
NSEL,S,NODE,,6101,6190 ！沿梁的腹板高度生成10层单元
NGEN,11,100,ALL,,,,D_beam/10
EGEN,11,100,1681,1708,1
NSEL,ALL
NSEL,S,NODE,,7101,7190 ！继续沿梁的翼缘厚度生成一层单元
NGEN,2,100,ALL,,,,tf_beam
EGEN,2,100,1961,1988,1
NSEL,ALL
！将实体模型的柱向上延伸H_beam的高度，避免梁单元和实体单元在
！梁柱节点处切换
NSEL,S,NODE,,7201,7290 ！生成6层单元，每层高H_beam/6
NGEN,7,100,ALL,,,,H_beam/6
EGEN,7,100,1989,2016,1
NSEL,ALL
！第一根实体模型柱完成。
！共计：节点79层，每层编号1-90， 逐层加100，顶层编号7801-7890
！单元78层，自动编号。每层28个，共28*78=2184个

！生成第二根柱及梁柱节点
NGEN,2,10000,ALL,,,Dis_hor ！从第一根柱拷贝所有的节点
                                                            ！节点号加10000
EGEN,2,10000,1,2184,1 ！从第一根柱拷贝所有的单元

！生成梁
！梁被夹在两根柱之间，实际长度为Dis_hor-H_col
N,20001,H_col/2,Dis_ver-H_beam/2,-W_beam/2
！生成梁的截面的所有节点
！梁的节点编号从20001开始
NGEN,4,1,20001,,,,,B_beam/3
N,20005,H_col/2,Dis_ver-H_beam/2,tw_beam/2
NGEN,4,1,20005,,,,,B_beam/3
NGEN,2,10,20001,20008,1,,tf_beam
NGEN,10,6,20014,20015,1,,D_beam/10
NGEN,2,60,20011,20018,1,,D_beam
NGEN,2,10,20071,20078,1,,tf_beam
NGEN,2,100,20001,20090,,(Dis_hor-H_col)/100 ！沿x方向偏移(Dis_hor-H_col)/100
！拷贝一层节点
E,20001,20002,20012,20011,20101,20102,20112,20111 ！生成梁的第一层截面单元
！两根柱单元总数为4368
！故梁的单元编号从4369开始
EGEN,7,1,4369
E,20014,20015,20021,20020,20114,20115,20121,20120
EGEN,10,6,4376
E,20071,20072,20082,20081,20171,20172,20182,20181
EGEN,7,1,4386
EGEN,100,100,4369,4392,1,,,,,,(Dis_hor-H_col)/100 ！沿x方向拷贝100层生成整根梁
！梁的实体模型完成
！总计：梁的节点为101层，每层编号1-88。从20001开始，逐层加100
！左端截面的节点为20001-20088； 右端截面的节点为30001-30088
！每层单元数为24个，总计24*100=2400个。单元编号为4369-6768

！-------------------------------------------------------------------------------
！建立梁和柱连接处的耦合关系
！-------------------------------------------------------------------------------
！自动耦合所有节点坐标重合的节点。梁翼缘的节点和柱的侧面完全重合，可以自动耦合。
！梁腹板的节点距离柱侧面相应节点的距离为(tw_col-tw_beam)/2=0.0011
！因此，设置耦合误差为0.002时，也能自动耦合。
CPINTF,all,0.002
FINISH
！--------------------------------------------------------------------------------
！定义边界条件，并求解
！--------------------------------------------------------------------------------
/SOLU
ANTYPE,TRANS ！定义分析类型
TUNIF,20 ！定义初始温度
AUTOTS,ON ！打开自动步长控制
DELTIM,20 ！定义初始时间步长
STEF,5.6696E-8 ！定义
TOFFST,273 ！定义绝对温度偏差
！定义受到火的热作用的边界
NSEL,S,NODE,,71,6071,100 ！选择第一根柱右侧翼缘的节点，
                                             ！定义为HTbound1
*DO,i,80,90,1
NSEL,A,NODE,,i,6000+i,100
*ENDDO
CM,HTbound1,NODE
NSEL,S,NODE,,10020,16020,100 ！选择第二根柱左侧翼缘的节点，
                                                            ！定义为HTbound2
*DO,i,10001,10011,1
NSEL,A,NODE,,i,6000+i,100
*ENDDO
CM,HTbound2,NODE
NSEL,S,NODE,,20001,30090,100 ！选择梁除上翼缘上表面外所有的面
                                                             ！定义为HTbound3
*DO,i,20081,20090,1
NSEL,U,NODE,,i,10000+i,100
*ENDDO
CM,HTbound3,NODE
！施加热边界条件并求解
*DO,tm,60,180,60 ！定义时间参数tm从60到600（秒）
Time,tm ！当前时间为tm
Temp=20+345*LOG10(8*tm/60+1) ！计算环境空气温度
SF,HTbound1,CONV,25,Temp ！对边界HTbound1施加对流作用
SF,HTbound2,CONV,25,Temp ！对边界HTbound2施加对流作用
SF,HTbound3,CONV,25,Temp ！对边界HTbound3施加对流作用
SF,HTbound1,RDSF,0.9,1 ！定义HTbound1为第一个热辐射场
SF,HTbound2,RDSF,0.9,2 ！定义HTbound2为第二个热辐射场
SF,HTbound3,RDSF,0.9,3 ！定义HTbound3为第三个热辐射场
SPCTEMP,1,Temp ！定义第一个热辐射场的环境温度
SPCTEMP,1,Temp ！定义第二个热辐射场的环境温度
SPCTEMP,1,Temp ！定义第三个热辐射场的环境温度
SOLVE ！求解
*ENDDO
FINISH
/POST1
PLNSOL,TEMP,,0,
FINISH

！--------------------------------------------------------------------------------------
！结构分析
！--------------------------------------------------------------------------------------
/PREP7
/TITLE,Part 2: structural analysis
ET,1,SOLID45,1,1 ！对应于SOLID70的结构单元
！为SOLID45
ET,2,BEAM188 ！单元类型2
！------------------------------------------------------------------------------
！定义结构分析材料特性
！------------------------------------------------------------------------------
fy=275E+6 ！常温下屈服应力
exx=2.1E+11 ！常温下杨氏模量
MPTEMP ！清楚原来的温度场
MPTEMP,,20,100,200,300,400 ！定义随温度变化的杨氏模量
MPDATA,EX,1,,exx,0.9*exx,0.8*exx,0.7*exx
MPTEMP,,500,600,700,800,900
MPDATA,EX,1,,0.6*exx,0.31*exx,0.13*exx,0.09*exx,0.0675*exx
MP,NUXY,1,0.3 ！定义泊松比
MP,ALPX,1,1.4E-5 ！定义热膨胀系数
!
TB,MISO,1,10,3 ！定义随温度变化的应力-应变关系
TBTEMP,20 ！20度时的应力-应变关系
TBPT,,fy/exx,fy
TBPT,,0.02,fy
TBPT,,0.15,fy
!
TBTEMP,100 ！100度时的应力-应变关系
TBPT,,fy/exx,fy
TBPT,,0.02,fy
TBPT,,0.15,fy
!
TBTEMP,200 ！200度时的应力-应变关系
TBPT,,0.807*fy/(0.9*exx),0.807*fy
TBPT,,0.02,fy
TBPT,,0.15,fy
!
TBTEMP,300 ！300度时的应力-应变关系
TBPT,,0.613*fy/(0.8*exx),0.613*fy
TBPT,,0.02,fy
TBPT,,0.15,fy
!
TBTEMP,400 ！400度时的应力-应变关系
TBPT,,0.420*fy/(0.7*exx),0.420*fy
TBPT,,0.02,fy
TBPT,,0.15,fy
!
TBTEMP,500 ！500度时的应力-应变关系
TBPT,,0.360*fy/(0.6*exx),0.360*fy
TBPT,,0.02,0.780*fy
TBPT,,0.15,0.780*fy
!
TBTEMP,600 ！600度时的应力-应变关系
TBPT,,0.180*fy/(0.310*exx),0.180*fy
TBPT,,0.02,0.470*fy
TBPT,,0.15,0.470*fy
!
TBTEMP,700 ！700度时的应力-应变关系
TBPT,,0.075*fy/(0.130*exx),0.075*fy
TBPT,,0.02,0.230*fy
TBPT,,0.15,0.230*fy
!
TBTEMP,800 ！800度时的应力-应变关系
TBPT,,0.050*fy/(0.090*exx),0.050*fy
TBPT,,0.02,0.110*fy
TBPT,,0.15,0.110*fy
!
TBTEMP,900 ！900度时的应力-应变关系
TBPT,,0.0375*fy/(0.0675*exx),0.0375*fy
TBPT,,0.02,0.060*fy
TBPT,,0.15,0.060*fy
！------------------------------------------------------------------------------
！定义梁和柱的截面特性
！------------------------------------------------------------------------------
SECTYPE,1,beam,I,column ！定义柱截面为截面类型1
SECDATA,W_col,W_col,H_col,tf_col,tf_col,tw_col
SECTYPE,2,beam,I,beam ！定义梁截面为截面类型2
SECDATA,W_beam,W_beam,H_beam,tf_beam,tf_beam,tw_beam
！----------------------------------------------------------------------------
！用梁单元建立框架的剩余部分的模型
！---------------------------------------------------------------------------
K,1,,Dis_ver+H_beam*1.5 ！定义生成框架的关键点
K,2,,2*Dis_ver
K,3,,3*Dis_ver
K,4,Dis_hor,Dis_ver+H_beam*1.5
K,5,Dis_hor,2*Dis_ver
K,6,Dis_hor,3*Dis_ver
K,7,Dis_hor+H_col/2,Dis_ver
K,8,2*Dis_hor
K,9,2*Dis_hor,Dis_ver
K,10,2*Dis_hor,2*Dis_ver
K,11,2*Dis_hor,3*Dis_ver
K,12,3*Dis_hor
K,13,3*Dis_hor,Dis_ver
K,14,3*Dis_hor,2*Dis_ver
K,15,3*Dis_hor,3*Dis_ver
!
K,100,-3,3 ！定义用于确定梁的主轴方向的
！关键点
K,200,5,20
！生成线
L,1,2 ！线1-10为柱
L,2,3
L,4,5
L,5,6
L,8,9
L,9,10
L,10,11
L,12,13
L,13,14
L,14,15
L,2,5 ！线11-18为梁
L,3,6
L,7,9
L,5,10
L,6,11
L,9,13
L,10,14
L,14,15
！定义线的属性
LSEL,S,LINE,,1,10,1 ！定义线1-10 （柱）的属性
LATT,1,,2,,100,,1
LSEL,ALL
LSEL,S,LINE,,11,18,1 ！定义线11-18（梁）的属性
LATT,1,,2,,200,,2
LSEL,ALL
！划分单元
LESIZE,ALL,0.3 ！定义单元尺寸
LEMESH,ALL ！划分单元

！---------------------------------------------------------------------------
！建立耦合与约束关系
！---------------------------------------------------------------------------
CPINTF,ALL,0.002 ！自动耦合实体模型部分
！实体模型和线模型之间有三个接口：两个柱端的连接，以及底层中跨的梁左端连接到
！第二根实体柱的侧面
！建立关键点1和第一根柱柱端的连接
！实体模型和线模型之间有三个接口：两个柱端的连接，以及底层中跨的梁左端连接到第二根实体柱的侧面
！建立关键点1和第一根柱柱端的连接
N1=NODE(0,Dis_ver+H_beam*1.5,0) ！找到对应于关键点1的节点号
num=0 ！num用于标记约束方程的编号
*DO,k,7801,7820,1 ！建立柱端一翼缘节点和节点N1之间绕Z轴转动的约束关系
num=num+1
DX=NX(k)
CE,num,0,k,UY,1,N1,UY,-1,N1,ROTZ,-DX
*ENDDO
*DO,k,7871,7890,1 ！建立柱端另一翼缘节点和节点N1之间绕Z轴转动的约束关系
num=num+1
DX=NX(k)
CE,num,0,k,UY,1,N1,UY,-1,N1,ROTZ,-DX
*ENDDO
*DO,k,7821,7869,1 ！建立柱端腹板节点和节点N1之间绕Z轴转动的约束关系
num=num+1
DX=NX(k)
CE,num,0,k,UY,1,N1,UY,-1,N1,ROTZ,-DX
num=num+1
DX=NX(k+1)
CE,num,0,k+1,UY,1,N1,UY,-1,N1,ROTZ,-DX
*ENDDO
NSEL,S,NODE,,N1 ！耦合节点N1和柱端腹板节点
！在X方向的位移
NSEL,A,NODE,,7821,7869,6
NSEL,A,NODE,,7822,7870,6
CP,NEXT,UX,ALL
NSEL,ALL
！类似地，建立关键点4和第二根柱端的连接
N4=NODE(Dis_hor,Dis_ver+H_beam*1.5,0)
*DO,k,17801,17820,1
num=num+1
DX=NX(k)
CE,num,0,k,UY,1,N4,UY,-1,N4,ROTZ,-DX
*ENDDO
*DO,k,17871,17890,1
num=num+1
DX=NX(k)
CE,num,0,k,UY,1,N4,UY,-1,N4,ROTZ,-DX
*ENDDO
*DO,k,17821,17869,1
num=num+1
DX=NX(k)
CE,num,0,k,UY,1,N4,UY,-1,N4,ROTZ,-DX
num=num+1
DX=NX(k+1)
CE,num,0,k+1,UY,1,N4,UY,-1,N4,ROTZ,-DX
*ENDDO
NSEL,S,NODE,,N4
NSEL,A,NODE,,17821,17869,6
NSEL,A,NODE,,17822,17870,6
CP,NEXT,UX,ALL
NSEL,ALL
！建立梁端关键点7和柱侧面的连接
N7=NODE(Dis_hor+H_col/2,Dis_ver,0) ！对应于关键点7的节点为N7
*DO,i,16000,16100,100 ！建立梁的上翼缘的转动约束
*DO,j,81,90,1
num=num+1
DY=NY(i+j)-Dis_ver
CE,num,0,i+j,UX,1,N7,UX,-1, N7,ROTZ,DY
*ENDDO
*ENDDO
*DO,i,17100,17200,100 ！建立梁的下翼缘的转动约束
*DO,j,81,90,1
num=num+1
DY=NY(i+j)-Dis_ver
CE,num,0,i+j,UX,1,N7,UX,-1, N7,ROTZ,DY
*ENDDO
*ENDDO
NSEL,S,NODE,,N7 ！耦合梁的腹板与柱的侧面沿
！Y方向的位移
NSEL,A,NODE,,16285,17085,100
NSEL,A,NODE,,16286,17086,100
CP,NEXT,UY,ALL
NSEL,ALL
FINISH
     
/SOLU
ANTYPE,0 ！静力分析
TREF,20 ！参考温度为20
NLGEOM,ON ！设置大变形效应
！-----------------------------------------------------------------------------
！施加静力分析荷载与边界条件
！-----------------------------------------------------------------------------
NSEL,S,LOC,Y,0 ！所有柱脚固定
D,ALL,ALL
NSEL,ALL
DK,13,UX ！框架右端设水平支撑
DK,14,UX
DK,15,UX
DK,ALL,UZ ！所有梁柱节点处设平面外支撑
DK,ALL,ROTX ！所有梁柱节点处设扭转约束
DK,ALL,ROTY
FK,3,FY,-75500 ！柱顶集中力
FK,6,FY,-151000
FK,11,FY,-151000
FK,15,FY,-75500
LSEL,S,LINE,,11,18,1 ！对所有线单元施加横梁均布荷载
ESLL,S
SFBEAM,ALL,,PRES,25400
ESEL,ALL
LSEL,ALL
NSEL,S,NODE,,20084,30084,100 ！对实体梁在腹板上部施加面均布
！荷载
NSEL,A,NODE,,20085,30085,100
SF,ALL,PRES,25400/tw_beam
NSEL,ALL
！----------------------------------------------------------------------------
！设置时间步长并求解
！----------------------------------------------------------------------------
TIME,1 ！第一步常温下的反应分析，时间为1
DELTIM,0.2 ！初始步长0.2
SOLVE ！求解
*DO,tm,60,180,60 ！设置时间从60到180，步长60
TIME,tm ！当前时间为tm
LDREAD,TEMP,,,tm,,,RTH ！读入时间tm时的温度分布
DELTIM,20 ！初始步长20
SOLVE ！求解
*ENDDO
FINISH
/POST1 ！后处理
PLNSOL,U,Y ！画出框架的变形和沿Y方向的变形
FINISH
/POST26 ！时间后处理
NSOL,2,25005,U,Y ！定义变量UY-梁的跨中挠度
NSOL,3,20004,U,X ！定义变量UX-梁的左端伸出长度
PLVAR,2,3 ！画出以上变量随时间的变化关系
FINISH

dingwei

看了你的贴。有收获。不过有些问题还是不明白。能和你联系吗？更好的交流。
QQ：42723162