层单元shell91/99/181/281/solid46/190/185/186/191计算同一问题，结果不同？

phe666

谢谢各位！

问题描述：采用1种实体单元solid45和9种层单元，对同一问题进行计算，其中solid45、shell91、shell99、shell181、shell281、solid46计算结果相同，而
solsh190、solid185、solid186、solid191的计算结果大三倍左右，为什么呢？

几何模型：四层的层合玻璃平板，总厚度为4.58mm
材料模型：每层都为各向同性的线弹性材料，但具有不同的参考温度
计算：当温度从140度降到－30度时的热应力

1）用实体单元solid45进行计算，命令流和计算结果请参见 http://forum.simwe.com/thread-841999-1-1.html

2）用shell91、shell99、shell181、shell281、solid46层单元进行计算，计算命令流和计算结果如下

（注1：这些单元的计算结果与1）中solid45的计算结果相近，可以认为是准确的。）

(注2：为简洁，这里只列出了shell91的命令流，其它的命令流非常相近，如有感兴趣的同志请跟帖，我再贴上来)

!*******************
!   1-shell91
!   shell91-x80y41-difftref
!******************
/PREP7
/TITLE, shell91, x80y41, difftref
ET,1,SHELL91                ! 8 NODE LAYERED SHELL ELEMENT

keyopt,1,5,2
keyopt,1,6,1
keyopt,1,8,1

R,1,4                       ! 4 LAYERS PER ELEMENT
RMORE
RMORE,1,0,0.38,0.38,0.38,0.38     ! LAYER 1: 0.38 THK;
rmore,2,0,0.5,0.5,0.5,0.5        ! LAYER 2: 0.5 THK
rmore,3,0,0.5,0.5,0.5,0.5      ! LAYER 3: 0.5 THK;
rmore,4,0,3.2,3.2,3.2,3.2      !LAYER 4: 3.2 THK

MP,EX,1,3000               ! MATERIAL 1 PROPERTIES
MP,NUXY,1,0.4
mp,reft,1,99
MP,ALPX,1,26E-6

MP,EX,2,10.1               ! MATERIAL 2 PROPERTIES
MP,NUXY,2,0.42
mp,reft,2,55
MP,ALPX,2,140E-6

MP,EX,3,10.1               ! MATERIAL 3 PROPERTIES
MP,NUXY,3,0.42
mp,reft,3,55
MP,ALPX,3,140E-6

MP,EX,4,72000               ! MATERIAL 4 PROPERTIES
MP,NUXY,4,0.22
mp,reft,4,140
MP,ALPX,4,8.5E-6

RECTNG,0,80,0,41,       !生成平面并划分网格
LSEL,S,LOC,X,40
LESIZE,all, , ,80, , , , ,0
lsel,s,loc,y,20.5
lesize,all, , ,41, , , , , 0
allsel,all
amesh,all

nsel,s,loc,y,0        !施加约束
DSYM,SYMM,Y, ,  
nsel,s,loc,x,0
DSYM,SYMM,X, ,  
nsel,s,loc,x,0
nsel,r,loc,y,0
d,all,uz,0
ALLSEL,ALL  
!*  
BF,all,TEMP,-30         !施加载荷
ALLSEL,ALL  
/SOLU   
ANTYPE,0                !求解设置，此处非必须的
NLGEOM,1
NSUBST,20,10000,20   
OUTRES,ERASE
OUTRES,ALL,1
AUTOTS,1
TIME,20
ALLSEL,ALL  
SAVE,'allok-miao-shell91-x80y41-difftref','db',
/STATUS,SOLU

SOLVE                    !求解  
FINISH


计算结果见下图(变形放大50倍，并设置/eshape,1）

[ 本帖最后由 phe666 于 2008-7-31 21:52 编辑 ]

phe666

续上贴


3）采用solsh190、solid185、solid186、solid191进行计算，命令流和计算结果如下。

  （注1：这些单元的计算结果比上述1）、2）中单元的计算结果大三倍左右，可以认为是错误的。）

    (注2：同样为简洁，这里只列出了solsh190的命令流，其它的命令流非常相近，如有感兴趣的同志请跟帖，我再贴上来)


!*********************
!5--solsh190
!*********************

/PREP7
/TITLE,  solsh190, x80y41, difftref
ET,1,SOLSH190               ! LAYERED SOLID-SHELL ELEMENT
KEYOPT,1,8,1                ! WRITE LAYER RESULTS

SECTYPE,1,SHELL
SECDATA,0.38,1               ! LAYER 1: 0.38 THK
SECDATA,0.5, 2               ! LAYER 2: 0.5 THK
secdata,0.5,3                   !LAYER 3: 0.5 THK
secdata,3.2,4                    !LAYER 4: 3.2 THK

MP,EX,1,3000               ! MATERIAL 1 PROPERTIES
MP,NUXY,1,0.4
mp,reft,1,99
MP,ALPX,1,26E-6

MP,EX,2,10.1               ! MATERIAL 2 PROPERTIES
MP,NUXY,2,0.42
mp,reft,2,55
MP,ALPX,2,140E-6

MP,EX,3,10.1               ! MATERIAL 3 PROPERTIES
MP,NUXY,3,0.42
mp,reft,3,55
MP,ALPX,3,140E-6

MP,EX,4,72000               ! MATERIAL 4 PROPERTIES
MP,NUXY,4,0.22
mp,reft,4,140
MP,ALPX,4,8.5E-6

BLOCK,0,80,0,41,0,4.58,          !建立一个六面体  
!*
!*
lsel,s,loc,x,40                          !设置单元划分参数
lesize,all, , ,80, , , , ,0
lsel,s,loc,y,20.5
lesize,all, , ,41, , , , ,0
lsel,s,loc,z,2.29
lesize,all, , ,1, , , , , 0
allsel,all
!*
TYPE,1                                     !划分单元
MSHAPE,0,3D
MSHKEY,1
!*******
veorient,1,kp,2,5                  !指定单元方向
!********
VMESH,all   
!*  

nsel,s,loc,y,0                   !施加约束
DSYM,SYMM,Y, ,  
nsel,s,loc,x,0
DSYM,SYMM,X, ,  
nsel,s,loc,x,0
nsel,r,loc,y,0
nsel,r,loc,z,0
d,all,uz,0
ALLSEL,ALL  
!*  
BF,all,TEMP,-30         !施加载荷
ALLSEL,ALL  

/SOLU   
ANTYPE,0                !求解设置，非必须
NLGEOM,1
NSUBST,20,1000,20   
OUTRES,ERASE
OUTRES,ALL,1
AUTOTS,1
TIME,20
ALLSEL,ALL  
SAVE,'allok-miao-solsh190-x80y41-difftref','db',
/STATUS,SOLU

SOLVE         !求解   
FINISH  



计算结果见下图（变形放大50倍，并设置/eshape,1）

[ 本帖最后由 phe666 于 2008-7-31 21:52 编辑 ]

phe666

自己顶一顶，呵呵

phe666

不好意思，自己再顶一顶

phe666

不好意思，自己再顶一顶

海浪

帮楼主顶一下。辛苦了

koalabear

感谢楼主的共享。
有个问题希望得到你的指点：
现在我有两种材料，内层材料是碳钢，外层材料是玻璃纤维，现在我想用内层建实体模型，外层建壳单元模型，请问这种如何进行分析。
实体模型我用185，壳模型我用99，因为设计角度问题，因此用的99.
我试了几种角度，但是结果完全一致，我怀疑我操作过程中有问题，期待你指点。谢谢。

koalabear

这是我用46单元建立的模型，后面的命令流我没有整理。
R1=100
T1=4
T2=4
l1=500
/PREP7  
!*  
ET,1,SOLID185   
ET,2,SOLID46
KEYOPT,2,8,1
!*  
MPTEMP,,,,,,,,  
MPTEMP,1,0
MPDATA,EX,1,,2e5
MPDATA,PRXY,1,,0.3  
MPDATA,EX,2,,47.33e3
MPDATA,EY,2,,8.97e3
MPDATA,EZ,2,,8.97e3
MPDATA,PRXY,2,,0.26
MPDATA,PRYZ,2,,0.05
MPDATA,PRXZ,2,,0.26
MPDATA,GXY,2,,6.2e3
MPDATA,GYZ,2,,2e3   
MPDATA,GXZ,2,,2e3   

*SET,_RC_SET,1,
R,1
RMODIF,1,1,2,0,0,0,0,0  
!*  
RMODIF,1,13,1,20,t2/2,1,10,t2/2,

CYLIND,R1,R1+T1,0,L1,0,90,
CYLIND,R1+t1,R1+T1+t2,0,L1,0,90,
圆形0度和90上是对称，一侧端面是轴向约束，内压10MPa.
我调整角度，结果都一样。

thp1230

您好，我刚开始学ansys做薄壁结构的分析，我对你用壳网格做这种层状结构很有兴趣，看了你的91壳单元的命令流，
RECTNG,0,80,0,41,       !生成平面并划分网格
LSEL,S,LOC,X,40
LESIZE,all, , ,80, , , , ,0
lsel,s,loc,y,20.5
lesize,all, , ,41, , , , , 0
allsel,all
amesh,all
这段是你对网格的描述，我不知道你四层网格具体是怎么用壳网格描述的，是四层壳单元么，我不太清楚怎么描述的

lucky07

谢谢楼主，你的这个例子和我将要做的东西很像，谢谢！很有用

lucky07

请教，如果我想把每一层的应力等效成一个值，应该怎么输出这个数据。也就是，4层的话，分别输出4个等效的值。
进一步，假设这四层，每层中间厚度取一个点，然后输出这四个应力，应该怎么操作？
希望楼主帮助，谢谢！

杨逸

楼主有联系方式吗，想请教一下

守候

正在学习复合材料建模，能不能把那几个程序全部发给我参考参考啊，谢谢，30837443@qq.com

zhangyingying85

这些单元的刚度矩阵是不一样的，问题应该就出在这些方面了，计算时应当选取合适的单元，并不是所有的单元都可以用，呵呵，我是新手，渴望高手不吝赐教

w4001002

太好了！现在正在学习这个！

cugxiong

资源共享 共同提高

tyrone

学习啊学习啊

junwen686

你这shell单元还有厚度啊？

FXL2010

楼主辛苦了！