- 积分
- 64
- 注册时间
- 2003-3-10
- 仿真币
-
- 最后登录
- 1970-1-1
|
在这个例子中, 电流通过suspended金属桥,Joule heating引起温升,并伴随相变。例子很简单,只是说明如何做热电耦合。
FINISH
/CLEAR
k=95
DEN=3900
Cp=450
/PREP7
um=1e-6
L=100*um
W=10*um
T=0.05*um
mA=0.001
rou=1e-7
I=3.1624*mA
DT=5
FUSION=15*Cp
T0=480
T_MELT=500
T_LOW=0
T_HIGH=1.5*T_MELT
Size=1*um
!*
ET,1,SOLID69
UIMP,1,DENS, , ,DEN,
UIMP,1,KXX,KYY,KZZ,k,k,k,
UIMP,1,RSVX,RSVY,RSVZ,rou,rou,rou
!UIMP,1,C, , ,Cp,
MPTEMP,1,T_LOW,T_MELT-DT/2,T_MELT+DT/2,T_HIGH
MPDATA,ENTH,1,1,0,DEN*Cp*(T_MELT-DT/2-T_LOW),DEN*(Cp*(T_MELT-DT/2-T_LOW)+FUSION),DEN*(Cp*(T_MELT-DT/2-T_LOW)+FUSION+Cp*(T_HIGH-T_MELT-DT/2))
BLC4, 0, 0, W, L, T
lsel,s,LOC,x,0,0
lsel,r,LOC,y,0,L
lesize,all,Size,
allsel,all
lsel,s,LOC,y,0,0
lsel,r,LOC,x,0,W
lesize,all,W,
allsel,all
TYPE,1
MAT,1
mshkey,1
mshape,0,3d
vmesh,1
/solu
tunif,T0
TREF,T0
asel,s,LOC,y,0,0
asel,a,LOC,y,L,L
DA,all,TEMP,T0 !Two ends of the bridge are kept at T0
allsel,all
asel,s,LOC,y,0,0 ! Assume one end V=0
DA,ALL,VOLT,0
asel,all
nsel,s,LOC,y,L,L
cp,2,volt,all ! Couple VOLT dofs
ni=ndnext(0) ! Get master node
nsel,all
VSEL,ALL
f,ni,amps,I !Apply current at one end
allsel,all
ANTYPE,4
SOLCONTROL,OM,0
TIME,1e-4
AUTOTS,-1
DELTIM,1e-6, , ,1
KBC,1
OUTRES,ALL,ALL,
SOLVE |
评分
-
1
查看全部评分
-
|