一个关于复杂面荷载施加的例子

zhang717556119

命令流如下：
fini
/cle
/filname,ex3-6
/titile,ex3-6
!
/prep7
et,1,45
et,2,42
mp,ex,1,26e9
mp,prxy,1,0.2
mp,dens,1,2449
!
k,1
k,2,,-9
k,3,-6.35,-9
k,4,-3.35
a,1,2,3,4
!
type,2
aesize,all,0.5
amap,1,1,2,3,4 !映射划分网格
type,1
extopt,esize,15 !拉伸方向划分份数为15
extopt,aclear,1 !拉伸完成后清除面单元
vext,all,,,,,8.2 !z方向拉伸8.2米
!
et,500,63 !定义63号单元，用于施加荷载
!
type,500
asel,s,loc,x,0
amesh,all
esla,s !选择面上所有单元
nsla,s,1 选择面上所有节点（包含选所有和面相联系的节点（如面内线，关键点处的节点））
!
*get,enmax,elem,,num,max !得到选择集中最大的单元号
*get,enmin,elem,,num,min !得到选择集中最小的单元号
!
dofsel,s,fx,fy,fz !选择将进行操作的自由度
fcum,add !将力的施加方式设置为“累加”而非默认的“替代”
!
*do,i,enmin,enmax !开始对最小号到最大号单元循环
   if,esel(i),eq,1,then !选择语句，判断当前单元是否在选择集中
    *get,ae,elem,i,area !获取单元的真实面积
    xe=centrx(i) !单元中心的x坐标
    ye=centry(i) !单元中心的y坐标
    ze=centrz(i) !单元中心的z坐标
    !
    p_e=1.71e4*(ye+1) !压力公式
    f_tot=p_e*ae !单元上的合力
    esel,s,elem,,i !选择第i个单元
    nsle,s,corner !选择单元角点上的节点
    *get,nn,node,,count !得到当前选择集中节点的个数
    f_n=f_tot/nn !得到每个节点上需施加的力
     *do,j,1,nn !循环对第i个单元上的每个节点施加集中力
        f,nelem(i,j),fx,f_n*cos(16.5*3.14/180) !压力作用方向在x方向
        f,nelem(i,j),fy,f_n*sin(16.5*3.14/180) !压力作用方向在y方向
     *enddo
   *endif
    esla,s !从新选择面上所有单元
*enddo
aclear,all !清除面上的63号单元
fcum,repl !将力的施加方式还原为默认的“替代”
allsel
!
asel,s,loc,y,-9
da,all,all
!
/solu
alls
solve

xtddpla

楼主的意思是把面选出来，通过面选择单元，再把单元节点选择出来，并获取单元面积通过面积求力，再把力分配给节点，？

zhang717556119

xtddpla 发表于 2012-3-31 15:46
楼主的意思是把面选出来，通过面选择单元，再把单元节点选择出来，并获取单元面积通过面积求力，再把力分配 ...

恩，是的。。。。

zhang717556119

模样 发表于 2012-4-27 10:32
看看先

ok!   

模样

看看先  

模样

zhang717556119 发表于 2012-5-2 14:38
ok!

你知道在ansys中如何加反复荷载吗？。。。求指教。。。

zhang717556119

模样 发表于 2012-5-3 07:56
你知道在ansys中如何加反复荷载吗？。。。求指教。。。

用循环做，do循环

yun34666

不错哦。。。。

模样

zhang717556119 发表于 2012-5-3 12:15
用循环做，do循环

多谢。。。我试试。。。。