【原创】焊接过程的温度分布一定要用到生死单元吗？

bqc

刚开始做焊接热分析，采用间接法。先用solid45计算温度场的分布，再TTS算热应力和变形。分析内容是，在一块板的中间沿纵向焊。热源我先简化为在焊接区域一致分布的热输入，准备算没问题之后再考虑高斯热源。
问题是，我计算的结果和文献上的相比相差很大。
我的热输入，是用了一个do循环，在每个时刻t写入此时的受热区域，然后做瞬态分析。没有用到生死单元。我不知道这样是不是不对？是不是必须要用生死单元呢？
希望达人给予帮助！
另外做相关课题的朋友们也可以在这里展开讨论。

附上我的命令流：                                                                                            
!                                 THERMAL ANALYSIS OF THE WELDING PROCESS            
/filname, heat_transfer               !Changes the Jobname for the analysis
/title, heat generation               
                                      !Defines a main title
/com,thermal                          !Places a comment in the output
!Unit:meter,kilogram,centidegree,Watt,Joule,second
   
!                                 PARAMETERS DEFINING                                             
Dens=7850     !defines the dense of steel, kg/m3
L=0.3         !defines the length of the model   
W=0.2         !defines the width of the model
H=0.006       !defines the depth of the model
Troom=20      !defines the room temperature
Speed=0.005   !defines the heating speed     
!                                 METERIAL PROPERTIES      
/prep7                                        !Enters the model creation preprocessor.
et,1,70                                       !uses solid 70 element
mp,dens,1,Dens                                !defines the dense of meterial
mptemp,,0,100,300,600,800,1450                !defines a temperature table with 6 different values
mpdata,kxx,1,,51.9,51.1,46.1,35.6,26,29.45    !thermal conductivity of steel, W/(m ºC)
mpdata,c,1,,450,499.2,565.5,773.3,931,437.93  !specific heat of steel, J/(kg ºC)
mpdata,hf,2,,1,6.5,7.5,7.2,7.1,7              !heat convection coefficient of air, W/(m2 ºC)   
!                                 MODELLING                                                      
blc4,,,W/2,L        !Creates a rectangular area, x(0-W), y(-2/L,2/L)
vext,1,,,,,-H         !Generates one volumes by extruding areas, z(-H,0)
agen,2,6,,,0.005      !copies an area from x=0(area6) to x=0.005(area7)
vsba,1,7              !devides volumn 1 by area7
vatt,1,,1             !associates meterial#1 and type#1 with volumes 1 and 2   
!                                 ELEMENTS MESHING                                                
mshape,0,3d                     !meshs with hexahedral-shaped elements with Dimension=3-D
mshkey,1                      !uses mapped meshing
lsel,,,,21,24                 !select lines 21,22,23,24
lsel,a,loc,z,-0.005,-0.001    !select also the lines between the deck and the bottom
lesize,all,0.001              !specifies the element size of the selected linesas 0.001m
                              !(inside the heating zone)   
allsel                        !selects everything
lsel,u,,,21,24                !unselects lines 21,22,23,24
lsel,u,loc,z,-0.005,-0.001    !select also the lines between the deck and the bottom
lesize,all,0.005              !specifies the size of the selected lines as 0.005m
                              !(outside the heating zone)
allsel                        !selects everything
vmesh,all                     !meshs all the volumns
nummrg,all                    !merges coincident or equivalently defined items, for all items
!                                 LOAD APLLYING                                                      
/sol                    !enters the solution processor
antype,4                !performs a transient analysis
asel,,,,4               !selects areas 4
asel,a,,,8,11           !selects also areas 8,9,10,11
nsla,,1                 !selects the nodes associated with the selected areas
                        !for all nodes(interior to area, interior to lines, and at keypoints)
sf,all,conv,-2,Troom    !defines the thermal convection load on all selected nodes
!the film coefficient is determined from the HF property table for material 2 (mpdata,hf,2......)
                        !the bulk temperature is equal to Troom
/psf,conv,hcoef,2   !shows the heat convection load symbols on model displays as arrows
/replot             !replots   
!                                 SOLUTION CONTROLS                                               
allsel              !selects everything
Tunif,Troom         !assigns a uniform temperature Troom to all nodes before the analysis
deltim,1,0.02,2     !specifies the time step, the min and max time step as 1, 0.02 and 2 seconds
kbc,1            !specifies stepped loading   
autots,on           !uses automatic time stepping
timint,on           !turns on transient effects
tintp,,,,1          !defines transient integration parameters, as default
outres,all,all        !all solution items except SVAR and LOCI are written in the result file
                    !writes the solution of the specified solution results item for every substep   
!                                 THE WELDING PROCESS                                             
do,i,1,60          !starts a do loop
time,i              !sets the time for a load step as i second
sfdele,all,hflux    !deletes the heat generation loads on all nodes              
nsel,,loc,x,0,0.005                      !selects the heating zone
nsel,r,loc,y,(i-1) Speed,i Speed         !the y value of the heating zone is changing by time
nsel,r,loc,z,0                      !the heating affected depth
sf,all,hflux,6000000                     !inputs the heat flux
allsel              !select everything
lswrite,i           !writes load and load step option data to a file
enddo              !ends the do loop   
!                                 COLDING (WITHOUT HEAT INPUT)                                    
do,j,61,240        !starts another do loop
time,60+(j-60) 20   !sets the time for a load step, 80,100,120,140......
sfdele,all,hflux    !deletes the heat generation loads on all nodes                 
lswrite,j           !writes load and load step option data to a file
enddo              !ends the do loop   
!                                 SOLVING THE MODEL                                               
lssolve,1,61,1      !Reads and solves load steps 1 to 62 (time 1 to 100 seconds)
/psf,hflu, ,2       !shows the heat flux load symbols on model displays as arrows
/replot             !replots   
!                                 RESULTS DISPLAY (TIME DEPENDENT CURVES)                        
/post26                                  !enters the time-history results postprocessor
nsol,2,node(0,0,0),temp,,x0y0z0       !specifies nodal data to be stored from the results file
nsol,3,node(0,0.05,0),temp,,x0y0.05z0   
nsol,4,node(0,0.1,0),temp,,x0y0.1z0
nsol,5,node(0,0.15,0),temp,,x0y0.15z0
nsol,6,node(0,0.2,0),temp,,x0y0.2z0   
nsol,7,node(0,0.25,0),temp,,x0y0.25z0
nsol,8,node(0,0.3,0),temp,,x0y0.3z0  
plvar,2,3,4,5,6,7,8                   !displays the defining variables in the form of a graph

save   
!                                 RESULTS DISPLAY (EACH TIME STEP)                                
/post1          !enters the database results postprocessor
set,first       !defines the data set of the first time step from the results file
plnsol,temp     !plots the temperature results of the specific time step as continuous contours
set,30          !defines the data set of the 30th time step from the results file
plnsol,temp     !plots the temperature results of the specific time step as continuous contours
set,60          !defines the data set of the 60th time step from the results file
plnsol,temp     !plots the temperature results of the specific time step as continuous contours
set,last        !defines the data set of the last time step from the results file
plnsol,temp     !plots the temperature results of the specific time step as continuous contours
finish          !exits normally from a processor   
!                                 STRUCTURAL ANALYSIS                                             
/com,structural
/prep7
etchg,tts

mpdata,ex,1,,2e11,2e11,2e11,8.8e10,2e10,2e9
mpdata,nuxy,1,,0.2786,0.3095,0.331,0.3738,0.4238,0.4738
mpdata,alpx,1,,10e-6,11e-6,12e-6,14e-6,14e-6,15e-6

nsel,,loc,x,0.08
nsel,r,loc,z,0
d,all,uz,0
allsel

da,6,symm
allsel

/solu
tref,20
ldread,temp,,,,,'heat_transfer','rth'
solve

/post26                                 
nsol,2,node(0,0,0),u,z,x0y0z0      
nsol,3,node(0,0.05,0),u,z,x0y0.05z0   
nsol,4,node(0,0.1,0),u,z,x0y0.1z0
nsol,5,node(0,0.15,0),u,z,x0y0.15z0
nsol,6,node(0,0.2,0),u,z,x0y0.2z0   
nsol,7,node(0,0.25,0),u,z,x0y0.25z0
nsol,8,node(0,0.3,0),u,z,x0y0.3z0  
plvar,2,3,4,5,6,7,8      
!                                 ANALYSIS COMPLETED   
/finish

wuyp802

如果焊前开坡口或焊后出现余高 ，那么要用生死单元
其他情况没必要