- 积分
- 42
- 注册时间
- 2002-12-4
- 仿真币
-
- 最后登录
- 1970-1-1
|
*====================================================
*
* 分析管片与围岩的接触、围岩的断层滑动引起的应力分布
*
*
*====================================================
DATABASE NEW SAVE=NO PROMPT=NO
FEPROGRAM ADINA
CONTROL FILEVERSION=V81
*====================================================
*
* 定义点坐标
*
*====================================================
COORDINATES POINT SYSTEM=0
@CLEAR
1 0.00000000000000 -3.00000000000000 0.00000000000000 0
2 0.00000000000000 3.00000000000000 0.00000000000000 0
3 0.00000000000000 0.00000000000000 3.00000000000000 0
4 0.00000000000000 0.00000000000000 -3.00000000000000 0
5 0.00000000000000 0.00000000000000 0.00000000000000 0
6 0.00000000000000 -2.75000000000000 0.00000000000000 0
7 0.00000000000000 2.75000000000000 0.00000000000000 0
8 0.00000000000000 0.00000000000000 -2.75000000000000 0
9 0.00000000000000 0.00000000000000 2.75000000000000 0
10 0.00000000000000 13.0000000000000 12.0000000000000 0
11 0.00000000000000 -13.0000000000000 12.0000000000000 0
12 0.00000000000000 -13.0000000000000 -15.0000000000000 0
13 0.00000000000000 13.0000000000000 -15.0000000000000 0
14 0.00000000000000 13.0000000000000 3.00000000000000 0
15 0.00000000000000 -13.0000000000000 0.00000000000000 0
16 0.00000000000000 1.00000000000000 -15.0000000000000 0
17 0.00000000000000 1.00000000000000 12.0000000000000 0
18 0.00000000000000 -2.75787200000000 1.18178400000000 0
19 0.00000000000000 2.41438600000000 1.77858300000000 0
20 0.00000000000000 1.00000000000000 2.83406700000000 0
21 0.00000000000000 1.00000000000000 -2.82753600000000 0
@
*====================================================
*
* 定义线
*
*====================================================
LINE ARC NAME=1 MODE=1 P1=1 P2=3 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
*
LINE ARC NAME=2 MODE=1 P1=3 P2=2 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
*
LINE ARC NAME=3 MODE=1 P1=2 P2=4 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
*
LINE ARC NAME=4 MODE=1 P1=4 P2=1 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
LINE ARC NAME=5 MODE=1 P1=7 P2=9 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
*
LINE ARC NAME=6 MODE=1 P1=9 P2=6 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
*
LINE ARC NAME=7 MODE=1 P1=6 P2=8 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
*
LINE ARC NAME=8 MODE=1 P1=8 P2=7 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
*
LINE ARC NAME=19 MODE=1 P1=18 P2=20 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
*
LINE ARC NAME=20 MODE=1 P1=20 P2=19 CENTER=5 PCOINCID=YES,
PTOLERAN=1.00000000000000E-05
*====================================================
*
* 定义上部围岩的Surface
*
*====================================================
SURFACE VERTEX NAME=1 P1=17 P2=15 P3=18 P4=20
*
SURFACE VERTEX NAME=2 P1=11 P2=15 P3=17 P4=11
*
SURFACE VERTEX NAME=3 P1=17 P2=20 P3=19 P4=14
*
SURFACE VERTEX NAME=4 P1=17 P2=14 P3=10 P4=17
*
*====================================================
*
* 在同样位置复制两条线,为下部围岩的断层边界线
*
*====================================================
TRANSFORMATI TRANSLATION NAME=1 MODE=SYSTEM SYSTEM=0,
DX=0.0 DY=0.0 DZ=0.0
*
LINE TRANSFORMED NAME=30 PARENT=22 TRANSFOR=1 PCOINCID=NO,
PTOLERAN=1.0E-05 COUPLED=YES NCOPY=1
@CLEAR
26
@
*====================================================
*
* 生成下部围岩轮廓线
*
*====================================================
LINE ARC NAME=32 MODE=1 P1=23 P2=21 CENTER=5 PCOINCID=YES,
PTOLERAN=1.0E-05
*
LINE ARC NAME=33 MODE=1 P1=21 P2=24 CENTER=5 PCOINCID=YES,
PTOLERAN=1.0E-05
*
LINE STRAIGHT NAME=34 P1=15 P2=16
*
LINE STRAIGHT NAME=34 P1=22 P2=16
*
LINE STRAIGHT NAME=35 P1=16 P2=21
*
LINE STRAIGHT NAME=36 P1=22 P2=12
*
LINE STRAIGHT NAME=37 P1=12 P2=16
*
LINE STRAIGHT NAME=38 P1=21 P2=13
*
LINE STRAIGHT NAME=39 P1=13 P2=25
*
LINE STRAIGHT NAME=40 P1=16 P2=13
*====================================================
*
* 生成下部围岩的Surface
*
*====================================================
SURFACE PATCH NAME=5 EDGE1=30 EDGE2=34 EDGE3=35 EDGE4=32
*
SURFACE PATCH NAME=6 EDGE1=34 EDGE2=36 EDGE3=37 EDGE4=0
*
SURFACE PATCH NAME=7 EDGE1=38 EDGE2=39 EDGE3=31 EDGE4=33
*
SURFACE PATCH NAME=8 EDGE1=38 EDGE2=35 EDGE3=40 EDGE4=0
*====================================================
*
* 为操作选择方便,定义了不同的Zone,可以分别显示Zone
*
*====================================================
ZONE NAME=TOPSOIL NODEATTA=YES GEOMATTA=YES
@CLEAR
'geometry surfaces 1 to 4'
@
*
ZONE NAME=LOWSOIL NODEATTA=YES GEOMATTA=YES
@CLEAR
'geometry surfaces 5 to 8'
@
*
ZONE NAME=LEFT NODEATTA=YES GEOMATTA=YES
@CLEAR
'WHOLE MODEL'
'subtract zone topsoil'
'subtract zone lowsoil'
@
*====================================================
*
* 生成支护的Surface
*
*====================================================
SURFACE VERTEX NAME=9 P1=1 P2=6 P3=9 P4=3
*
SURFACE VERTEX NAME=10 P1=1 P2=4 P3=8 P4=6
*
SURFACE VERTEX NAME=11 P1=3 P2=9 P3=7 P4=2
*
SURFACE VERTEX NAME=12 P1=7 P2=8 P3=4 P4=2
*====================================================
*
* 下部围岩中需要挖掉的Surface
*
*====================================================
*
SURFACE VERTEX NAME=15 P1=23 P2=21 P3=5 P4=23
*
SURFACE VERTEX NAME=16 P1=5 P2=21 P3=24 P4=5
*
SURFACE VERTEX NAME=17 P1=23 P2=5 P3=24 P4=23
*====================================================
*
* 为操作选择方便,定义了不同的Zone,可以分别显示Zone
*
*====================================================
ACTIVEZONE
@CLEAR
'TOPSOIL'
@
*====================================================
*
* 定义辅助线,生成辅助点,然后生成上部围岩需挖掉的面
*
*====================================================
LINE STRAIGHT NAME=52 P1=18 P2=19
*
SPLIT-LINE NAME=52 USPLIT=0.657691 LINE1=53 LINE2=54,
COUPLED=YES RESTRICT=YES
*
SURFACE VERTEX NAME=18 P1=18 P2=26 P3=20 P4=18
*
SURFACE VERTEX NAME=19 P1=20 P2=26 P3=19 P4=20
*
ZONE NAME=support NODEATTA=YES GEOMATTA=YES
@CLEAR
'geometry surfaces 9 to 12'
@
*====================================================
*
* 定义接触组1,为支护与上下围岩的接触关系,共2各接触对
* 由于围岩卸载70%,所以支护出现的时间为开挖时刻后推移
* 14.(总的单元死亡刚度过渡时间为20),所以接触面的Birth
* 时间与材料Birht时间相同。
*====================================================
CGROUP CONTACT2 NAME=1 SUBTYPE=STRAIN,
FRICTION=0.1,
TBIRTH=114.1 TDEATH=1000.0
*
CONTACTSURFA NAME=1
@CLEAR
1 1
2 1
@
*
CONTACTSURFA NAME=2
@CLEAR
4 1
3 1
1 1
2 1
@
*
CONTACTSURFA NAME=3 PRINT=DEFAULT SAVE=DEFAULT SOLID=NO BODY=0,
ORIENTAT=AUTOMATIC MARQUEEB=0 DESCRIPT='NONE'
@CLEAR
19 1
20 1
@
*
CONTACTSURFA NAME=4 PRINT=DEFAULT SAVE=DEFAULT SOLID=NO BODY=0,
ORIENTAT=AUTOMATIC MARQUEEB=0 DESCRIPT='NONE'
@CLEAR
32 1
33 1
@
*
CONTACTPAIR NAME=1 TARGET=1 CONTACTO=3
*
CONTACTPAIR NAME=2 TARGET=2 CONTACTO=4
*====================================================
*
* 定义接触组2,是上下围岩非开挖部分的接触面,共两个
* 接触对。非开挖部分的接触关系一直存在。
*====================================================
CGROUP CONTACT2 NAME=2 SUBTYPE=STRAIN FRICTION=0.1
*
CONTACTSURFA NAME=1
@CLEAR
30 1
@
*
CONTACTSURFA NAME=2
@CLEAR
31 1
@
*
CONTACTSURFA NAME=3
@CLEAR
22 1
@
*
CONTACTSURFA NAME=4
@CLEAR
26 1
@
*
CONTACTPAIR NAME=1 TARGET=1 CONTACTO=3
*
CONTACTPAIR NAME=2 TARGET=2 CONTACTO=4
*====================================================
*
* 定义接触组3,是上下围岩开挖部分的接触面,共1个
* 接触对。非开挖部分的接触关系到开挖时刻即100.1时刻
* death。
*====================================================
CGROUP CONTACT2 NAME=3 SUBTYPE=STRAIN FRICTION=0.1,
TBIRTH=0.0 TDEATH=120.1
*
CONTACTSURFA NAME=1
@CLEAR
48 1
@
*
CONTACTSURFA NAME=2
@CLEAR
53 1
54 1
@
*
CONTACTPAIR NAME=1 TARGET=1 CONTACTO=2
*====================================================
*
* 界面中检查接触面的法向,发现接触组1中的第三个接触
* 发现未指向材料内部,进行调整。调整前首先要设置接触
* 组1为当前可以修改的单元组。
*====================================================
SET CGROUP NAME=1
*
CONTACTSURFA NAME=3,
ORIENTAT=INPUT
@CLEAR
19 1
20 1
@
*====================================================
*
* 定义材料参数,支护为弹性,围岩为MC
*
*
*====================================================
MATERIAL ELASTIC NAME=1 E=2.0E+10 NU=0.167,
DENSITY=2500.
*
MATERIAL MOHR-COULOMB NAME=2 E=1.0E+08,
NU=0.2 PHI=30.0 PSI=0.0,
COH=1.0E+07 TCUT=1.0E+10,
DENSITY=2500.0 DILATION=NO
*====================================================
*
* 定义并施加约束
*
*
*====================================================
FIXITY NAME=YF
@CLEAR
'Y-TRANSLATION'
@
*
FIXITY NAME=ZF
@CLEAR
'Z-TRANSLATION'
@
*
FIXBOUNDARY LINES FIXITY=YF
@CLEAR
24 'YF'
36 'YF'
39 'YF'
28 'YF'
@
*
FIXBOUNDARY LINES FIXITY=ZF
@CLEAR
24 'YF'
28 'YF'
36 'YF'
39 'YF'
37 'ZF'
40 'ZF'
@
*====================================================
*
* 定义重力荷载并施加
*
*
*====================================================
LOAD MASS-PROPORTIONAL NAME=1 MAGNITUD=10.0,
AX=0.0 AY=0.0 AZ=-1.0,
INTERPRE=BODY-FORCE
*
APPLY-LOAD BODY=0
@CLEAR
1 'MASS-PROPORTIONAL' 1 'MODEL' 0 0 1 0.0 0 -1 0 0 0 ,
'NO' 0.0 0.0 1 0
@
*
APPLY-LOAD BODY=0
@CLEAR
1 'MASS-PROPORTIONAL' 1 'MODEL' 0 0 1 0.0 0 -1 0 0 0 ,
'NO' 0.0 0.0 1 0
@
*====================================================
*
* 划分网格前进行划分单元密度的设置
*
*
*====================================================
SUBDIVIDE LINE NAME=42 MODE=DIVISIONS NDIV=3 RATIO=1.0,
PROGRESS=GEOMETRIC CBIAS=NO
@CLEAR
41
43
44
@
*
SUBDIVIDE LINE NAME=1 MODE=DIVISIONS NDIV=12 RATIO=1.0,
PROGRESS=GEOMETRIC CBIAS=NO
@CLEAR
6
5
2
8
3
4
7
@
*
SUBDIVIDE LINE NAME=19 MODE=LENGTH SIZE=0.3
@CLEAR
20
32
33
@
*
SUBDIVIDE LINE NAME=19 MODE=LENGTH SIZE=0.3
@CLEAR
20
32
33
@
*
SUBDIVIDE LINE NAME=22 MODE=DIVISIONS NDIV=10 RATIO=8.0,
PROGRESS=GEOMETRIC CBIAS=NO
@CLEAR
23
26
30
35
38
31
@
*
SUBDIVIDE LINE NAME=22 MODE=DIVISIONS NDIV=10 RATIO=0.125,
PROGRESS=GEOMETRIC CBIAS=NO
@CLEAR
30
35
@
*
SUBDIVIDE LINE NAME=27 MODE=LENGTH SIZE=3.0
@CLEAR
29
28
21
25
24
36
37
34
40
39
@
*
SUBDIVIDE LINE NAME=53 MODE=LENGTH SIZE=0.5
@CLEAR
52
53
52
54
55
@
*
ZONE NAME=LOWSOIL NODEATTA=YES GEOMATTA=YES
@CLEAR
'geometry surfaces 5 to 8'
'geometry surfaces 15 to 17'
@
*
SUBDIVIDE LINE NAME=46 MODE=LENGTH SIZE=0.5
@CLEAR
45
47
48
@
*====================================================
*
* 定义面的单元生死,围岩在100.1时刻死掉,(刚度完全
* 消失向后延迟20);支护在114.1时刻生成。
*
*====================================================
SURF-ELEMDAT TWODSOLID
@CLEAR
19 0 0.00000000000000 'DEFAULT' 'DEFAULT' 0.00000000000000,
100.100000000000 'NO' 0.00000000000000
18 0 0.00000000000000 'DEFAULT' 'DEFAULT' 0.00000000000000,
100.100000000000 'NO' 0.00000000000000
17 0 0.00000000000000 'DEFAULT' 'DEFAULT' 0.00000000000000,
100.100000000000 'NO' 0.00000000000000
16 0 0.00000000000000 'DEFAULT' 'DEFAULT' 0.00000000000000,
100.100000000000 'NO' 0.00000000000000
15 0 0.00000000000000 'DEFAULT' 'DEFAULT' 0.00000000000000,
100.100000000000 'NO' 0.00000000000000
9 0 0.00000000000000 'DEFAULT' 'DEFAULT' 114.100000000000,
0.00000000000000 'NO' 0.00000000000000
10 0 0.00000000000000 'DEFAULT' 'DEFAULT' 114.100000000000,
0.00000000000000 'NO' 0.00000000000000
11 0 0.00000000000000 'DEFAULT' 'DEFAULT' 114.100000000000,
0.00000000000000 'NO' 0.00000000000000
12 0 0.00000000000000 'DEFAULT' 'DEFAULT' 114.100000000000,
0.00000000000000 'NO' 0.00000000000000
@
*====================================================
*
* 定义地应力场
* 并定义初始地应力场的主轴方向(否则加载在单元坐标系
* 上,通常不符合要求。)然后将定义的局部坐标系施加到
* 所有围岩的Surface上。
*
*====================================================
*
STRAIN-FIELD NAME=1 A=-300000.0 B=25000.,
C=0.3 D=0.0 E=0.0 F=0.0
*
*
AXES CONSTANT NAME=1 AX=1.0 AY=0.0,
AZ=0.0 BX=0.0 BY=1.0,
BZ=0.0
*
SET-AXES-STR SURFACES
@CLEAR
1 1 2 3
2 1 2 3
3 1 2 3
4 1 2 3
5 1 2 3
6 1 2 3
7 1 2 3
8 1 2 3
15 1 2 3
16 1 2 3
17 1 2 3
18 1 2 3
@
*
*====================================================
*
* 定义单元组,INITIALS=BOTH为有初始应力输入
* STRAIN-F=1为地应力场输入1
*
*====================================================
EGROUP TWODSOLID NAME=1 SUBTYPE=STRAIN MATERIAL=1
*
EGROUP TWODSOLID NAME=2 SUBTYPE=STRAIN MATERIAL=2,
INITIALS=BOTH STRAIN-F=1
*
EGROUP TWODSOLID NAME=3 SUBTYPE=STRAIN,
MATERIAL=2,
INITIALS=BOTH STRAIN-F=1
*
*====================================================
*
* 划分单元,支护为映射,围岩为自由四边形网格
*
*
*====================================================
GSURFACE NODES=4 group=1
@CLEAR
9
10
11
12
@
*
GSURFACE NODES=4 NCOINCID=group GROUP=2,
PREFSHAP=QUAD-DIRECT MESHING=FREE-FORM METHOD=DELAUNAY
@CLEAR
4
4
3
1
2
19
18
@
*
COPY ZONE NAME1=WHOLE_MODEL NAME2=MESHPLOT00001 POSITION=1
*
ZONE NAME=MESHPLOT00001 NODEATTA=YES GEOMATTA=YES
@CLEAR
'whole model'
'SUBTRACT CONTACT GRO 1 OF RE 1 OF SUB 0 OF PR ADINA'
'SUBTRACT CONTACT GRO 2 OF RE 1 OF SUB 0 OF PR ADINA'
'SUBTRACT CONTACT GRO 3 OF RE 1 OF SUB 0 OF PR ADINA'
@
*
GSURFACE NODES=4 NCOINCID=group GROUP=3,
PREFSHAP=QUAD-DIRECT MESHING=FREE-FORM METHOD=DELAUNAY
@CLEAR
7
7
8
5
5
6
16
15
17
@
*
COPY ZONE NAME1=WHOLE_MODEL NAME2=MESHPLOT00001 POSITION=1
*
ZONE NAME=MESHPLOT00001 NODEATTA=YES GEOMATTA=YES
@CLEAR
'whole model'
'SUBTRACT CONTACT GRO 1 OF RE 1 OF SUB 0 OF PR ADINA'
'SUBTRACT CONTACT GRO 2 OF RE 1 OF SUB 0 OF PR ADINA'
'SUBTRACT CONTACT GRO 3 OF RE 1 OF SUB 0 OF PR ADINA'
@
*
*====================================================
*
* 因支护生成瞬间为自由体,需增加辅助弹簧单元进行约束
*
*
*====================================================
PROPERTYSET NAME=1 K=0.01
*
EGROUP SPRING NAME=4 PROPERTY=1
*
*
SPRING POINTS
@CLEAR
1 2 2 0 2 1
2 3 3 0 3 1
3 1 2 0 2 1
4 4 3 0 3 1
@
*====================================================
*
* 自动施加步长分析,单元刚度过渡时间为20,
* 只有YZ自由度,设置输入初始应变作为导致变形的初始应力
*
*====================================================
MASTER ANALYSIS=STATIC AUTOMATI=ATS TRELEASE=20.,
IDOF=100111 INITIALS=DEF
*====================================================
*
* 打开大位移开关
*
*====================================================
Kinematics displacement=large
*
*====================================================
*
* 控制重力的时间函数,100时刻加满重力
*
*====================================================
TIMEFUNCTION NAME=1
@CLEAR
0.0 0.0
100.0 1.0
200.0 1.0
@
*====================================================
*
* 定义时间步长
*
*====================================================
TIMESTEP NAME=DEFAULT
@CLEAR
10 10.0
21 1.0
@
*====================================================
* 结束
*
* 在观察结果时,115时刻为围岩自承卸荷力70%时刻,支护
* 承受荷载5%;在121时刻为围岩自承卸荷力70%,支护30%,
* 此时系统变形完全稳定。
*
*====================================================
[[i] 本帖最后由 jinjinhao 于 2006-8-12 17:12 编辑 [/i]] |
本帖子中包含更多资源
您需要 登录 才可以下载或查看,没有账号?注册
×
评分
-
1
查看全部评分
-
|