一个小的例子，供大家参考，并欢迎讨论，改进！
单元生死法，在温度场计算基础上，增加结构场生死法下的应力计算
RESUME,'hinge-seed','db','.'
/filname,standhinge
save,standhinge,db
/prep7
et,1,solid5
keyopt,1,1,0
mp,kxx,1,23.8 !定义左焊缝材料热物理性能，增加了热焓，用于相变分析
mp,c,1,500
mp,dens,1,7860
mp,ex,1,203e9
mp,alpx,1,10.6e-6
mp,prxy,1,0.29
MPTEMP,1,0,2643,2750,2875,3000
MPDATA,ENTH,1,1,0,128.1e6,163.8e6,174.2e6,184.6e6
mp,kxx,2,23.8 !定义铰链主体材料热物理性能
mp,c,2,500
mp,dens,2,7860
mp,ex,2,203e9
mp,alpx,2,10.6e-6
mp,prxy,2,0.29
mp,kxx,3,23.8 !定义右焊缝材料热物理性能，增加了热焓，用于相变分析
mp,c,3,500
mp,dens,3,7860
mp,ex,3,203e9
mp,alpx,3,10.6e-6
mp,prxy,3,0.29
MPTEMP,1,0,2643,2750,2875,3000
MPDATA,ENTH,3,1,0,128.1e6,163.8e6,174.2e6,184.6e6
numcmp,kp
numcmp,line
numcmp,area
numcmp,volu
cskp,11,0,5,7,2 !建立左焊缝几何模型
csys,11
wpcsys,,11
WPSTYLE,,,,,,,,1
cyl4,0,0,2e-3,90,,180,50e-3
csdele,11
wpcsys,,0
cskp,11,0,10,9,11 !建立右焊缝几何模型
csys,11
wpcsys,,11
WPSTYLE,,,,,,,,1
cyl4,0,0,2e-3,90,,180,50e-3
csdele,11
wpcsys,,0
vglue,all !粘接各体
numcmp,kp
numcmp,line
numcmp,area
numcmp,volu
!*****************************
lsel,s,,,42,43
lsel,a,,,46,47
LESIZE,all, , ,4, , , , ,1
lsel,s,,,7,8
LESIZE,all, , ,20, , , , ,1
mat,1
type,1
vsel,s,,,2 !选择左边焊缝，材料为1，网格划分
vsweep,all
allsel,all
mat,3
type,1
vsel,s,,,3 !选择右边焊缝，材料为3，网格划分
vsweep,all
allsel,all
esize,2.5e-3
vsel,u,,,2,3 !选择铰链主体，材料为2，网格划分
type,1
mat,2
vsweep,all
allsel,all
finish
/prep7
long=50e-3
lsize=50e-3/20
cskp,11,0,5,7,2 !建立左焊缝单元组
csys,11
wpcsys,,11
WPSTYLE,,,,,,,,1
*do,i,1,20
VSEL,S, , ,2
VPLOT
NSLV,R,1
NPLOT
nsel,r,loc,z,lsize*(i-1),lsize*i
NPLOT
esln,r,1
EPLOT
cm,strcat('comp_',chrval(i)),elem
allsel,all
*enddo
csdele,11
wpcsys,,0
cskp,11,0,10,9,11 !建立右焊缝单元组
csys,11
wpcsys,,11
WPSTYLE,,,,,,,,1
*do,i,1,20
VSEL,S, , ,3
VPLOT
NSLV,R,1
NPLOT
nsel,r,loc,z,lsize*(i-1),lsize*i
NPLOT
esln,r,1
EPLOT
cm,strcat('comp_',chrval(i+20)),elem
allsel,all
*enddo
csdele,11
wpcsys,,0
!*****************************
ESEL,S,MAT,,1,3,2
EKILL,ALL !杀死左边和右边两条焊缝单元，左焊缝初始稳态分析
esel,s,live
eplot
allsel,all
finish
!*****************************
/SOLU
nropt,full,,on
NLGEOM,ON
TOFFST,273 !定义温度偏移量
asel,s,,,2 !定义底板位移约束
asel,a,,,17,21,4
nsla,r
d,all,all
allsel,all
cskp,11,0,5,7,2 !建立左焊缝坐标系
csys,11
wpcsys,,11
WPSTYLE,,,,,,,,1
ASEL,S,EXT
!ASEL,u,,,17,21,4
!asel,u,,,2
ASEL,U,LOC,Y,0
SFA,ALL,,CONV,50,70 ! 施加对流换热载荷
ALLSEL,ALL
!*****************************
cmsel,s,strcat('comp_',chrval(1)),elem !左焊缝第1单元组复活，
ealive,all
esel,s,live
eplot
VSEL,S, , ,2
VPLOT
NSLV,R,1
NPLOT
nsel,r,loc,z,0,lsize
D,ALL,TEMP,3000 !施加左边焊缝第1单元组节点温度载荷
NSEL,INVE !选择其它节点
D,ALL,TEMP,70 !施加初始温度载荷
allsel,all
antype,trans,new !初始温度场瞬态分析
TIMINT,OFF !关闭时间积分，变成稳态分析
time,1e-2
nsubst,5,6,4,1
outres,all,3
KBC,0 !设置为斜坡载荷
ALLSEL,ALL
solve
save
!*****************************
!第10步：左焊缝单元组顺序复活温度场分析
dt=1
*do,i,1,20,1
*if,i,ne,1,then
cmsel,s,strcat('comp_',chrval(i)),elem !左焊缝第i单元组复活，
ealive,all
esel,s,live
eplot
VSEL,S, , ,2
VPLOT
NSLV,R,1
NPLOT
nsel,r,loc,z,lsize*(i-1),lsize*i
D,ALL,TEMP,3000 !施加左边焊缝第i单元组节点温度载荷
*endif
esel,all
antype,trans,rest
TIMINT,ON
time,i*dt
rescontrol,,none
nsubst,5,6,4,1
outres,all,3
KBC,0 !设置为斜坡载荷
ALLSEL,ALL
solve
save
*enddo
csdele,11
wpcsys,,0
!*****************************
!第二步：左边侧焊缝相变分析（20到100秒)
DDELE,ALL,TEMP !删除温度载荷
TIMINT,ON !打开时间积分
TINTP,,,,1 !定义瞬态积分参数
antype,trans,rest
TIMINT,ON
TIME,100 !定义求解时间
nsubst,5,6,4,1
outres,all,3
!DELTIME,1,.5,10 !定义时间子步
AUTOTS,ON !打开自动时间开关
KBC,0 !设置为斜坡载荷
!OUTRES,ALL,ALL !设置结果输出
SOLVE ! 求解
save
!*****************************
!第三步：左边侧焊缝凝固分析（100到1000秒)
antype,trans,rest
TIMINT,ON
TIME,1000 ! 定义求解时间
!DELTIME,50,10,100 ! 定义时间子步
nsubst,5,6,4,1
outres,all,3
AUTOTS,ON ! 打开自动时间开关
SOLVE ! 求解
save
!*****************************
cskp,11,0,10,9,11 ! 建立右焊缝坐标系统
csys,11
wpcsys,,11
WPSTYLE,,,,,,,,1
*do,i,1,20,1 !右焊缝单元组顺序复活温度场分析
cmsel,s,strcat('comp_',chrval(i+20)),elem !右边焊缝第(i＋20)单元组复活，
ealive,all
esel,s,live
eplot
VSEL,S, , ,3
VPLOT
NSLV,R,1
NPLOT
nsel,r,loc,z,lsize*(i-1),lsize*i
D,ALL,TEMP,3000 !施加右边焊缝第i单元组节点温度载荷
esel,all
antype,trans,rest
TIMINT,ON
time,1000+i*dt
rescontrol,,none
nsubst,5,6,4,1
outres,all,3
KBC,0 !设置为斜坡载荷
ALLSEL,ALL
solve
save
*enddo
!*****************************
!第二步：右边侧焊缝相变分析（1020到1100秒)
DDELE,ALL,TEMP !删除温度载荷
TIMINT,ON !打开时间积分
TINTP,,,,1 !定义瞬态积分参数
antype,trans,rest
TIMINT,ON
TIME,1100 !定义求解时间
!DELTIME,1,.5,10 !定义时间子步
nsubst,5,6,4,1
outres,all,3
KBC,0 !设置为斜坡载荷
ALLSEL,ALL
SOLVE !求解
save
!第三步：右边侧焊缝凝固分析（1100到2000秒)
antype,trans,rest
TIMINT,ON
TIME,2000 ! 定义求解时间
nsubst,5,6,4,1
outres,all,3
KBC,0 !设置为斜坡载荷
ALLSEL,ALL
SOLVE ! 求解
save
!*****************************
!第七步：后处理
/POST1 ! 进入通用后处理器
SET,,, ,,, ,4 ! 读取1秒中分析结果
PLNSOL, TEMP,, 0 ! 显示1秒钟后焊接件的温度分布
SET,,, ,,, ,42 ! 读取20秒中分析结果
PLNSOL, TEMP,, 0 ! 显示20秒钟后焊接件的温度分布
SET,,, ,,, ,44 ! 读取100秒中分析结果
PLNSOL, TEMP,, 0 ! 显示100秒钟后焊接件的温度分布
SET,,, ,,, ,46 ! 读取1000秒中分析结果
PLNSOL, TEMP,, 0 ! 显示1000秒钟后焊接件的温度分布
SET,,, ,,, ,86 ! 读取1020秒中分析结果
PLNSOL, TEMP,, 0 ! 显示1020秒钟后焊接件的温度分布
SET,,, ,,, ,88 ! 读取1100秒中分析结果
PLNSOL, TEMP,, 0 ! 显示1100秒钟后焊接件的温度分布
SET,,, ,,, ,90 ! 读取2000秒中分析结果
PLNSOL, TEMP,, 0 ! 显示2000秒钟后焊接件的温度分布
/POST26 ! 进入时间历程后处理器
NSOL,2,271,TEMP,, TEMP_2
STORE,MERGE
NSOL,3,344,TEMP,,TEMP_3
STORE,MERGE
NSOL,4,334,TEMP,,TEMP_4
STORE,MERGE
NSOL,5,1003,TEMP,,TEMP_5
STORE,MERGE
NSOL,6,1112,TEMP,,TEMP_6
STORE,MERGE
NSOL,7,4572,TEMP,,TEMP_7
STORE,MERGE
!NSOL,8,3027,TEMP,,TEMP_8
!STORE,MERGE
!NSOL,9,3112,TEMP,, TEMP_9
!STORE,MERGE !定义焊接件某些位置8个节点的时间温度变量
/AXLAB,X,TIME
/AXLAB,Y,TEMPERATURE !更改坐标轴标识
/XRANGE,0,2000 !设定横坐标轴范围
PLVAR,2,3,4,5,6,7, !绘制8节点温度随时间的变化曲线
!/EXIT,NOSAV !退出ANSYS
finish |
IP卡
狗仔卡
发表于 2008-5-28 15:31:39
提升卡
沉默卡
喧嚣卡
变色卡
抢沙发
千斤顶
显身卡
