- 积分
- 0
- 注册时间
- 2003-5-2
- 仿真币
-
- 最后登录
- 1970-1-1
|
楼主 |
发表于 2004-4-29 21:47:34
|
显示全部楼层
来自 上海交通大学
回复: 【讨论】一个多相问题
它的 命令流:
!!!!模型尺寸参数
LX = 10
NDX = 10
LY1 = 2
LY2 = 0.1
LY3 = 1.0
NDY1 = 10
NDY2 = 3
NDY3 = 10
YOFFSET = 0
/prep7
et,1,141 ! 2-D XY system
keyopt,1,1,2 ! 设置两个物相
esha,2 !Quad elements
!!!!
rect,,LX,YOFFSET,YOFFSET+LY1
rect,,LX,YOFFSET+LY1,YOFFSET+LY1+LY2
rect,,LX,YOFFSET+LY1+LY2,YOFFSET+LY1+LY2+LY3
nummrg,all
numcmp,all
!网格设置
lsel,s,,,3,9,3
lsel,a,,,1
lesi,all,,,NDX,
lsel,s,,,2,4,2
lesi,all,,,NDY1,-5.0
lsel,s,,,5,7,2
lesi,all,,,NDY2,-5.0
lsel,s,,,8,10,2
lesi,all,,,NDY3,-5.0
allsel
!材料属性分配
mat,1 !for fluids material must be 1
amesh,1 !mesh fluid 1 region
amesh,3 !mesh fluid 2 region
mat,2 !for solid set material to 2
amesh,2 !mesh solid region
! 对下边区域流体入口边界条件设置
lsel,s,,,4
nsll,s,1 !选择全部节点和 选择内部的 节点的 区别是什么
d,all,pres,10 !inlet pressure & temp specified for fluid 1
d,all,temp,100
!对下边区域流体出口边界条件设置
lsel,s,,,2
nsll,s,1
d,all,pres,0. !outlet pressure specified for fluid 1
!对下边区域流体底边边界条件设置
lsel,s,,,1
nsll,s,1
d,all,vy,0 !symmetry surface for fluid 1 only
!对上边区域入口边界条件设置
lsel,s,,,8
nsll,s,1
d,all,pres,10. !inlet pressure & temp specified for fluid 2
d,all,temp,400
!对上边区域出口边界条件设置
lsel,s,,,10
nsll,s,1
d,all,pres,0. !outlet pressure specified for fluid 2
!对上边流体区域上边边界设置
lsel,s,,,9
nsll,s,1
d,all,vx,0 !wall boundary conditions
d,all,vy,0
allsel
!对中间隔离体属性设置,设置了密度传导系数和比热
mp,dens,2,5.
mp,kxx,2,100
mp,c,2,13
/SOLU
!对各个物相的初始条件进行了设置
nsel,s,loc,x,,lx !select nodes for fluid 1
nsel,s,loc,y,o,ly1
ic,all,sp01,1.0 !set mass fraction for fluid 1
ic,all,sp02,0.0
nsel,s,loc,x,,lx
nsel,s,loc,y,ly1+ly2,ly1+ly2+ly3 !select nodes for fluid 2
ic,all,sp01,0.0 !set mass fraction for fluid 2
ic,all,sp02,1.0
allsel
!定义流体类型
FLDA,ITER,EXEC,200 !设置总体迭代步数
FLDA,PROT,DENS,CMIX ! Fluid density
FLDA,PROT,VISC,CMIX ! Fluid viscosity
FLDA,PROT,COND,CMIX ! Fluid conductivity
FLDA,PROT,SPHT,CMIX ! Fluid specific heat
!设置所有的 流体属性为可变
flda,vary,dens,t !all properties MUST be variable
flda,vary,visc,t
flda,vary,cond,t
flda,vary,spht,t
!定义流体性质方程的 名义项参数
FLDA,NOMI,DENS,1.0 ! initial density for all fluid region
FLDA,NOMI,VISC,2.0 ! initial viscosity for all fluid region
FLDA,NOMI,COND,3.0 ! initial conductivity for all fluid region
FLDA,NOMI,SPHT,4.0 ! initial specific heat for all fluid region
!
!设置各个物相的属性
msprop,1,spht,constant,1 !sp heat for fluid 1
msprop,2,spht,constant,2 !sp heat for fluid 2
msprop,1,dens,constant,1 !density for fluid 1
msprop,2,dens,constant,2 !density for fluid 2
msprop,1,visc,constant,1.0 !viscosity for fluid 1
msprop,2,visc,constant,2.0 !viscosity for fluid 2
msprop,1,cond,constant,.1 !conductivity for fluid 1
msprop,2,cond,constant,.2 !conductivity for fluid 2
!收敛设置
FLDA,CONV,PRES,1.0E-10 ! PCCR convergence criterion
FLDA,TERM,PRES,1.E-09
FLDA,OUTP,SP01,T
FLDA,OUTP,SP02,T
save
SOLVE !solve for flow only |
|