【讨论】轴对称单元模态分析

ainite

以前有帖子讨论过这个问题：http://www.simwe.com/cgi-bin/ut/ ... 16929&h=1#89515
但是，一届频率虽然接近，但二阶以上就不行了。我试着做了几个例子，包括四周固支的圆盘、一端固定的圆柱。用了shell93、solid95和轴对称plane82单元。得出的结论是：在ANSYS中用轴对称单元计算的模态结果不正确。
偶郁闷中，请各位大虾支点。

ainite

有谁能告诉我：在ANSYS中用轴对称单元计算的模态结果是正确的？

htbbzzg

用轴对称单元计算振动模态，不是所有的轴对称单元都能用的，可以参考 ANSYS 帮助中的以下内容：
    Axisymmetric Elements with Nonaxisymmetric Loads - 说明又哪些轴对称单元可以进行非轴对称分析及如何进行；
    Mode 命令 - 定义用轴对称单元进行非轴对称分析时的轴向谐波数
    shell61 - 用于进行非轴对称分析的轴对称简谐壳体单元 (实际上是一个线单元)
    VM151   - 一个简支圆盘非轴对称振动的算例，使用 shell61进行计算。
  
关于 VM151：
其中提供了一个简支圆盘非轴对称振动的算例，使用 shell61进行计算。
圆盘厚度.05， 半径3，弹性模量 30e6, 泊松比 0.3, 密度 0.00073
此例我也算了一下，并使用 shell93 实际算了一个圆盘的例子，两种模型的计算结果列出如下：
    按 shell61 计算的频率结果：
        轴对称解 (前三阶)  267.67， 1611.5， 4018.9
     1个谐波的解 (前三阶)  753.74， 2628.1， 5568.1
     2个谐波的解 (前三阶)  1388.9， 3800.2， 7273.5
     3个谐波的解 (前三阶)  2166.3， 5122.9， 9131.8
     4个谐波的解 (前三阶)  3081.2， 6592.1
     5个谐波的解 (前三阶)  4129.7， 8204.3
    排列以后，前 6 阶频率为：
       267.67， 753.74， 1388.9， 1611.5， 2166.3， 2628.1
  
    按 shell93 计算，前10 阶频率为：
       267.60， 752.66， 752.66， 1385.0， 1385.0， 1610.2， 2158.9， 2158.9， 2624.2， 2624.2
    二者比较，去掉重复的频率后，显然基本一致。
    由此可见，用轴对称单元计算振动模态是完全可以的，只是需要掌握有关的技巧。
    不过，我不太主张用轴对称单元计算振动模态，原因是对于非轴对称振动频率，全面的振型显示不出来，不知是否有更好的办法显示。
  
VM151的命令流如下：
  
VM151 (Nonaxisymmetric Vibration of a Circular Plate) Input Listing
/VERIFY,VM151
/PREP7   
JPGPRF,500,100,1             ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM151, NONAXISYMMETRIC VIBRATION OF A CIRCULAR PLATE
C***          FORMULAS FOR NATURAL FREQUENCY AND MODE SHAPE, BLEVINS, PAGE 240
ET,1,SHELL61
R,1,.05            ! THICKNESS OF PLATE
MP,EX,1,30E6
MP,DENS,1,.00073
MP,PRXY,1,0.3
K,1
K,2,3
L,1,2
LESIZE,1,,,9
LMESH,1
M,ALL,UY
NSEL,S,LOC,X,0
D,ALL,UX
NSEL,S,LOC,X,3     ! SELECT NODE AT R=3 AND CONSTRAIN
D,ALL,UX,,,,,UY
NSEL,ALL
D,ALL,UZ           ! CONSTRAIN TORSIONAL DOF'S
FINISH
/SOLU     
ANTYPE,MODAL       ! MODE FREQUENCY ANALYSIS
MXPAND,3           ! EXPAND FIRST 3 MODE SHAPES
MODOPT,REDUC
OUTPR,BASIC,ALL
MODE,0             ! ZERO HARMONIC MODE
SOLVE
FINISH
/POST1
/WINDOW,1,LTOP
SET,1,1
PLDISP,1
/NOERASE
/WINDOW,1,OFF
*GET,F1,MODE,0,FREQ
FINISH
/SOLU     
MODE,1             ! FIRST HARMONIC MODE
SOLVE
FINISH
/POST1
/WINDOW,2,RTOP
SET,1,1
PLDISP,1
/WINDOW,2,OFF
*GET,F2,MODE,1,FREQ
FINISH
/SOLU     
MODE,2             ! SECOND HARMONIC MODE
SOLVE
FINISH
/POST1
/WINDOW,3,BOT
SET,1,1
PLDISP,1
*GET,F3,MODE,1,FREQ
*STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'F(0,1) ','F(1,1) ','F(1,2) '
LABEL(1,2) = 'Hz ','Hz ','Hz '
*VFILL,VALUE(1,1),DATA,269.96,756.13,1391.3
*VFILL,VALUE(1,2),DATA,F1,F2,F3
*VFILL,VALUE(1,3),DATA,ABS(F1/269.96),ABS(F2/756.13),ABS(F3/1391.3)
/COM
/OUT,vm151,vrt
/COM,------------------- VM151 RESULTS COMPARISON -------------
/COM,
/COM,                 |    TARGET   |    ANSYS   |    RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.2,'  ',F11.2,'   ',1F6.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm151,vrt
  
!  整个圆盘计算的命令流
finish
/clear,start
! /COM,ANSYS RELEASE  5.7    UP20001208       13:28:34    07/18/2003               
/PREP7   
!*
!*
ET,1,SHELL93
!*
KEYOPT,1,4,0
KEYOPT,1,5,2
KEYOPT,1,6,0
!*
R,1,0.05,0,0,   
!*
MPTEMP,,,,,,,,   
MPTEMP,1,0   
MPDATA,EX,1,,30e6   
MPDATA,PRXY,1,,0.3   
MPDATA,DENS,1,,0.00073   
!*
CYL4, , ,3   
!*
wpro,,90.000000,
ASBW,       1   
!*
wpro,,,-90.000000   
!  o,,-90.000000,   
!  o,,-90.000000,   
!*
FLST,2,2,5,ORDE,2   
FITEM,2,2   
FITEM,2,-3   
ASBW,P51X   
!*
LESIZE,ALL,0.25, , , ,1, , ,1,   
!*
FLST,5,4,5,ORDE,3   
FITEM,5,1   
FITEM,5,4   
FITEM,5,-6   
CM,_Y,AREA   
ASEL, , , ,P51X  
CM,_Y1,AREA  
CHKMSH,'AREA'   
CMSEL,S,_Y   
!*
MSHKEY,1
AMESH,_Y1   
MSHKEY,0
!*
CMDELE,_Y   
CMDELE,_Y1   
CMDELE,_Y2   
!*
CSYS,1   
!*
NROTAT,all
!*
FLST,2,160,1,ORDE,8  
FITEM,2,1   
FITEM,2,-41  
FITEM,2,962  
FITEM,2,-1001   
FITEM,2,1882
FITEM,2,-1921   
FITEM,2,2802
FITEM,2,-2840   
!*
/GO  
D,P51X, , , , , ,UX,UY,UZ, , ,   
!*
D,all, , , , , ,ROTZ, , , , ,   
!*
FINISH   
/SOLU   
!*
ANTYPE,MODAL       ! MODE FREQUENCY ANALYSIS
MODOPT,LANB,10   
EQSLV,SPAR   
LUMPM,0  
PSTRES,0
!*
MODOPT,LANB,10,0,10000, ,OFF, ,2
!*
SOLVE   
!*
FINISH   
/POST1   
!*
SET,LIST
!*

lebywind

厉害^_^

liu0311

佩服！~
学到东西！~

ainite

htbbzzg ，多谢，来日相见，就像台湾一位学弟跟我说的 "必请吃一顿大餐，以解决心头之痛！"

charmingporsche

学习了~~~~