finish
/prep7 !进入前处理
/title,sijidianji !标注标题
/pnum,area,1 !显示面积编号
*set,pi,3.14
*set,m,3 !定子相数
*set,miu_0,4*pi*1e-7 !空气绝对磁导率
*set,miu_k,1 !空气相对磁导率
*set,miu_fe,2000 !铁磁材料相对磁导率（2000-6000）
*set,n_coil,10 !!!!!!励磁绕组线圈匝数
*set,i_coil,10 !!!!!!每匝导体电流值
*set,F_coil,n_coil*i_coil !!!!!!计算每相磁动势
!!!!!!!!!!!!!!!定义单元类型!!!!!!!!!!!!!!!!!!!!!
et,1,plane53 !二维静态
!et,2,infin9 !远场单元
mp,murx,1,1 !空气相对磁导率、载流线圈的相对磁导率、转轴材料给材料1
mp,murx,2,miu_fe !铁的相对磁导率给材料2
!mp,murx,3,1 !载流线圈的相对磁导率給材料3
!mp,murx,4,1 !转轴-材料4
!!!!!!!!!!!!!!!!!!!!画定子侧!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
*set,s_outer,12 !定子外径（半径，米）
*set,s_inner,8 !定子内径
*set,r1,s_outer
*set,r2,s_inner
*set,gap_l,1 !气隙长
*set,dalt_l,gap_l/3 !气隙分成三部分
*set,r3,r2-dalt_l
*set,r4,r3-dalt_l
!*set,r5,r4-dalt_l
!*set,r_outer,r5 !转子外径
*set,r_inner,1.2 !转子内径,转轴半径
*set,r6,r_inner
pcirc,0,r1,0,360 !画圆定子外径、内径和三部分气隙，内径，外径，起始角度，终止角度
pcirc,0,r2,0,360
pcirc,0,r3,0,360
pcirc,0,r4,0,360
pcirc,0,r6,0,360
aovlap,all !面重叠
numcmp,area !
allsel,all !
*get,kp_max,kp,,num,max,, ! 得到当前最大节点数
*get,line_max,line,,num,max,, ! 得到当前最大线数
*get,area_max,area,,num,max,, ! 得到当前最大面积数
!!!!!!!!!!!!!!!画定子槽!!!!!!!!!!!!!!!
*set,stator_slot_number,36 !定子槽数
*set,stator_slot_theta,360/stator_slot_number !定子槽间角
*set,stator_slot_wide,1 !定子槽口宽
*set,stator_slot_halfwide,stator_slot_wide/2 !槽口半宽
*set,stator_slot_high,1.8 !定子槽高
*set,high_1,sqrt(r2**2-stator_slot_halfwide**2) !定子槽下点坐标
csys,0 !直角坐标
k,kp_max+1,-stator_slot_halfwide,high_1,0 !k,关键点号,x,y,z
k,kp_max+2,-stator_slot_halfwide,high_1+stator_slot_high,0
k,kp_max+3,stator_slot_halfwide,high_1+stator_slot_high,0
k,kp_max+4,stator_slot_halfwide,high_1,0
lstr,kp_max+1,kp_max+2 !由点画线(定子槽)
lstr,kp_max+2,kp_max+3
lstr,kp_max+3,kp_max+4
larc,kp_max+1,kp_max+4,1,r2 !
lsel,s,,,line_max+1,line_max+4,1 !由线生面，面号自动加一
al,all !用所有的线建面
asel,s,,,area_max+1 !选面
csys,1 !极坐标
agen,stator_slot_number,all,,,,stator_slot_theta !旋转拷贝槽
allsel,all
aovlap,all
numcmp,area
numcmp,kp
allsel,all
*get,kp_max,kp,,num,max,,
*get,line_max,line,,num,max,,
*get,area_max,area,,num,max,,
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!画转子侧!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
csys,0
*set,rotor_p,4 !转子极数
*set,rotor_p_theta,360/rotor_p !转子极距
*set,rotor_yoke_high,2 !转子轭部高
!*set,r_yoke,r6+rotor_yoke_high
*set,pole_body_wide,3 !极身宽
*set,wide_1,pole_body_wide/2
*set,pole_body_high,3 !极身高
*set,p_t_wide,4.5 !极靴宽
*set,wide_2,p_t_wide/2
*set,p_t_high,1.5 !极靴高
*set,p_t_high_1,0.5 !极靴边高
*set,r7,r6+rotor_yoke_high
*set,r8,r7+pole_body_high
*set,r9,r8+p_t_high
pcirc,0,r7,0,360 !画转子轭
asel,all
aovlap,all
allsel,all
numcmp,area
numcmp,line
*get,kp_max,kp,,num,max,,
*get,line_max,line,,num,max,,
*get,area_max,area,,num,max,,
*set,w_1,sqrt(r7**2-wide_1**2) !计算转子极身关键点的坐标
k,kp_max+1,-wide_1,w_1,0 !画极靴
k,kp_max+2,-wide_1,r8
k,kp_max+3,-wide_2,r8,
k,kp_max+4,-wide_2,r8+p_t_high_1
k,kp_max+5,wide_2,r8+p_t_high_1
k,kp_max+6,wide_2,r8
k,kp_max+7,wide_1,r8
k,kp_max+8,wide_1,w_1
lstr,kp_max+1,kp_max+2
lstr,kp_max+2,kp_max+3
lstr,kp_max+3,kp_max+4
larc,kp_max+4,kp_max+5,1,r9
lstr,kp_max+5,kp_max+6
lstr,kp_max+6,kp_max+7
lstr,kp_max+7,kp_max+8
larc,kp_max+1,kp_max+8,1,r7
lsel,s,,,line_max+1,line_max+8,1
al,all
asel,s,,,area_max+1
csys,1
agen,rotor_p,all,,,,rotor_p_theta
allsel,all
aovlap,all
nummrg,kp !合并重复节点
numcmp,all !压缩实体编号
allsel,all
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!画励磁绕组截面!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
csys,0
*get,kp_max,kp,,num,max,,
*get,line_max,line,,num,max,,
*get,area_max,area,,num,max,,
*set,coil_wide_l,0.3*pole_body_wide !转子励磁绕组截面宽
*set,coil_high_l,0.8*pole_body_high !转子励磁绕组截面高
*set,s_l_coil,coil_wide_l*coil_high_l !计算励磁绕组截面积
k,kp_max+1,-coil_wide_l-wide_1,r7+0.1*pole_body_high
k,kp_max+2,-coil_wide_l-wide_1,r7+0.1*pole_body_high+coil_high_l
k,kp_max+3,-wide_1,r7+0.1*pole_body_high+coil_high_l
k,kp_max+4,-wide_1,r7+0.1*pole_body_high
!lstr,kp_max+1,kp_max+2
!lstr,kp_max+2,kp_max+3
!lstr,kp_max+3,kp_max+4
!lstr,kp_max+4,kp_max+1
a,kp_max+1,kp_max+2,kp_max+3,kp_max+4 !由点生面
allsel,all
asel,s,,,area_max+1
csys,1
agen,rotor_p,all,,,,rotor_p_theta
allsel,all
nummrg,kp !合并重复节点
numcmp,kp !压缩节点数
numcmp,line !压缩线数
allsel,all
csys,0 !画另一侧励磁绕组
*get,area_max,area,,num,max,,
*get,kp_max,kp,,num,max,,
*get,line_max,line,,num,max,,
k,kp_max+1,coil_wide_l+wide_1,r7+0.1*pole_body_high
k,kp_max+2,coil_wide_l+wide_1,r7+0.1*pole_body_high+coil_high_l
k,kp_max+3,wide_1,r7+0.1*pole_body_high+coil_high_l
k,kp_max+4,wide_1,r7+0.1*pole_body_high
a,kp_max+1,kp_max+2,kp_max+3,kp_max+4
asel,s,,,area_max+1
csys,1
agen,rotor_p,all,,,,rotor_p_theta
allsel,all
csys,0
asel,all
aovlap,all
nummrg,kp !合并重复节点
numcmp,all !压缩实体编号
allsel,all
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!给各区域附属性（怎样实现参数化？？）!!!!!!!!!!!!!!!!!!!!!!!!!
!定子侧赋属性
asel,s,,,3,38,1 !选3~38面
aatt,1,1,1 !给载流线圈付材料号1，单元号1
asel,s,,,40
aatt,2,1,1 !给定子铁芯区域付材料号2，单元1
asel,s,,,1 !转轴
aatt,1,1,1
asel,s,,,2
aatt,1,1,1 !气隙
asel,s,,,39
aatt,1,1,1 !气隙
!转子侧赋属性
allsel,all
asel,s,,,42,49,1 !励磁线圈
aatt,1,1,1
asel,s,,,50,53,1 !转子极身
aatt,2,1,1
asel,s,,,41 !转子厄
aatt,2,1,1
asel,s,,,54 !气隙
aatt,1,1,1
allsel,all
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!画网格!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
allsel,all
mshape,1,2D !使用二维三角形网格
smrtsize,1 !使用智能网格划分
amesh,all
finish
!!!!!!!!!!!!!!!!!!!!!!!!!!!!进入求解!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/solu
*set,js_r,F_coil/s_l_coil !!!!!励磁电流密度F_coil
csys,1
lsel,s,loc,x,r1 !!!!!!给定外边界条件loc
dl,all,,az,0,
!lsel,s,loc,x,r6
!dl,all,,az,0,
!给励磁绕组赋面电流密度
csys,0
*DO,j,0,3,1
BFA,42+j,js,0,0,(-1)**j*js_r
BFA,46+j,js,0,0,(-1)**(j+1)*js_r
*ENDDO
!!!!!!!!!!给电枢绕组赋面电流密度
*set,js_A,100*cos(0)
*set,js_B,100*cos(0-2*pi/3)
*set,js_C,100*cos(0+2*pi/3)
asel,s,,,35 !A相赋电流
*do,j,0,3,1
bfa,35+j,js,,,(-1)**j*js_A
*enddo
asel,s,,,3,4,1
*do,i,3,4,1
*do,j,0,3,1
bfa,i+j*8,js,,,(-1)**j*js_A
*enddo
*enddo
asel,s,,,5,7,1 !c相赋电流
*do,i,5,7,1
*do,j,0,3,1
bfa,i+j*8,js,,,(-1)**(j+1)*js_C
*enddo
*enddo
asel,s,,,8,10,1 !B相赋电流
*do,i,8,10,1
*do,j,0,3,1
bfa,i+j*8,js,,,(-1)**j*js_B
*enddo
*enddo
allsel,all
solve !求解
finish
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!进入后处理!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/post1
plf2d,28,0,10,1
!plvect,b,,,,vect,elem,on,0 !!!!!!!!!!!!!!!!!!!!!!!!!!!!
!plvect,h,,,,vect,elem,on,0
finish |
IP卡
狗仔卡
发表于 2011-4-13 11:44:30
提升卡
沉默卡
喧嚣卡
变色卡
抢沙发
千斤顶
显身卡
发表于 2011-4-19 12:41:55
