- 积分
- 237
- 注册时间
- 2003-6-27
- 仿真币
-
- 最后登录
- 1970-1-1
|
发表于 2003-12-1 06:33:15
|
显示全部楼层
来自 上海徐汇区
回复: 请问:ANSYS中可以列出变形后的节点坐标(x,y,z)吗?
至少有两种方法给出变形后的节点坐标:
1 用 upcoord 命令直接用位移结果修改节点坐标,命令格式如下:
upcoord, factor, key
其中: factor - 用位移结果修改节点坐标时的比例银子,一般为1;
key - 用位移结果修改节点坐标后是否将数据库中的位移清为零。
使用 upcoord 命令后,再用 list 命令显示出的节点坐标就是变形后的坐标了。
2 如果不想修改节点坐标,以下的 APDL 程序可以将当前选定的节点组的变形后坐标写到一个文件(暂定 result.txt,可以自己修改)中,其中参数 arg1 为所要读取的结果组号,默认为 last:
!*
/post1
*get,sys0,active,0,csys ! current coordinate system
csys,0
*cfopen,result,txt ! prepar to write result file named result.txt
*get,nn,node,,count ! nn - the count of selected nodes
fn=nint(arg1)
*if,fn,gt,0.001,then ! read the arg1'th set of result or last set of result
set,arg1
*else
set,last
*endif
!*
in=ndnext(0) ! teh first node number in selected nodes
*do,i,1,nn
*if,nsel(in),eq,1,then
xi=nx(in)+ux(in)
yi=ny(in)+uy(in)
zi=nz(in)+uz(in)
*vwrite,in,xi,yi,zi ! write the coordinates of node - in
(f6.0,' ',3f16.8)
! *vwrite,nx(in),ny(in),nz(in) ! for verify
! (' ',3f16.8)
! *vwrite,ux(in),uy(in),uz(in) ! for verify
! (' ',3f16.8)
*endif
in=ndnext(in)
*enddo
!*
*cfclos
xi= ! release xi ......
yi=
zi=
nn=
in=
fn=
sys0=
i=
csys,sys0 |
|