- 积分
- 0
- 注册时间
- 2009-9-18
- 仿真币
-
- 最后登录
- 1970-1-1
|
这个例子是2007年"6个不错的例子---------程序完整详细"这个帖子中第3个例子的实现,其中建模部分是参考“求助压电悬臂梁的静态仿真问题,不知为什么没有结果”这个帖子中斑竹老师的代码,但是最后谐响应分析的结果与文档中给出的结构不一样,还请斑竹老师及各位大侠看看,谢谢!
/FILENAME,PZT-beam
! 定义分析文件名
/TITLE,Modal and static analysis of a Si beam actuated by a PZT thin film
tstep = 10.0E-6 ! Technology step
lbeam = 200E-6 ! Length of beam
wbeam = 50E-6 ! Width of beam
tbeam = 10.0E-6 ! Thickness of beam
l_PZt = lbeam-2*tstep ! Length of PZt on beam
w_PZt = wbeam-2*tstep ! Width of PZt layer
t_PZt = 2.0E-6 ! Thickness of piezoelectric actuator ceramic
l_PtB = lbeam-tstep ! Length of bottom Pt layer on beam
l_PtT = lbeam-3*tstep ! Length of top Pt layer on beam
w_PtB = wbeam-tstep ! Width of bottom Pt layer
w_PtT = wbeam-3*tstep ! Width of top Pt layer
t_Pt1 = 0.07E-6 ! Thickness of lower platinum electrode
t_Pt2 = 0.1E-6 ! Thickness of upper platinum electrode
/PREP7 ! Enter preprocessor
/COM,-------------------- Define element tables
ET,1,5,0 ! 8-node coupled field solid with all DOFs, for PZt
ET,2,45 ! 8-node solid with displacements (UX,UY,UZ) used for Si
ET,3,41 ! Membrane Shell (Pt layers)
/COM,-------------------- PZT piezo ceramic layer material properties (material 1)
MP,DENS,1,7400
MP,PERX,1,4.8E-9 ! Permittivity of piezoceramic
MP,PERY,1,4.8E-9 ! Physical Acoustic Principles and Methods
MP,PERZ,1,4.8E-9 ! Warren P. Mason Volume 1 Academic Press 1964
TB,PIEZ,1
! Piezoelectric "e" matrix of piezoceramic
TBDATA,3,-1.86
TBDATA,6,-1.86 ! Physical Acoustic Principles and Methods
TBDATA,9,9.0 ! Warren P. Mason Volume 1 Academic Press 1964
TBDATA,11,9.8
TBDATA,13,9.8
TB,ANEL,1 ! Stiffness "c" matrix of piezoceramic
TBDATA,1,13.5E10,6.74E10,6.81E10
TBDATA,7,13.5E10,6.81E10 ! Physical Acoustic Principles and Methods
TBDATA,12,11.3E10 ! Warren P. Mason Volume 1 Academic Press 1964
TBDATA,16,2.22E10
TBDATA,19,2.22E10
TBDATA,21,3.355E10
MP,MURX,1,0 ! Bogey material properties to suppress error messages
MP,KXX,1,0 ! Bogey material properties to suppress error messages
/COM,-------------------- Si isotropic material properties (material 2)
MP,EX,2,120e9 ! Young's module of Si for isotropic 120e9 originally
MP,NUXY,2,0.42 ! Poisson's ration of Si
MP,DENS,2,2329 ! Density of Si
/COM,-------------------- Platinum electrode material properties (material 3)
MP,EX,3,95e9 ! Young's modulus of Pt
MP,NUXY,3,0.33 ! Poisson's ration of of Pt
MP,DENS,3,21450 ! Handbook of chemistry and physics
R,1,t_Pt1 ! Real constant 1; thickness of lower Pt electrode
R,2,t_Pt2 ! Real constant 2; thickness of upper Pt electrode
FINISH ! Quit processor
/COM, ! Model the beam
/PREP7
BLC4,0,0, LBEAM, WBEAM, TBEAM
BLC4,0,0, L_PTB, WBEAM, TBEAM
BLC4,0,0, LBEAM, W_PTB, TBEAM
BLC4,0,0, L_PZT, WBEAM, TBEAM
BLC4,0,0, LBEAM, W_PZT, TBEAM
BLC4,0,0, L_PTT, WBEAM, TBEAM
BLC4,0,0, LBEAM, W_PTT, TBEAM
BLC4,0,0, L_PZT,W_PZT, TBEAM+ T_PZT
BLC4,0,0, L_PTT,W_PZT, TBEAM+ T_PZT
BLC4,0,0, L_PZT, W_PTT, TBEAM+ T_PZT
BTOL,1e-006
VOVLAP ,ALL
/VIEW,1,1,1,1 ! 变换视角
/AUTO,1 ! 自动适应窗口大小
/TRIAD,OFF
VPLOT ! 显示体
/COM, ! 对于三种材料网格剖分
/COM,-------------------- Mesh PZT volumes
VSEL,S,LOC,Z,tbeam,tbeam+t_pzt ! Select volumes by Z coordinate location (PZT)
TYPE,1 ! Use element table type 1 for meshing (PZT)
MAT,1 ! Use material 1 attributes for meshing (PZT)
VMESH,ALL ! Mesh all selected volumes
/COM ! Mesh si
VSEL,S,LOC,Z,0,tbeam ! Select Si volumes
TYPE,2
MAT,2
VMESH,ALL
/COM,-------------------- Mesh bottom Pt electrode and define component by nodes
TYPE,3 ! Use element table type 3 for meshing (Pt)
MAT,3 ! Use material 3 attributes for meshing (Pt)
ASEL,S,LOC,Z,tbeam ! Select lower electrode areas
ASEL,R,LOC,X,0, L_PTB
ASEL,R,LOC,Y,0,W_PTB
REAL,1 !Real constant set 1 (bottom Pt electrode thickness)
AMESH,ALL ! Mesh all selected areas
NSLA,S,1 ! Select nodes based on selected areas
!!!!!!!!!!!!这是自己加的
CM,bot_elec,NODE ! Top electrode node component
!!!!!!!!!!!!
CP,1,VOLT,ALL ! Couples volt DOF on top electrode
*GET,nel1,NODE,,NUM,MIN ! Get lowest node number of selected node set
/COM,-------------------- Mesh top Pt electrode and define component by nodes
ASEL,S,LOC,Z,tbeam+t_PZT ! Select upper electrode areas
ASEL,R,LOC,X,0, L_PTT
ASEL,R,LOC,Y,0,W_PTT
REAL,2 ! Real constant set 1 (top Pt electrode thickness)
AMESH,ALL ! Mesh all selected areas
NSLA,S,1 ! Select nodes based on selected areas
!!!!!!!!!!!!这是自己加的
CM,top_elec,NODE ! Top electrode node component
!!!!!!!!!!!!
CP,2,VOLT,ALL ! Couples volt DOF on bottom electrode
*GET,nel2,NODE,,NUM,MIN ! Get lowest node number of selected node set
ALLSEL ! Select everything
FINISH ! Exit active processor
/SOLU ! Enter solution processor
ANTYP,HARM ! Harmonic analysis type
HARFRQ,0.310E+06,0.314E+06 ! Frequency range for analysis
NSUBST,10 ! Number of steps to calculate
KBC,1 ! Step loads (no ramp)
D,bot_elec,VOLT,0.0 ! Assign zero potential to a node of top electrode
D,top_elec,VOLT,10.0 ! Assign cyclic potential of 10 V to top electrode
NSEL,S,LOC,X,0 ! Select nodes at beam attachment point
D,ALL,UX,,,,,UY,UZ ! Remove displacement DOFs from selected nodes
NSEL,S,LOC,Y,0 ! Select nodes at beam centre line
DSYM,SYMM,Y ! Define symmetry boundary conditions
NSEL,ALL ! Select all nodes
SOLVE ! Solve current load step
FINISH ! Exit active processor
/POST26 ! Enter time-history post-processor
NSEL,S,LOC,Y,0 ! Select nodes with coordinates Y=0
NSEL,R,LOC,Z,0 ! Reselect coordinates with Z=0
NSEL,R,LOC,X,lbeam ! Reselect coordinates with X=lbeam
*GET,ntip,NODE,,NUM,MIN ! Get number of node at beam tip (selected node)
NSOL,2,ntip,U,Z,tip_uz ! Store node ntip vert. displ. in variable tip_uz
NSEL,ALL ! Select all nodes
WPCSYS ! Align work-plane with global coordinate system
PRVAR,2 ! List data for tip_uz variable
!PLVAR,2 ! Plot displacements as a function of frequency
FINISH ! Exit active processor
上面代码运行的结果
文档中给出的结果
ps.是新手,从模仿开始啊!还请各位大大多指导![](static/image/smiley/default/cry.gif) |
本帖子中包含更多资源
您需要 登录 才可以下载或查看,没有账号?注册
×
|