- 积分
- 0
- 注册时间
- 2008-5-14
- 仿真币
-
- 最后登录
- 1970-1-1
|
FINISH
/CLEAR,START
/units,si
/TITLE, Test for EDGE-Formulation with SOLID117
!
! Parameters
*SET,l,5e-6 ! length
*SET,h,1e-6 ! height
*SET,w,5e-6 ! width
*SET,a,3e-6 ! 1st addition length of magnetic core
*SET,b,5e-6 ! 2nd addition length of magnetic core
! *** Create Model
!
FINISH
/PREP7
!
ET,1,117 ! Element type #1 is a magnetic edge element, 117.
! (We use only one in this example)
!
MP,MURX,1,1 ! Define relative permeability of material #1.
! Material #1 is the conductor made from copper
MP,RSVX,1,17.2e-9 ! Define electric resistivity of material #1.
!
MP,MURX,2,500 ! Define relative permeability of material #2.
! Material #2 is the magnetic core made from NiFe
!
MP,MURX,3,1 ! Define relative permeability of material #3.
! Material #3 is the air ambient
!
! Define rectangular block of conductor volume
! region
BLOCK,-w,w,-h,h,-15e-6,15e-6 !
!
! Define rectangular block of upper magnetic core
! volume region
BLOCK,-w-a,w+a,h+a,h+2*a,-l,l
BLOCK,w+a,w+a+b,h+a,h+2*a,-l,l
BLOCK,-w-a,-w-a-b,h+a,h+2*a,-l,l
BLOCK,w+a,w+a+b,h,h+a,-l,l
BLOCK,-w-a,-w-a-b,h,h+a,-l,l
!
! Define rectangular block of lower magnetic core ! volume region
BLOCK,-w-a,w+a,-(h+a),-(h+2*a),-l,l
BLOCK,w+a,w+a+b,-(h+a),-(h+2*a),-l,l
BLOCK,-w-a,-w-a-b,-(h+a),-(h+2*a),-l,l
BLOCK,w+a,w+a+b,-h,-(h+a),-l,l
BLOCK,-w-a,-w-a-b,-h,-(h+a),-l,l
!
! Define rectangular block of air ambient
BLOCK,-22e-6,22e-6,-15e-6,15e-6,-15e-6,15e-6
! Overlap volumes
VOVLAP,ALL
NUMCMP,VOLU
! Assign attributes to the volumes
VSEL,S,VOLU,,1
VATT,1 ! conductor
VSEL,S,VOLU,,2,11,1 ! magnetic core
VATT,2
VSEL,S,VOLU,,12 ! air ambient
VATT,3
! Mesh volumes
VSEL,S,MAT,,1,2,1 ! Conductor and magnetic core with hexaelements
ASLV,S
LSLA,S
LESIZE,ALL,3e-6
MSHKEY,1 ! MAPPED VOLUME MESH
MSHAPE,0,3D ! USING HEX
VMESH,ALL
VSEL,S,MAT,,3 ! Air ambient
ASLV,S
LSLA,S
LESIZE,ALL,3e-6
MSHKEY,0 ! FREE VOLUME MESH
MSHAPE,1,3D ! USING TET
VMESH,ALL
ALLSEL,ALL
FINISH
/SOLU
!*** Apply current density on conductor ***
ESEL,S,MAT,,1 ! Select coil element
BFE,ALL,JS,1,,,-1e9 ! Apply current density
!*** Flux parallel boundary condition at all extern area of air ambient ***
ASEL,S,EXT
DA,ALL,AZ,0
ALLSEL,ALL
! Solution parameters
ANTYPE,0
NROPT,AUTO,,
EQSLV,SPAR,,0,
PRECISION,0
MSAVE,0
PIVCHECK,1
/STATUS,SOLU
SOLVE
FINISH
/POST1
!*** Vectorplot of magnetic flux (BSUM) for magnetic core's and conductor's
! elements
/VSCALE,1,1,0
!
!*
PLVECT,B, , , ,VECT,ELEM,ON,0
ESEL,U,MAT,,3
/REPLOT
PLVECT,B, , , ,VECT,ELEM,ON,0
ESEL,U,MAT,,2
/REPLOT
/EFACET,1
PLNSOL, B,SUM, 0 |
|