/PREP7
ET,1,182 !* 2D 4-NODE STRUCTURAL SOLID ELEMENT
KEYOPT,1,1,2 !* ENHANCE STRAIN FORMULATION
KEYOPT,1,3,2 !* PLANE STRAIN
ET,2,182
KEYOPT,2,1,2
KEYOPT,2,3,2
ET,3,202 !* 2D 4-NODE COHESIVE ZONE ELEMENT
KEYOPT,3,3,2 !* PLANE STRAIN
MP,EX,4,1.353E5 !* E11 = 135.3 GPA
MP,EY,4,9.0E3 !* E22 = 9.0 GPA
MP,EZ,4,9.0E3 !* E33 = 9.0 GPA
MP,GXY,4,5.2E3
MP,GYZ,4,5.2E3
MP,GXZ,4,5.2E3
MP,PRXY,4,0.24
MP,PRXZ,4,0.24
MP,PRYZ,4,0.46
GMAX = 0.004
TNMAX = 25 !* TENSILE STRENGTH
TB,CZM,5,,,EXPO !* COHESIVE ZONE MATERIAL
TBDATA,1,TNMAX,GMAX,1000.0
RECTNG,0,100,0,1.5 !* DEFINE AREAS
RECTNG,0,100,0,-1.5
LSEL,S,LINE,,5,8,5 !* DEFINE LINE DIVISION
LESIZE,ALL,0.75
LSEL,INVE
LESIZE,ALL, , ,200
ALLSEL,ALL
TYPE,1 !* MESH AREA 2
MAT,4
LOCAL,11,0,0,0,0
ESYS,11
AMESH,2
CSYS,0
TYPE,2 !* MESH AREA 1
ESYS,11
AMESH,1
CSYS,0
NSEL,S,LOC,X,30,100
NUMMRG,NODES
ESLN
TYPE,3
MAT,5
CZMESH,,,1,Y,0, !* GENERATE INTERFACE ELEMENTS
ALLSEL,ALL
NSEL,S,LOC,X,100 !* APPLY CONSTRAINTS
D,ALL,ALL
NSEL,ALL
FINISH
/SOLU
ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,X
NSEL,R,LOC,Y,1.5 !* APPLY DISPLACEMENT LOADING ON TOP
D,ALL,UY,10
NSEL,ALL
ESEL,ALL
ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,X
NSEL,R,LOC,Y,-1.5 !* APPLY DISPLACEMENT LOADING ON BOTTOM
D,ALL,UY,-10
NSEL,ALL
ESEL,ALL
NLGEOM,ON
AUTOTS,ON
TIME,1
NSUBST,40,40,40
OUTRES,ALL,ALL
SOLVE !* PERFORM SOLUTION
FINISH
二维的仿真.... |