求助，压电变压器与电阻负载的耦合问题，有图，有命令流

agoodman

先贴上命令流
!ansys中压电材料参数输入默认为[CE][e][εS]
FINISH
/CLEAR
/PREP7
/COM    Use PZT5A and METAL
ET,1,SOLID5,3       !压电材料使用solid5单元
ET,2,SOLID45         !金属材料使用solid45单元
MP,DENS,2,2500        !金属密度         
MP,NUXY,2,0.22        !金属泊松比  
MP,EX,2,7.2E10        !金属弹性模量



!压电材料参数输入
MP,DENS,1,7750        !压电材料的密度

TB,PIEZ,1               !define piezo. table for pzt
TBDATA,3,-5.3512           ![e] 压电常数矩阵
TBDATA,6,-5.3512
TBDATA,9,15.784
TBDATA,14,12.295
TBDATA,16,12.295

MP,PERX,1,919                !介电常数  εS
MP,PERY,1,919
MP,PERZ,1,826

TB,ANEL,1                   ![CE] 压电应力矩阵
TBDATA,1,12.035E10,7.518E10,7.509E10
TBDATA,7,12.035E10,7.509E10
TBDATA,12,11.087E10
TBDATA,21,2.105E10
TBDATA,19,2.105E10
TBDATA,16,2.257E10

/COM       geometric parameters
R=1.5E-2     !器件的半径
TM=1E-3    !中间金属层的厚度
TIN=1E-3     !压电输入层的厚度
TOUT=1E-3    !压电输出层的厚度
Vin=1     !激励电压的幅值

!负载电阻
RL=100


LSIZE=2E-3 !网格分割的大小

CSYS,1      !使用柱坐标
CYLIND,,R,-TM/2,TM/2,0,360       !建立金属层的模型
CYLIND,,R,TM/2,TM/2+TIN,0,360    !建立输入层的模型
CYLIND,,R,TM/2+TIN,TM/2+TIN+TOUT,0,360    !建立输出层的模型
CYLIND,,R,-TM/2-TIN,-TM/2,0,360            !建立输入层的模型
CYLIND,,R,-TM/2-TIN-TOUT,-TM/2-TIN,0,360    !建立输出层的模型

ALLSEL,ALL   !将各层黏贴起来
VGLUE,ALL
ALLSEL,ALL

!网格划分
LSEL,S,LOC,Z,-TM/2-TIN-TOUT,TM/2+TIN+TOUT
LESIZE,ALL,LSIZE,,,,1,,,1



AllSEL,ALL

VSEL,S,LOC,Z,-TM/2,TM/2
VATT,2,,2
VSWEEP,ALL

ALLSEL,ALL
VSEL,U,LOC,Z,-TM/2,TM/2
VATT,1,,1
VSWEEP,ALL

!定义电阻单元
ET,3,CIRCU94,0
R,1,RL
!定义电阻连接点
ALLSEL,ALL
*GET,NODE1,NODE,,NUM,MAX
*SET,NODE1,NODE1+1
*SET,NODE2,NODE1+1
N,NODE1,2*R,0,TM+TIN+TOUT
N,NODE2,2*R,0,-TM-TIN-TOUT
ALLSEL,ALL
TYPE,3
REAL,1
E,NODE1,NODE2




!定义输入电极
ALLSEL,ALL
NSEL,S,LOC,Z,TM/2
NSEL,A,LOC,Z,-TM/2
CP,1,VOLT,ALL
*get,n_vi,node,0,num,min

!加载激励电压
D,n_vi,VOLT,Vin



!定义地
ALLSEL,ALL
NSEL,S,LOC,Z,TM/2+TIN
NSEL,A,LOC,Z,-TM/2-TIN
NSEL,A,NODE,,NODE1
CP,2,VOLT,ALL
*get,n_ground,node,0,num,min
D,n_ground,VOLT,0


!定义输出电极
ALLSEL,ALL
NSEL,S,LOC,Z,TM/2+TIN+TOUT
NSEL,A,LOC,Z,-TM/2-TIN-TOUT
NSEL,A,NODE,,NODE2
CP,3,VOLT,ALL
*get,n_vo,node,0,num,min

!短路
!D,n_vo,VOLT,0



!定义简支边界条件  (待定)
ALLSEL,ALL
csys,1
NSEL,S,LOC,X,R
D,ALL,UZ,0

ALLSEL,ALL

save

FINISH

/SOLU
eqslv,sparce
antype,harmic
hropt,full
outers,all,all
harfrq,10E3,20E3
nsubst,20
kbc,1
solve
FINISH



/POST26
RFORCE,2,N_VI,AMPS       
CFACT,,,,1      !定义虚数i
PROD,3,2,1,,MHOS,,,-2*3.1416   ! 计算导纳Y=-jwQ/V
ABS,4,3,,,Yamp,,,1,               ! 求Y幅值_模
CONJUG,5,3,,,ConY,,,1          ! 求Y共轭G-Bj
QUOT,6,5,4,, ,,,1                   ! 除以模值
QUOT,6,6,4,,Zohm,,,1            ! 再除以模值，获得阻抗Z=1/Y=（G-Bj)/(G^2+B^2)

agoodman

当我取RL电阻为500欧姆时，得到的变压器输入阻抗图为

agoodman

阻抗太小，实际上应该数量级应该为1000欧姆到4000欧姆之间，请求高手解答
还有就是不考虑电阻时，得到的短路和开路输入阻抗就是正确的，有图

agoodman

不考虑电阻的开路和短路代码就是去掉
!定义电阻单元
ET,3,CIRCU94,0
R,1,RL
!定义电阻连接点
ALLSEL,ALL
*GET,NODE1,NODE,,NUM,MAX
*SET,NODE1,NODE1+1
*SET,NODE2,NODE1+1
N,NODE1,2*R,0,TM+TIN+TOUT
N,NODE2,2*R,0,-TM-TIN-TOUT
ALLSEL,ALL
TYPE,3
REAL,1
E,NODE1,NODE2

agoodman

不要沉啊

hy1966

谐分析系统阻尼要加，谐振附近的点要密一些