【原创】用循环语句建立网架模型

tenyen

问题提出：
一正放四角锥网架，周边简支，平面尺寸45m×45m，网架高度3m,网格间距3m,上下弦、斜杆的平均截面面积分别为17.17cm^2、13.08cm^2、7.90cm^2，荷载q=2.0KN/m^2, 材料的弹性模量206e9N/M^2。
  
问题分析
根据结构的几何特点，单元类型选用LINK8单元（空间桁架单元），根据各节点的坐标生成节点，并采用直接法构建有限元类型（通过连接节点直接生成单元）。采用默认的求解器求解，求解结束后列表显示各节点的位移（PRDISP）、各节点反力（PRESOL）。
  
下面是命令流:

yiby

我帮你将它帖出来，方便大家看。
  
/prep7   
et,1,8  !定义单元类型
mp,ex,1,206e9   !定义杨氏弹性模量
mp,prxy,1,.3   !定义泊松比
r,1,17.17e-4   !定义实常数
r,2,13.08e-4   
r,3,7.9e-4   
l1=45    !网架的平面尺寸
l2=45   
a=3  !网格间距
b=3
m=l1/a  
n=l2/b
m1=m+1  
n1=n+1  
h=3  !网架高度
q=2.0e3  !荷载
  
real,1
  
!定义上弦节点
*do,i,1,n1,1
*do,j,1,m1,1
n,(i-1)*m1+j,(j-1)*a,0,(i-1)*b   
*enddo   
*enddo
  
!定义下弦节点
*do,i,1,n,1  
*do,j,1,m,1  
n,m1*n1+(i-1)*m+j,(j-1)*a+a/2,-h,(i-1)*b+b/2
*enddo   
*enddo  
  
!建立上弦杆单元
real,1
*do,i,1,m1,1
*do,j,i,i+(n1-2)*m1,m1
e,j,j+m1
*enddo   
*enddo  
  
*do,i,1,m1*(n1-1)+1,m1
*do,j,i,i+m1-2,1  
e,j,j+1
*enddo   
*enddo
  
!建立下弦杆单元
real,2  
*do,i,1,m,1  
*do,j,i,i+m*(n-2),m  
e,m1*n1+j,m1*n1+j+m  
*enddo   
*enddo   
  
*do,i,1,m*(n-1)+1,m  
*do,j,i,i+m-2,1  
e,m1*n1+j,m1*n1+j+1  
*enddo   
*enddo   
  
!建立腹杆单元
real,3   
*do,i,1,n,1  
*do,j,1,m,1  
e,m1*n1+(i-1)*m+j,(i-1)*m1+j
e,m1*n1+(i-1)*m+j,(i-1)*m1+j+1   
e,m1*n1+(i-1)*m+j,i*m1+j
e,m1*n1+(i-1)*m+j,i*m1+j+1   
*enddo   
*enddo   
  
finish   
/solu   !进入求解器
nsel,s,loc,x,0   !施加位移约束
nsel,a,loc,x,l1  
nsel,a,loc,z,l2  
nsel,a,loc,z,0   
cm,ty,node
d,all,ux
d,all,uy
d,all,uz
allsel,all   
/VIEW, 1 ,1,1,1  
/REPLOT   
EPLOT  
  
nsel,s,loc,y,0  !施加荷载
cmsel,u,ty
f,all,fy,-q*a*b
  
allsel,all   
EPLOT
   
solve     !求解
finish
  
/post1  !进入通用后处理器
prnsol,dof    !列表显示各节点的位移
presol,forc   !列表显示各单元节点的反力

yiby

很好的东东，可以帮助大家理解循环控制的使用！

蔓蔓青萝

这个写的简单易懂，不错

zx_buff

很好，谢谢啦！

Wallace998

谢谢分享！

czr598

可以帮助大家理解循环控制的使用