求助，变压器场路耦合的问题

xiaodong_hust

我做的就是用场路耦合模拟一个单相变压器的变比分析，
在低压侧加30000伏50Hz的交流电压，高压侧接一个100欧的电阻
命令流如下

KEYW,MAGNOD,1   
!Part 1:intializing the parameter of geometry and properties,
  Rc=1.51/2           !铁心半径 ;
  Hc=3.49             !铁心高度;
  Rh1=2.044/2         !高压绕组内半径;
  Rh2=2.384/2         !高压绕组外半径;
  h1=2.05             !高压绕组高
  Wh=Rh2-Rh1          !高压绕组宽
  Rl1=1.574/2         !低压绕组内半径;
  Rl2=1.824/2         !低压绕组外半径;
  l1=2.08             !低压绕组高
  Lh=Rl2-Rl1          !低压绕组宽;
  Nh=508              !Turns of high winding;
  L=4.28              !变压器长;
  H=3.720             !变压器高;
  W=3                 !变压器宽;
  Nl=32               !Turns of  low winding;
  Hw=2.25             !内窗高
  Ww=0.595            !内窗宽
  R1=0.000003    !绕组电阻率
  R2=0.000003    !油箱电阻率
  R3=0.000003    !磁屏蔽电阻率
  
!Part 2:建立2维变压器模型
  /PREP7
  Rectng,0,Rc+Ww+Rc,-Hc/2,Hc/2
  Rectng,0,L/2+0.022,-H/2-0.022,H/2+0.022   ！磁屏蔽
  Rectng,Rc,Rc+Ww,-Hw/2,Hw/2        !右内窗，铁心
  Rectng,Rh1,Rh2,-h1/2,h1/2       ! 高压绕组
  Rectng,Rl1,Rl2,-l1/2,l1/2       !低压绕组
  AOVLAP,ALL
  NumCmp,All

!Part 3:定义材料、单元
  ET,1,PLANE53          !空气，铁心，油
  ET,2,PLANE53,3,       !高压铰线圈
  ET,3,PLANE53,3,       !低压铰线圈
  ET,4,PLANE53,0,       !油箱和磁屏蔽（算涡流）
  
  MP,MURX,1,1           !油;
  Mp,Murx,2,8000        !铁心
  UIMP,3,MURX,RSVX,,1,R1    !高压线圈
  UIMP,4,MURX,RSVX,,1,R1    !低压线圈
  MP,MURX,5,1

  
  r,1,Wh*h1,Nh,3.14*(Rh1+Rh2),1,1 !高压线圈单元的实常数
  r,2,Lh*l1,Nl,3.14*(Rl1+Rl2),1,1 !低压线圈单元的实常数
  
  
  ASEL,s,area,,1       !1号面高压线圈1
  AATT,3,1,2
  ASEL,s,area,,2       !2号面低压线圈2
  AATT,4,2,3
  Asel,S,area,,3       !
  AATT,5,,4
  Asel,S,area,,4       !
  AATT,2,,1
  Asel,S,area,,5      !
  AATT,1,,1

!Part 4:划分单元网格
!part4.1:划分线圈
  LSel,S,,,13
  LSel,A,,,15
  LSel,A,,,17
  LSel,A,,,19
  Lesize,All,,,30
  LSel,S,,,12
  LSel,A,,,14
  LSel,A,,,16
  LSel,A,,,18
  Lesize,All,,,5
  Asel,s,area,,1
  Asel,A,area,,2
  MShape,0,2D        
  Mshkey,1           
  Amesh,All
  Allsel,All
!part4.2:划分铁心,空气油,油箱，磁屏蔽
  Asel,s,area,,3
  Asel,A,area,,4
  Asel,A,area,,5
  ESIZE,,30,
  MShape,0,2D
  Mshkey,0
  Amesh,All
  Allsel,All
  
  
!part4.1:细分磁屏蔽和油箱
  Allsel,All
  Lsel,s,,,1
  Lsel,A,,,2
  Lsel,A,,,3
  !LREFINE,all,,,1,
! LREFINE,all,,,1,
  
!Part 5: 场路耦合;
!part5.1:高压侧1
  Allsel,All
  Et,50,Circu124
  R,50,0.000000001
  Et,5,Circu124,5   !高压铰线圈;
  R,5,1
  Et,6,Circu124
  R,6,100
  N,,-6,1                 
  N,,-6,2
  N,,-7,1
  N,,-7,2               
  *Get,Nmax,Node,0,Num,Max
  Type,6
  Real,6
  E,Nmax,Nmax-1     !Independent Current Source element;
  Type,5
  Real,5
  E,Nmax-2,Nmax-3,241  !Stranded Coil element(To FEM domain)
  Type,50
  Real,50
  E,Nmax,Nmax-2
  E,Nmax-1,Nmax-3
  NSEL,S,NODE,,Nmax-1
  D,ALL,VOLT,0            !电压零点约束
  
!part5.3:低压侧1
  Allsel,All
  Et,7,Circu124,5   !低压铰线圈;
  R,7,1
  Et,8,Circu124,4,1  
  R,8,,30000,50
  N,,6,1                 
  N,,6,2
  N,,7,1.5
  N,,7,1
  N,,7,2   
  *Get,Nmax,Node,0,Num,Max
  Type,8
  Real,8
  E,Nmax-1,Nmax,Nmax-2   
  Type,7
  Real,7
  E,Nmax-3,Nmax-4,888  !Stranded Coil element(To FEM domain)
  Type,50
  Real,50
  E,Nmax,Nmax-3
  E,Nmax-1,Nmax-4
  NSEL,S,NODE,,Nmax
  D,ALL,VOLT,0            !电压零点约束
  Allsel,All

!Part6:耦合自由度
ESel,S,Mat,,3    !线圈
NSLE,S
CP,1,CURR,ALL        
CP,2,EMF,ALL
Allsel,All
ESel,S,Mat,,4    !线圈
NSLE,S
CP,1,CURR,ALL        
CP,2,EMF,ALL
Allsel,All



!Part 7: 加边界条件
ESEL,ALL
NSEL,EXT                   ! Select exterior nodes
D,ALL,AZ,0                 ! Set potentials to zero (flux-parallel)
ALLSEL,ALL
FINISH

xiaodong_hust

不过求解的结果不正确，
高压跟低压线圈的电流却是一样的，根本看不出变比的效果
高压侧电阻的两端电压很小。
请大家帮我找一下错误，感激不尽

stonebox

把高压侧的电阻去掉试一试

xiaodong_hust

问题出在我耦合绞线圈自由度的时候
我吧四个两个线圈分开耦合就正确了

ouxiao2009

原帖由 xiaodong_hust 于 2007-5-14 17:00 发表
!Part6:耦合自由度
ESel,S,Mat,,3    !线圈
NSLE,S
CP,1,CURR,ALL        
CP,2,EMF,ALL
Allsel,All
ESel,S,Mat,,4    !线圈
NSLE,S
CP,1,CURR,ALL        
CP,2,EMF,ALL
Allsel,All

把后面的CP,1,CURR,ALL
             CP,2,CURR,ALL
换成      CP,3,CURR,ALL
             CP,4,CURR,ALL
应该就对了吧

sagna

楼主命令流怎么修改的   希望解答下   感谢

PAPULAR

给练习这个案例的人提个醒，这个命令流中的，
Rectng,0,L/2+0.022,-H/2-0.022,H/2+0.022   ！磁屏蔽           

这里的 ！是中文的，调试的时候改成英文的!

PAPULAR

Type,6
  Real,6
  E,Nmax,Nmax-1     !Independent Current Source element;

这个注释不对吧，高压端有电源？况且还是6号单元。