最近做了一个椭球/双椭球体热元加载的例子,发现了一个有趣的问题:先把命令流附上:
/UNITS,SI
/CONFIG,NRES,10000
/PREP7
ET,1,SOLID70
MP,DENS,1,7930
MP,C,1,502
mptemp,1,20,100,500
mpdata,kxx,1,1,12.1,16.3,21.4
/VIEW,1,1,1,1
!*************定义基板尺寸***********
lx=0.1
lz=0.1
ly=0.006
!*************定义焊接参数***********
weld=0.015 !每道焊道宽度
wheight=0.004 !焊道的高度
LSIZE=0.005
V=0.008 !速度
tinc=LSIZE/V !每小段的时间间隔
pi=3.1415926
U=25
I=180
Q=U*I !电源有效功率
effect=0.8
f1=0.6
f2=1.4
ah=0.006
chf=2*ah
chb=8*ah
bh=0.004
Qmax11=6*effect*3**(1/2)*f1*q/(pi*pi**(1/2)*ah*bh*chf)
Qmax12=6*effect*3**(1/2)*f2*q/(pi*pi**(1/2)*ah*bh*chb)
!*****************建立模型,生成网格**************
block,0,lx,0,ly,0,lz
wpoff,0,ly,lz/2
block,0,lx,0,wheight,-weld/2,weld/2
wpoff,0,0,-weld/2
vsbw,all,,delete
wpoff,0,0,weld
vsbw,all,,delete
vglue,all
lsel,s,,,p
lsel,s,line,,26
lsel,a,line,,30
lsel,a,line,,33
lsel,a,line,,35
lsel,s,line,,26
lsel,a,line,,30
lsel,a,line,,33
lsel,a,line,,35
lesize,all,0.005,,,0.2,,,,1
lsel,s,line,,9,10
lsel,a,line,,12
lsel,a,line,,38
lesize,all,0.005,,,0.2,,,,1
lsel,s,line,,2
lsel,a,line,,4,5
lsel,a,line,,7
lsel,a,line,,14
lsel,a,line,,16
lsel,a,line,,19
lsel,a,line,,39
lesize,all,0.0025,,,1,,,,1
lsel,s,line,,23,24
lsel,a,line,,41,42
lsel,a,line,,45
lsel,a,line,,47
lsel,s,line,,23,24
lsel,a,line,,41,42
lsel,a,line,,45
lsel,a,line,,47
lesize,all,0.0025,,,1,,,,1
vmesh,all
/PNUM,DEFA
EPLOT
fini
SAVE
/solu
antype,trans,new
nlgeom,on
timint,0,struct
timint,1,therm
timint,0,mag
timint,0,elect
tref,25
nropt,auto
autos,on
kbc,0
pred,on
lnsrch,on
!************杀死焊缝去单元***********
nsel,s,loc,y,ly,ly+wheight
esln,s,1
CM,weld_elem,ELEM
ekill,all
esel,s,elem,,weld_elem
nsle,s
cm,weld_node,node
ALLSEL,ALL
esel,s,live
eplot
!**********施加对流载荷*************
esel,s,live
nsel,s,loc,z,0
nsel,a,loc,z,lz
nsel,a,loc,x,0
nsel,a,loc,x,lx
sf,all,conv,10,25
ALLSEL,ALL
esel,s,live
nsel,s,loc,y,ly
nsel,u,loc,z,lz/2-weld/2,lz/2+weld/2
nsel,a,loc,x,lx
sf,all,conv,10,25
ALLSEL,ALL
!************定义数组维数**********
MAX_X=1+lx/LSIZE
!*************定义table数组******************************************
*do,i,1,MAX_X,1
XX=(I-1)*LSIZE
!!!!!!!生死单元的处理
nsel,s,node,,weld_node
nsel,r,loc,x,XX-chf/2,XX+chf/2
cm,cur_node,node
esln,s
ealive,all
nsel,s,node,,weld_node
nsel,u,node,,cur_node
cm,weld_node,node
!!!!!!双椭球体热源的加载
ALLSEL,ALL
!!!双椭球热源的加载
!!!前半球节点的选取
local,11,2,XX,ly+wheight,lz/2,,,,bh/chf,ah/chf,
NSEL,S,LOC,X,0,chf
NSEL,R,LOC,Y,270,360
NSEL,R,LOC,Z,0,180
CM,FRONT,NODE
ALLSEL,ALL
!!!!!!!!!!!!!!!!!!!!!!!!!!!
LOCAL,13,0,XX,ly+wheight,lz/2, , , ,1,1,
*DEL,_FNCNAME
*DEL,_FNCMTID
*DEL,_FNC_C1
*DEL,_FNC_C2
*DEL,_FNC_C3
*DEL,_FNC_C4
*DEL,_FNCCSYS
*DEL,'front'
*SET,_FNCNAME,'front'
*DIM,_FNC_C1,,1
*DIM,_FNC_C2,,1
*DIM,_FNC_C3,,1
*DIM,_FNC_C4,,1
*SET,_FNC_C1(1),qmax11
*SET,_FNC_C2(1),chf
*SET,_FNC_C3(1),bh
*SET,_FNC_C4(1),ah
*SET,_FNCCSYS,13
! /INPUT,front.func,,,1
*DIM,%_FNCNAME%,TABLE,6,20,1,,,,%_FNCCSYS%
!
! Begin of equation: Qmax11*exp(-3(({x}/chf)^2+({y}/bh)^2+({z}/ah)^2))
*SET,%_FNCNAME%(0,0,1), 0.0, -999
*SET,%_FNCNAME%(2,0,1), 0.0
*SET,%_FNCNAME%(3,0,1), %_FNC_C1(1)%
*SET,%_FNCNAME%(4,0,1), %_FNC_C2(1)%
*SET,%_FNCNAME%(5,0,1), %_FNC_C3(1)%
*SET,%_FNCNAME%(6,0,1), %_FNC_C4(1)%
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 0, 0, 0, 0
*SET,%_FNCNAME%(0,2,1), 0.0, -2, 0, 1, 0, 0, -1
*SET,%_FNCNAME%(0,3,1), 0, -3, 0, 1, -1, 2, -2
*SET,%_FNCNAME%(0,4,1), 0.0, -1, 0, 1, 2, 4, 18
*SET,%_FNCNAME%(0,5,1), 0.0, -2, 0, 2, 0, 0, -1
*SET,%_FNCNAME%(0,6,1), 0.0, -4, 0, 1, -1, 17, -2
*SET,%_FNCNAME%(0,7,1), 0.0, -1, 0, 1, 3, 4, 19
*SET,%_FNCNAME%(0,8,1), 0.0, -2, 0, 2, 0, 0, -1
*SET,%_FNCNAME%(0,9,1), 0.0, -5, 0, 1, -1, 17, -2
*SET,%_FNCNAME%(0,10,1), 0.0, -1, 0, 1, -4, 1, -5
*SET,%_FNCNAME%(0,11,1), 0.0, -2, 0, 1, 4, 4, 20
*SET,%_FNCNAME%(0,12,1), 0.0, -4, 0, 2, 0, 0, -2
*SET,%_FNCNAME%(0,13,1), 0.0, -5, 0, 1, -2, 17, -4
*SET,%_FNCNAME%(0,14,1), 0.0, -2, 0, 1, -1, 1, -5
*SET,%_FNCNAME%(0,15,1), 0.0, -1, 0, 3, 0, 0, -2
*SET,%_FNCNAME%(0,16,1), 0.0, -4, 0, 1, -1, 3, -2
*SET,%_FNCNAME%(0,17,1), 0.0, -1, 0, 1, -3, 3, -4
*SET,%_FNCNAME%(0,18,1), 0.0, -1, 7, 1, -1, 0, 0
*SET,%_FNCNAME%(0,19,1), 0.0, -2, 0, 1, 17, 3, -1
*SET,%_FNCNAME%(0,20,1), 0.0, 99, 0, 1, -2, 0, 0
! End of equation: Qmax11*exp(-3(({x}/chf)^2+({y}/bh)^2+({z}/ah)^2))
!-->
BF,FRONT,HGEN,%front%
CMDELE,FRONT
ALLSEL,ALL
!!!后半球节点的选取
local,12,2,XX,ly+wheight,lz/2,,,,bh/chb,ah/chb,
NSEL,S,LOC,X,0,chb
NSEL,R,LOC,Y,180,270
NSEL,R,LOC,Z,0,180
CM,BEHIND,NODE
ALLSEL,ALL
!!!!!!!!!!!!!!!!!!!!!!!!!!!
LOCAL,14,0,XX,ly+wheight,lz/2, , , ,1,1,
*DEL,_FNCNAME
*DEL,_FNCMTID
*DEL,_FNC_C1
*DEL,_FNC_C2
*DEL,_FNC_C3
*DEL,_FNC_C4
*DEL,_FNCCSYS
*DEL,'back'
*SET,_FNCNAME,'back'
*DIM,_FNC_C1,,1
*DIM,_FNC_C2,,1
*DIM,_FNC_C3,,1
*DIM,_FNC_C4,,1
*SET,_FNC_C1(1),qmax12
*SET,_FNC_C2(1),chb
*SET,_FNC_C3(1),bh
*SET,_FNC_C4(1),ah
*SET,_FNCCSYS,0
! /INPUT,back.func,,,1
*DIM,%_FNCNAME%,TABLE,6,20,1,,,,%_FNCCSYS%
!
! Begin of equation: Qmax12*exp(-3(({x}/chb)^2+({y}/bh)^2+({z}/ah)^2))
*SET,%_FNCNAME%(0,0,1), 0.0, -999
*SET,%_FNCNAME%(2,0,1), 0.0
*SET,%_FNCNAME%(3,0,1), %_FNC_C1(1)%
*SET,%_FNCNAME%(4,0,1), %_FNC_C2(1)%
*SET,%_FNCNAME%(5,0,1), %_FNC_C3(1)%
*SET,%_FNCNAME%(6,0,1), %_FNC_C4(1)%
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 0, 0, 0, 0
*SET,%_FNCNAME%(0,2,1), 0.0, -2, 0, 1, 0, 0, -1
*SET,%_FNCNAME%(0,3,1), 0, -3, 0, 1, -1, 2, -2
*SET,%_FNCNAME%(0,4,1), 0.0, -1, 0, 1, 2, 4, 18
*SET,%_FNCNAME%(0,5,1), 0.0, -2, 0, 2, 0, 0, -1
*SET,%_FNCNAME%(0,6,1), 0.0, -4, 0, 1, -1, 17, -2
*SET,%_FNCNAME%(0,7,1), 0.0, -1, 0, 1, 3, 4, 19
*SET,%_FNCNAME%(0,8,1), 0.0, -2, 0, 2, 0, 0, -1
*SET,%_FNCNAME%(0,9,1), 0.0, -5, 0, 1, -1, 17, -2
*SET,%_FNCNAME%(0,10,1), 0.0, -1, 0, 1, -4, 1, -5
*SET,%_FNCNAME%(0,11,1), 0.0, -2, 0, 1, 4, 4, 20
*SET,%_FNCNAME%(0,12,1), 0.0, -4, 0, 2, 0, 0, -2
*SET,%_FNCNAME%(0,13,1), 0.0, -5, 0, 1, -2, 17, -4
*SET,%_FNCNAME%(0,14,1), 0.0, -2, 0, 1, -1, 1, -5
*SET,%_FNCNAME%(0,15,1), 0.0, -1, 0, 3, 0, 0, -2
*SET,%_FNCNAME%(0,16,1), 0.0, -4, 0, 1, -1, 3, -2
*SET,%_FNCNAME%(0,17,1), 0.0, -1, 0, 1, -3, 3, -4
*SET,%_FNCNAME%(0,18,1), 0.0, -1, 7, 1, -1, 0, 0
*SET,%_FNCNAME%(0,19,1), 0.0, -2, 0, 1, 17, 3, -1
*SET,%_FNCNAME%(0,20,1), 0.0, 99, 0, 1, -2, 0, 0
! End of equation: Qmax12*exp(-3(({x}/chb)^2+({y}/bh)^2+({z}/ah)^2))
!-->
BF,BEHIND,HGEN,%back%
CMDELE,BEHIND
ALLSEL,ALL
time,i*tinc
nsubst,10
SOLVE
BFDELE,all,HGEN
esel,s,live
eplot
OUTRES,ALL,ALL,
*ENDDO
!!!添加冷却载荷第二步
CSYS,0
TIME,lx/V+5
NSUBST,15, , ,1
!!!DELTIM,0.05,0.01,0.1,1
SOLVE
!!!添加冷却载荷第二步
TIME,lx/V+20
NSUBST,15, , ,1
!!!DELTIM,0.2,0.1,0.4,1
SOLVE
现象就出在标红的命令流那,按照各种版本的意思,在建立球坐标系时,对应的XYZ变成r,φ,θ,其中r为原点O与点P间的距离,θ为有向线段与z轴正向所夹的角,φ为从正z轴来看自x轴按逆时针方向转到有向线段的角。问题是θ就应该是上述命令流中的度数,但结果却不对称。改为-90~90后,结果就对称了,这是为什么???
|