本帖最后由 civilman狼人 于 2012-11-10 11:24 编辑
思路:1.建立实体或平面单元;
2.弹簧约束处再定义节点(新定义的节点可以与体或面弹簧连接节点重合,也可以不重合。重合则表示弹簧长度为零,计算时不会弹出警告;不重合则表示弹簧有一定长度,建立的模型和实际“看起来”更符合,计算时会弹出警告,要求弹簧长度为零,即节点i和j重合,但是计算结果和重合时完全一样,可不予理会该警告),用来定义弹簧单元。对于平面问题,需要定义三类弹簧,即分别提供水平、竖向和面内弯曲的约束;对于三维问题,则需要定义6种弹簧,分别提供ux,uy,uz,xy,yz和zx的刚度。
!下面为一个平面问题的静力计算问题,对于三维动力问题可做类似地修改即可,即前处理中增加弹簧种类、后处理中将静载变为动载(包括正弦载荷)即可。
finish
/clear
/PREP7
ET,1,PLANE42 !定义平面单元
ET,2,COMBIN40 !定义水平弹簧单元
ET,3,COMBIN40 !定义竖向弹簧单元
ET,4,COMBIN40 !定义xy面内抵抗弯矩弹簧单元
!定义水平弹簧单元
KEYOPT,2,1,0
KEYOPT,2,3,0
KEYOPT,2,4,0
KEYOPT,2,6,0
!定义竖向弹簧单元
KEYOPT,3,1,0
KEYOPT,3,3,2
KEYOPT,3,4,0
KEYOPT,3,6,0
!定义xy面内抵抗弯矩弹簧单元
KEYOPT,4,1,0
KEYOPT,4,3,6
KEYOPT,4,4,0
KEYOPT,4,6,0
R,1,10000,0.5,,,,, !定义水平弹簧刚度及阻尼等
R,2,20000,0.5,,,,, !定义竖向弹簧刚度及阻尼等
R,3,50000,0.5,,,,, !定义xy面内抵抗弯矩弹簧刚度及阻尼等
MP,EX,1,2.1e11 !定义平面单元物理参数
MP,PRXY,1,0.3
RECTNG,,2,,1,
LESIZE,ALL,0.1,,,,1,,,1,
amesh,1 !定义平面单元分网
n,1000,0,-0.2 !在平面单元左下角的下方建立节点1000,用来建立弹簧单元;也可定义为n,1000,0,0(弹簧长度为零),计算时不会弹出警告
n,1001,2,-0.2 !在平面单元右下角的下方建立节点1001,用来建立弹簧单元;也可定义为n,1001,2,0(弹簧长度为零),计算时不会弹出警告
TYPE,2 !在平面单元左、右下角节点1、2和下方的节点1000、1001建立水平弹簧单元
MAT,1
REAL,1
ESYS,0
SECNUM,
TSHAP,LINE
e,1000,1
e,1001,2
TYPE,3 !在平面单元左、右下角节点1、2和下方的节点1000、1001建立竖向弹簧单元
MAT,1
REAL,2
ESYS,0
SECNUM,
TSHAP,LINE
e,1000,1
e,1001,2
TYPE,4 !在平面单元左、右下角节点1、2和下方的节点1000、1001建立xy面内抵抗弯矩弹簧
MAT,1
REAL,3
ESYS,0
SECNUM,
TSHAP,LINE
e,1000,1
e,1001,2
FINISH
/SOL
d,1000,all !约束节点1000
d,1001,all !约束节点1001
f,32,fx,100 !在平面单元的右上角施加水平载荷
solve
FINISH
/POST1
/EFACET,1
PLNSOL,U,SUM,0,1.0 !显示整体变形
AVPRIN,0,,
ETABLE,f1,SMISC,1 !定义弹簧单元一端节点i轴向力
AVPRIN,0,,
ETABLE,f2,SMISC,2 !定义弹簧单元另一端节点j轴向力
PRETAB,F1,F2 !列出各个弹簧轴向力
(模型图) 总体变形图
|