请问如何用ANSYS求出系统的整体刚度,及刚度矩阵?

Bill_Xu

请问如何用ANSYS求出系统的整体刚度,及刚度矩阵?
先谢谢了

lidongmei

[转帖]提取整体刚度矩阵、质量矩阵及阻尼矩阵的三种方法


1.

Which matrix you would like? element stiffness matrix or full stiffness matrix?

element stiffness is within file.emat. full stiffness matrix is within file.full

A simple way to dump the matrix is as follow:
-------------------
/aux2
fileaux2,file,emat
form,long
dump,all
-------------------


2.

可以使用/DEBUG命令来得到。详细步骤参见下面的宏文件

finish
/clear

PI=3.1415926

w1=3
w2=10
w3=6
w4=1.2
r=.8
t=0.08

/PREP7
!*
ET,1,SHELL63
R,1,t

ET,2,MASS21
R,2,500,500,500,2000,2000,2000,
!*
UIMP,1,EX, , ,2e11
UIMP,1,NUXY, , ,0.3,
UIMP,1,DAMP, , ,0.2,
UIMP,1,DENS, , ,7800,

BLC4,0,0,w2,w1
ESIZE,1.5,0,
AMESH,all

NSEL,S,LOC,X,0.0
D,all, , , , , ,ALL, , , , ,

allsel,all
SFA,all,1,PRES,12
FINISH

/OUTPUT,cp,out,, ! 将输出信息送到cp.out文件
/debug,-1,,,1 ! 指定输出单元矩阵

/SOLU
SOLVE
finish

/OUTPUT, TERM ! 将输出信息送到output windows中

! 这时用编辑器打开cp.out文件，可以看到按单元写出的质量、刚度等矩阵

3.

其原理很简单，即使用ansys的超单元即可解决问题。定义超单元，然后列出超单元的刚度矩阵即可。
面是一个小例题，自可明白。
/prep7
k,1
k,2,3000
l,1,2
et,1,beam3
mp,ex,1,2e5
mp,prxy,1,0.3
r,1,5000,2e7,200
lesize,all,,,10
lmesh,all
finish
!----以上正常建立模型，不必施加约束和荷载
/solu
antype,7 !substructuring分析类型
seopt,matname,1 !设置文件名称和刚度矩阵类型(刚度，质量，阻尼等)
nsel,all !选择所有节点
m,all,all !定义所有节点自由度为主自由度
solve !求解
selist,matname,3 !列出整体刚度矩阵

来自傲雪论坛