复合材料看某一层的应力分布

13805001tian

刚开始接触复合材料，网上找了一个例子，请问后处理中怎么看某一层的应力分布。试了命令：LAYER,n   !n表示第n层，貌似不管用。谢谢！
命令流：
finish
/clear
/PREP7
ET,1,181                !定义单元类型         
KEYOPT,1,8,2

L=0.01                        !模型长度
W=0.01                        !模型宽度

MP,EX,1,181E9                !定义材料特性
MP,EY,1,10.3E9
MP,EZ,1,10.3E9
MP,PRXY,1,0.28
MP,PRyz,1,0.3
MP,PRxz,1,0.28
MP,GXY,1,7.17e9
MP,GYZ,1,3.78e9        
MP,GXZ,1,7.17e9
MP,dens,1,1600

sect,1,shell,,                 
secdata,0.125e-3,1,0,3        !厚度、材料号、铺层角、积分点
secdata,0.125e-3,1,90,3
secdata,0.125e-3,1,45,3
secdata,0.125e-3,1,45,3
secdata,0.125e-3,1,90,3
secdata,0.125e-3,1,0,3

rect,0,L,0,W
ESIZE,0.0001
mshape,0,2d
mshkey,1
AMESH,ALL
/eshape,1

/SOLU
nsel,s,loc,x,0
d,all,ux
nsel,r,loc,y,0
d,all,all
nsel,s,loc,y,0
d,all,uy
nsel,s,loc,x,L
*get,nn,node,,count
f,all,fx,1e5*L/nn
cp,next,ux,all
nsel,s,loc,y,W
*get,nn,node,,count
f,all,fy,0.5e5*W/nn
cp,next,uy,all
allsel
OUTPR, ,1
SOLVE

/post1
PLNSOL,S,x,0,1

御水风

楼主解决该问题了吗？

hwcudca

你需要把命令流中的/eshape，1锁住就可以了。否则就是所有层的应力一起显示，Layer，n当然就没有用了。

yangwk43090404

hwcudca 发表于 2014-8-16 16:37
你需要把命令流中的/eshape，1锁住就可以了。否则就是所有层的应力一起显示，Layer，n当然就没有用了。 ...

请问，把/ehape,1锁住是什么意思啊？

hwcudca

:lol,就是把你的代码中的/eshape，1这一句改成！/eshape，1，或者是直接删掉这句话，然后你用layer，n，就可以查看每一层的应力了