!石英坩锅的热分析,从室温20度升至出炉温度1100度
finish
/clear
!
! Part1---predefined scalar parameters计算参数定义
!
! parameters for geometrical dimension
top_width=0.849 !上口外缘边长
top_wall_thickness=0.018 !上口壁厚
bottom_width=0.889 !下口外缘边长
bottom_wall_thickness=0.024 !下口壁厚
height=0.500 !坩锅高
bottom_thickness=0.021 !坩锅底厚度
inner_wall_radius=0.016 !内缘墙角倒脚半径
outer_wall_radius=0.023 !外缘墙角倒脚半径
inner_bottom_radius=0.017 !内缘底部四周倒脚半径
outer_bottom_wedge=0.014 !外缘底部四周斜倒脚契子尺寸
element_size=0.008
! paramters for material properties
modulus=80e9 !elastic modulus Pa
c_heat=744 !specific heat J/kg/K
air_convection=2.5 ! BTU/hr./ft.^2/F
heat_conduct=0.5 !千卡/米/时/K
heat_expansion=0.55e-6 ! /K
density=2.1e3 !Kg/m^3
! paramters for temperatures
prev_temp=1100 !开始温度
room_temp=20 !室温
!
! Part2----preprocessor建立实体模型
!
/PREP7
!***** building keypoints of top
K,1,top_width/2, 0,height
K,2,top_width/2, top_width/2,height
K,3,0, top_width/2,height
K,4,0, (top_width/2-top_wall_thickness),height
K,5,(top_width/2-top_wall_thickness), (top_width/2-top_wall_thickness),height
K,6,(top_width/2-top_wall_thickness), 0,height
!***** building keypoints of inner bottom
K,7,(bottom_width/2-bottom_wall_thickness), 0,bottom_thickness
K,8,(bottom_width/2-bottom_wall_thickness), (bottom_width/2-bottom_wall_thickness),bottom_thickness
K,9,0, (bottom_width/2-bottom_wall_thickness),bottom_thickness
K,10,0, 0,bottom_thickness
!***** building keypoints of outer bottom
K,11,0, 0,0
K,12,0, (bottom_width/2),0
K,13,(bottom_width/2), (bottom_width/2),0
K,14,(bottom_width/2), 0,0
!*****building vertical surface areas that hold the volume
A,5,6,7,8
A,2,3,12,13
A,4,5,8,9
A,1,2,13,14
A,11,10,9,12
A,11,10,7,14
A,1,6,7,14
A,3,4,9,12
!*****building area fillets on inner wall corners
AFILLT, 1, 3, inner_wall_radius
!*****building area fillets on 4 outer wall corners
AFILLT, 2,4, outer_wall_radius
!*****building horizontal surface areas that hold the volume
LSTR,23,27
LSTR,25,29
AL,4,30,23,41
AL,3,4,25,5
AL,5,33,22,44
AL,24,42,16,19,34
AL,1,31,18,21,45
!*****building area fillets on 2 inner floor corners
AFILLT, 11, 14, inner_bottom_radius
AFILLT, 9, 18,inner_bottom_radius
!****画出内缘的空间倒角
!**作辅助面,以便画出空间倒角
K,1001,(bottom_width/2), (bottom_width/2),inner_bottom_radius+bottom_thickness
A,1001,22,34
A,22,28,36
!**形成内缘墙倒角面与水平面的交线,并将倒角面在交线处截止
ASBA, 10, 9
ASBA, 17, 18
ADELE,9,,,1
ADELE,20,,,1
AL,9,11,26
ADELE,5,8,,1
ADELE,1,,,0
ADELE,3,,,0
ADELE,12,,,0
ADELE,15,,,0
!*****生成外缘地板处的斜倒角
KL,-21,(bottom_width/2-outer_bottom_wedge)/(bottom_width/2),37
KL,-18,(bottom_width/2-outer_bottom_wedge)/(bottom_width/2),38
*GET, lenth, line, 14, LENG
KL,-14,(lenth-outer_bottom_wedge)/lenth,39
KL,6,(lenth-outer_bottom_wedge)/lenth,40
KL,43,(lenth-outer_bottom_wedge)/lenth,41
KL,32,(lenth-outer_bottom_wedge)/lenth,42
K,43,kx(41)-outer_bottom_wedge,ky(41),0
K,44,kx(42),ky(42)-outer_bottom_wedge,0
LSTR,37,43
LSTR,38,44
LSTR,39,41
LSTR,40,42
LARC,44,43,37,(outer_wall_radius-outer_bottom_wedge)
LARC,41,42,39,outer_wall_radius
!*****生成地板处的角落
K,45,kx(35),ky(35),0
K,46,kx(36),ky(36),0
K,47,kx(32),ky(32),0
LSTR,45,46
LSTR,46,47
LDELE,6,,,1
LDELE,18,,,1
LDELE,14,,,1
LDELE,21,,,1
LDELE,43,,,1
LDELE,32,,,1
LDELE,45,,,1
LDELE,1,,,1
LDELE,31,,,1
K,11,0,0,0
LSTR,10,11
LSTR,11,45
LSTR,11,47
LSTR,45,37
LSTR,47,38
LSTR,38,40
LSTR,37,39
LSTR,40,3
LSTR,39,1
LSTR,36,46
LSTR,35,45
LSTR,32,47
LSTR,29,41
LSTR,23,42
LSTR,22,42
LSTR,34,41
LSTR,20,39
LSTR,19,40
LSTR,41,43
LSTR,42,44
LSTR,44,46
LSTR,22,44
LSTR,34,43
LSTR,43,46
!*****生成包络体积的面
AL,1,40,35,14
AL,1,6,32,54
AL,18,24,45,10,32
AL,29,22,34,45
AL,20,21,46,7,35
AL,46,28,23,27
AL,29,44,38,12
AL,13,27,30,39
AL,31,17,32,53
AL,31,55,35,19
AL,16,39,3,38
AL,42,26,43,16
AL,37,46,13,42
AL,43,50,45,12
AL,12,47,2,24
AL,13,48,8,21
AL,16,48,15,47
AL,57,2,18,17
AL,17,6,14,19
AL,4,39,42,36
AL,5,38,43,49
AL,51,8,20,19
AL,42,48,52
AL,51,52,11,31
AL,56,43,47
AL,9,56,57,31
AL,15,51,57
!*****生成底板实体
VA,19,3,1,18,17,29
VA,16,2,8,23,30,15
VA,11,13,6,24,31,12
VA,4,20,30,21,31,22
VA,7,26,32,18,10,23,33,34
VA,35,36,24,14,17,28,25,5
VA,9,33,34,36,35,22,27,37
!*
! element definition
!ET,1,SOLID226,11,1 !**耦合场分析单元
ET,1,SOLID70,0,,0
!*
! material properties
MPTEMP,,,,,,,,
MPTEMP,1,0,200,400,600,800,1000
MPTEMP,7,1200
MPDATA,EX,1,,77.8e9,82.5e9,83e9,84e9,85e9,85e9
MPDATA,EX,1,7,85e9
MP,PRXY,1,0.17
UIMP,1,REFT,,,room_temp
MP,ALPX,1,heat_expansion
MP,DENS,1,density
MPDATA,C,1,,0.213*4.2*1000,0.213*4.2*1000,0.23*4.2*1000,0.24*4.2*1000,0.26*4.2*1000,0.273*4.2*1000
MPDATA,C,1,7,0.28*4.2*1000
MPDATA,KXX,1,,0.331*4.2,0.394*4.2,0.367*4.2,0.447*4.2,0.484*4.2,0.514*4.2,0.547*4.2
MPDATA,KXX,1,7,0.581*4.2
ALLSEL,ALL
!*****网格划分
*get,lenth,line,1,leng
LSEL,,,,37
LSEL,A,,,12,13
LSEL,A,,,55
LSEL,A,,,8
LSEL,A,,,19
LSEL,A,,,50
LSEL,A,,,53
LSEL,A,,,17
LSEL,A,,,2
LESIZE,all,,,60
allsel,all
TYPE,1
MAT,1
mshape,0,3D
vmesh,1,4
VADD,5,6,7
TYPE,1
mshape,1,3D
!vmesh,5,7
VMESH,8
!*go,:10
!*****求解
/SOLU
ANTYPE,trans
!*****施加对称边界条件
ASEL,,,,3
ASEL,A,,,5,6
DA,all,SYMM
allsel,all
ASEL,,,,1
ASEL,A,,,7,8
DA,all,SYMM
allsel,all
!*****求解时间步长
TIME,30
DELTIM,0.4,0.4,3
AUTOTS,on
OUTRES,,all
TUNIF,20 !** 起点温度20度
!*****定义对流传热系数
ASEL,,,,9,16
ASEL,A,,,19,21
ASEL,A,,,25,29
ASEL,A,,,32
ASEL,A,,,2
ASEL,A,,,4
ASEL,A,,,37
NSLA,
SF,all,CONV,650,1100
!D,all,TEMP,1100
allsel,all
solve
finish
/POST1
PLNSOL,temp
:10
FINISH |