钢板剪力墙滞回分析

gongzhaoyu6

结构为两层钢板剪力墙，梁柱采用梁单元，钢板墙采用壳单元，先对结构进行屈曲分析，施加0.001倍的一阶模态作为初始缺陷，再对结构进行非线性屈曲分析。施加往复循环荷载，分别为11mm/-11mm，22mm/-22mm，33mm/-33mm，44mm/-44mm，55mm/-55mm，66mm/-66mm，但是每当加载到第四级荷载44mm/-44mm时，就不收敛停止计算了，恳请各位朋友给予指点。以下是命令。


FINI
/CLEAR
/FILNAM,Z1
/TITLE,shear wall
/CONFIG,NRES,40000

!主要控制参数
!框架尺寸
H0=325  $H1=200  $H=2725  $LS=1100
!梁
hb1=200  $hb2=300  $bb=120  $t1=6.5  $t2=10.7
!柱
hc=200  $bc=120  $t3=7  $t4=10
!内填钢板
LX=1100  $LY=1100  $TS=2.2

/PREP7
!!!!*****定义单元类型*****!!!!
ET,1,BEAM188
ET,2,SHELL181

!!!!*****定义实常数*****!!!!
R,1,TS

!!!!*****定义材料本构*****!!!!
!内嵌钢板
mptemp,1,0
mpdata,EX,1,,2.03E5
mpdata,PRXY,1,,0.3
TB,Bkin,1,1,2,1
TBTEMP,0
TBDATA,,296,0.02*203000,,,,

!梁柱
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,2,,2.03E5
MPDATA,PRXY,2,,0.3
TB,Bkin,2,1,2,1
TBTEMP,0
TBDATA,,378,0.02*203000,,,,

!!!!*****定义梁柱截面尺寸*****!!!!
!梁
sectype,2,beam,i,,2
secoffset,orig
secdata,bb,bb,hb2,t2,t2,t1

sectype,3,beam,i,,2
secoffset,cent
secdata,bb,bb,hb1,t2,t2,t1

sectype,4,beam,i,,2
secoffset,user,0,hb2
secdata,bb,bb,hb2,t2,t2,t1

!柱
sectype,5,beam,i,,2
secoffset,user,0,hc
secdata,bc,bc,hc,t4,t4,t3

sectype,6,beam,i,,2
secoffset,orig
secdata,bc,bc,hc,t4,t4,t3

!!!!*****建立几何模型*****!!!!
!创建梁柱关键点
K,1,0,0,0
K,2,0,325,0
K,3,0,1425,0
K,4,0,2525,0
K,5,0,2725,0

K,6,LS,0,0
K,7,LS,325,0
K,8,LS,1425,0
K,9,LS,2525,0
K,10,LS,2725,0

!定义方向关键点
K,100,1300,2925,0
allsel,all

L,1,2
L,2,3
L,3,4
L,4,5
L,6,7
L,7,8
L,8,9
L,9,10
L,2,7
L,3,8
L,4,9

ALLSEL,ALL
CM,KJ,LINE

BLC4,0,325,1100,1100
BLC4,0,1425,1100,1100
ASEL,ALL
CM,SPSW,AREA
ALLS

!!!!*****划分网格*****!!!!
!内嵌钢板
ASEL,S,,,SPSW
ALLSEL,BELOW,AREA
LSEL,R,LENGTH,,LX
LESIZE,ALL,,,22

ASEL,S,,,SPSW
ALLSEL,BELOW,AREA
LSEL,R,LENGTH,,LY
LESIZE,ALL,,,22

AATT,1,1,2
AMESH,ALL
ALLSEL,ALL

!梁柱
LSEL,S,,,KJ
ALLSEL,BELOW,LINE
LSEL,R,,,9
LATT,2,,1,,100,,4
LESIZE,ALL,,,22
LMESH,ALL

LSEL,S,,,KJ
ALLSEL,BELOW,LINE
LSEL,R,,,10
LATT,2,,1,,100,,3
LESIZE,ALL,,,22
LMESH,ALL

LSEL,S,,,KJ
ALLSEL,BELOW,LINE
LSEL,R,,,11
LATT,2,,1,,100,,2
LESIZE,ALL,,,22
LMESH,ALL

LSEL,S,,,KJ
ALLSEL,BELOW,LINE
LSEL,R,,,1,4,3
LATT,2,,1,,100,,5
LESIZE,ALL,,,4
LMESH,ALL

LSEL,S,,,KJ
ALLSEL,BELOW,LINE
LSEL,R,,,2,3
LATT,2,,1,,100,,5
LESIZE,ALL,,,22
LMESH,ALL

LSEL,S,,,KJ
ALLSEL,BELOW,LINE
LSEL,R,,,5,8,3
LATT,2,,1,,100,,6
LESIZE,ALL,,,4
LMESH,ALL

LSEL,S,,,KJ
ALLSEL,BELOW,LINE
LSEL,R,,,6,7
LATT,2,,1,,100,,6
LESIZE,ALL,,,22
LMESH,ALL
ALLS

NUMMRG,NODE,1,,,LOW
NUMCMP,NODE
ALLSEL,ALL

/SOLU
NSEL,S,LOC,Y,0
D,ALL,ALL
ALLS


F,552,FX,1
ANTYPE,STATIC
PSTRES,ON
TIME,1
NSUBST,5,5000,1
ALLSEL,ALL
SOLVE
FINI

/SOLU
ANTYPE,BUCKLE
PSTRES,ON
BUCOPT,LANB,2,0,0
MXPAND,1,0,0,0,0.001
ALLSEL,ALL
SOLVE

/PREP7
FACTOR=0.001
UPGEOM,FACTOR,last,last,Z1,RST
SAVE

/SOLU
NSEL,S,LOC,Y,0
D,ALL,ALL
ALLS
NSEL,S,LOC,Y,325
D,ALL,UZ
ALLS
NSEL,S,LOC,Y,1425
D,ALL,UZ
ALLS
NSEL,S,LOC,Y,2525
D,ALL,UZ
ALLS
NSEL,S,LOC,X,0
D,ALL,UZ
ALLS
NSEL,S,LOC,X,LX
D,ALL,UZ
ALLS

ANTYPE,0
NLGEOM,ON
LNSRCH,ON
PRED,ON,,ON
SSTIF,ON
NROPT,FULL
CNVTOL,F,,0.15,2,,
NEQIT,300
*SET,DDD,552

!循环加载
!!!!1%,11mm,cyclic-2
d,DDD,ux,11
allsel  
kbc,0   
nsubst,400,500000,10
outres,all,all  
solve   
d,DDD,ux,-11
allsel  
kbc,0   
nsubst,400,500000,10
outres,all,all  
solve   

!!!!2%,22mm,cyclic-2
d,DDD,ux,22
allsel  
kbc,0   
nsubst,800,500000,10   
outres,all,all  
solve   
d,DDD,ux,-22
allsel  
kbc,0   
nsubst,800,500000,10
outres,all,all  
solve   

!!!!3%,33mm,cyclic-2
d,DDD,ux,33
allsel  
kbc,0   
nsubst,1000,500000,5   
outres,all,all  
solve   

d,DDD,ux,-33
allsel  
kbc,0   
nsubst,2000,1000000,5   
outres,all,all  
solve   


!!!!4%,44mm,cyclic-2
d,DDD,ux,44
allsel  
kbc,0   
nsubst,2500,10000000,5  
outres,all,all  
solve   
d,DDD,ux,-44
allsel  
kbc,0   
nsubst,2500,10000000,5   
outres,all,all  
solve

!!!!5%,55mm,cyclic-2
d,DDD,ux,55
allsel  
kbc,0   
nsubst,3000,10000000,5   
outres,all,all  
solve   
d,DDD,ux,-55
allsel  
kbc,0   
nsubst,3000,1000000,5  
outres,all,all  
solve

!!!!6%,66mm,cyclic-2
d,DDD,ux,66
allsel  
kbc,0   
nsubst,4000,10000000,5   
outres,all,all  
solve   
d,DDD,ux,-66
allsel  
kbc,0   
nsubst,4000,10000000,5   
outres,all,all  
solve  


/post26
nsol,2,552,u,x  
rforce,3,552,f,x
xvar,2  
plvar,3