ansys焊接模拟分析（壳单元）

zndxwdm

这是我写的一个壳单元的焊接例子，为什么输入d,all,temp,25后提示igonred呢？请各位不吝指教！


finish  
/clear  
/filname,welding
/prep7  
Et,1,shell131
MPTEMP,,,,,,,,  
MPTEMP,1,20
MPTEMP,2,200
MPTEMP,3,500
MPTEMP,4,750
MPTEMP,5,1000   
MPTEMP,6,1500   
MPTEMP,7,1700   
MPTEMP,8,2500   
MPDATA,KXX,1,,50
MPDATA,KXX,1,,47
MPDATA,KXX,1,,40
MPDATA,KXX,1,,27
MPDATA,KXX,1,,30
MPDATA,KXX,1,,35
MPDATA,KXX,1,,40
MPDATA,KXX,1,,55
MPDATA,DENS,1,,7820
MPDATA,DENS,1,,7700
MPDATA,DENS,1,,7610
MPDATA,DENS,1,,7550
MPDATA,DENS,1,,7490
MPDATA,DENS,1,,7350
MPDATA,DENS,1,,7300
MPDATA,DENS,1,,7090
MPDATA,C,1,,460
MPDATA,C,1,,480
MPDATA,C,1,,530
MPDATA,C,1,,675
MPDATA,C,1,,670
MPDATA,C,1,,660
MPDATA,C,1,,780
MPDATA,C,1,,820
MPDATA,EX,1,,2.05E11
MPDATA,EX,1,,1.87E11
MPDATA,EX,1,,1.5E11
MPDATA,EX,1,,0.7E11
MPDATA,EX,1,,0.2E11
MPDATA,EX,1,,0.19E2
MPDATA,EX,1,,0.18E2
MPDATA,EX,1,,0.12e2
MPDATA,PRXY,1,,0.28
MPDATA,PRXY,1,,0.29
MPDATA,PRXY,1,,0.31
MPDATA,PRXY,1,,0.35
MPDATA,PRXY,1,,0.4  
MPDATA,PRXY,1,,0.45
MPDATA,PRXY,1,,0.48
MPDATA,PRXY,1,,0.5  
UIMP,1,REFT,,,20
MPDATA,ALPX,1,,1.1e-5   
MPDATA,ALPX,1,,1.22e-5  
MPDATA,ALPX,1,,1.39e-5  
MPDATA,ALPX,1,,1.48e-5  
MPDATA,ALPX,1,,1.34e-5  
MPDATA,ALPX,1,,1.33e-5  
MPDATA,ALPX,1,,1.32e-5  
MPDATA,ALPX,1,,1.31e-5  
TB,BISO,1,6,2,  
TBTEMP,20   
TBDATA,,220e6,0,,,,
TBTEMP,250  
TBDATA,,175e6,0,,,,
TBTEMP,500  
TBDATA,,80e6,0,,,,  
TBTEMP,750  
TBDATA,,40E6,0,,,,  
TBTEMP,1000
TBDATA,,10E6,0,,,,  
TBTEMP,1500
TBDATA,,1E-5,0,,,,  
k,1,,,  
k,2,,0.005,,
k,3,,0.01,,
k,4,,0.015,,
k,5,,0.035,
k,6,0.12,,  
k,7,0.12,0.005,,
k,8,0.12,0.01,,
k,9,0.12,0.015  
k,10,0.12,0.035
a,1,2,7,6   
a,2,3,8,7   
a,3,4,9,8   
a,4,5,10,9  
sectype,1,shell   
secoffset,mid
secdata,0.016,0.004
allsel,all  
aatt,1,,1,,1  
ASEL,s,,,2  
asel,a,,,3  
aesize,all,0.002
asel,s,,,1  
aesize,all,0.001
asel,s,,,4  
aesize,all,0.004
allsel,all  
mshape,0,2d
mshkey,1
amesh,all   
nummrg,all  
numcmp,all  
FINISH  

*SET,rb,0.001   
*SET,length,0.12                                !长度120mm
*SET,width,0.035                                !宽度35mm  
v=0.002                                         !焊接速度为2mm/s      
tinc=rb/v                                       !每个单元焊接时间
tm=length/v                                       !焊接时间为60S
U=13.2                                           !焊接电压
I=80                                             !焊接电流
ef=0.65                                          !焊接效率
p=U*I*ef                                         !焊接功率
r=0.003                                          !电弧热流分布参数2
qmax=3*p/(3.14159*r**2)                          !最大焊接热流密度，3为热流集中系数常数

max_time=length/rb+1                            !焊接长度总节点数
max_x=length/rb+1                                !长度总节点数
max_y=width/rb+1                                !宽度总节点数
*dim,flux2,table,max_x,max_y,max_time,x,y,time  !定义热流FLUX2
*do,k,1,max_time,1
    *do,i,1,max_x,1
      flux2(i,0,k)=(i-1)*rb
    *enddo

    *do,j,1,max_y,1
      flux2(0,j,k)=(j-1)*rb
    *enddo


  *do,i,1,max_x,1
    *do,j,1,max_y,1
     xcenter=v*(k-1)*tinc                          !焊接时单元停留长度坐标值
     ycenter=0
     distance=sqrt(((i-1)*rb-xcenter)**2+((j-1)*rb-ycenter)**2)!!所有点距离焊枪的距离
     *if,distance,le,r,then
      flux2(i,j,k)=qmax/exp(3*distance**2/(r**2))!!!!高斯热源
     *else
      flux2(i,j,k)=0
     *endif
    *enddo
   *enddo
  flux2(0,0,k)=(k-1)*tinc               !焊接时间跟踪累加
*enddo
/solu
antype,4                             
tunif,20   
tintp,0.005,,,1,,,                   !设置向后积分
kbc,1
timint,off
autots,on
ALLSEL,ALL
tref,20
time,1e-6
nsel,s,loc,x,0
nsel,a,loc,x,0.12
d,all,temp,20
NSUBST,1
solve               !进行稳态求解，得到初始条件
ddele,all,temp

*do,t,tinc,tm,tinc  
time,t  
allsel,all  
timint,on
sf,all,hflux,%flux2%  !flux2是先前定义的热流  
allsel,all  
nropt,full,,on     !牛顿迭代   
autots,1    !时间不跟踪
nsubst,10,,,1  !载荷步中子步数量   
kbc,1    !阶越载荷的施加  
lnsrch,1    !打开线性搜索
tsres,erase  !去掉时间表格
tintp,,,,1,,,,,  !指定瞬态积分参数   
solve
*enddo
!!冷却阶段一以1秒为步长到80秒
*DO,I,1,20
TIME,1*I+tm
allsel,all
AUTOTS,1
nsubst,10,,,1
LNSRCH,1
KBC,1  
TSRES,ERASE   !去掉时间表格
tintp,,,,1,,,,,
SOLVE
*ENDDO

!冷却阶段一以10秒为步长到280秒

*DO,I,1,20
TIME,10*I+tm+20
allsel,all
autots,1
nsubst,10,,,1
LNSRCH,1
KBC,1  
TSRES,ERASE
tintp,,,,1,,,,,
SOLVE
*ENDDO

esel,all
esln,s,1,all

eplot
allsel,all

save
finish
  
!******************************************************************!
!!!!!!!!!!!!!!!   热－结构单元转换   
!******************************************************************!
FINISH
/PREP7
rb=0.001
length=0.12                            !长度120mm                       
width=0.035                            !宽度35mm
v=0.002                                !焊接速度为2mm/s      
tinc=rb/v                              !每个单元焊接时间
tm=length/v                            !焊接时间为60S
ALLSEL,ALL
ETCHG,TTS                              !转换单元shell131－>shell181
TOFFST,273

ALLSEL,ALL                              !删除温度场计算过程可能遗留的边界条件
SFDELE,ALL,ALL                          !删除面载荷
SFEDELE,ALL,ALL,ALL                     !删除作用在单元上的面载荷
bFEDELE,ALL,ALL,ALL                     !删除作用在单元上的体载荷
DDELE,all,all                           !删除所有的体载荷

SAVE

!******************************************************************!
!            热应力求解器及选项      
!******************************************************************!
FINISH                                   !进入热应力求解器,确定分析类型等
/SOLU
ANTYPE,4
TRNOPT,FULL
LUMPM,0                                !指定使用与单元相关的质量矩阵公式
  
!热应力求解选项设定(大变形、缩减因子、线性搜索、自动时间步长等)
nlgeom,on                               !打开大位移效果（Turns large-deflection effects on）
NROPT,FULL,,ON                         !设定牛顿－拉夫森选项
ESTIF,1e-16                           !设定非默认缩减因子（默认1E-6，可选）
PRED,ON                                !预测器，即根据前面子步的结果预测温度结果；它在模型的非线性响应
                                       !随时间变化较剧烈的情况下非常有效。默认：自动预测每个子步后的结果。
TOFFST,273

LNSRCH,1                              !线性搜索开/关；
AUTOTS,ON                             !自动时间步长。有利于非线性收敛。
KBC,0                                 ! Loads are linearly interpolated (ramped)

TIMINT,1,STRUCT                       !Turns on transient effects
TIMINT,0,THERM
TIMINT,0,MAG
TINTP,0.005,,,1,0.5,0.2
CNVTOL,F,,0.05,2,0.01                 !非线性分析设置收敛数值
RESCONTROL,DEFINE,NONE,NONE,0         !不生成多点重启动文件
CUTCONTROL,PLSLIMIT,10,               ! Maximum equivalent plastic strain allowed within a time-step

OUTPR,NSOL,-2, !每个两步保存一次数据
OUTRES,NSOL,LAST !保存基本数据
tref,25
!******************************************************************!
!  热应力求解边界约束条件     
!******************************************************************!
!施加力学边界约束条件（约束的形式直接决定热应力是否收敛）

ALLSEL,ALL
nsel,s,loc,x,0
nsel,a,loc,x,0.12
nsel,a,loc,y,0.035
d,all,all
!******************************************************************!
            !热应力求解过程      
!******************************************************************!
!注意：在进行热应力求解是，LDREAD命令中的ntstep变量为载荷步数，不是时间


!冷却时的计算
*do,t,tinc,tm,tinc
allsel,all
time,t
AUTOTS,1
nsubst,10,,,1
LDREAD,TEMP,,,t,,'welding','rth'
solve
*ENDDO

*DO,t,61,80,1
allsel,all
TIME,t
AUTOTS,1
nsubst,10,,,1
LDREAD,TEMP,,,t,,'welding','rth'
solve
*ENDDO

*DO,t,90,280,10
allsel,all
TIME,t
AUTOTS,1
nsubst,10,,,1
LDREAD,TEMP,,,t,,'welding','rth'
solve
*ENDDO