找回密码
 注册
Simdroid-非首页
楼主: zengxiaodong

[电磁场] ANSYS Emag“现代技术”新单元Plane233线性摄动分析有问题!

[复制链接]
 楼主| 发表于 2015-12-7 16:53:13 | 显示全部楼层 来自 安徽宣城
本帖最后由 zengxiaodong 于 2015-12-7 16:55 编辑
zengxiaodong 发表于 2015-11-14 20:54
电脑格式化重装了,坚决不支付500美金!

在单元plane233中,增加了一个实常数,那就是厚度THK,如果给定实常数THK为0.087,也就是电机铁芯的厚度,则计算转矩时不必要再乘以厚度了,同理,计算自感、互感、绝对磁链时也不必乘以厚度了!

这与以前的plane53单元默认电机轴向长度为1米有一点区别,当然如果不指定plane233的THK实常数,则仍然默认为1米!
回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-8 15:13:25 | 显示全部楼层 来自 安徽宣城
Simdroid开发平台
本帖最后由 zengxiaodong 于 2015-12-8 17:18 编辑

可能是plane233在计算增量磁能和增量磁共能时,对于永磁材料的计算出现了错误,或者根本就不能包含永磁材料!因为在线性摄动分析手册中,特别提到永磁材料的问题,但是仅提到谐波分析可以包含永磁材料,而压根没有提到静态分析是否可以包含永磁材料!而且plane233单元还不能使用宏命令SENERGY来计算单元的磁能、磁共能,个中原因实在是令人疑惑!



Permanent magnets (MP,MGXX, also MGYY, MGZZ) are supported in a linear perturbation harmonic analysis. Although they contribute only to the base (operating point solution), they should not be removed from the model in the linear perturbation analysis.
——————摘自16.2版《低频电磁手册》第243页

回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-9 17:17:06 | 显示全部楼层 来自 安徽
本帖最后由 zengxiaodong 于 2015-12-15 00:00 编辑

有个例子VM213,其中有计算磁能、磁共能的内容,单元类型是SOLID236,可惜也没有包含永磁材料!



/COM,ANSYS MEDIA REL. 16.2 (6/24/2015) REF. VERIF. MANUAL: REL. 16.2
/VERIFY,VM213
/TITLE,VM213, DIFFERENTIAL INDUCTANCE OF A TRANSFORMER
/NOPR
/COM
/COM  REFERENCE:
/COM  M.GYIMESI,D.OSTERGAARD,"INDUCTANCE COMPUTATION BY
/COM  INCREMENTAL FINITE ELEMENT ANALYSIS", IEEE
/COM  TRANSACTION ON MAGNETICS, VOL.35, NO.3 (1998),
/COM  PP.1119-1122
/COM
/COM
/COM       ^ y axis             : symmetry plane
/COM       :                    : core center
/COM       :<.x1.>.<.x2.>.<.x..>:
/COM       :      :      :      :
/COM  --------------------------:
/COM !                          : nonlin core:
/COM !     yoke ideal iron      : H = Hs (B/Bs)^2; BS=2T;HS=100A/m
/COM !                          :
/COM !      -------------       :....
/COM !leg  !      :      !nonlin:  ^
/COM !ideal!coil1 :coil2 ! iron :  y
/COM !iron !      :      ! core :  :
/COM !      -------------       :..v..> x axis
/COM !                          :
/COM !     yoke ideal iron      :
/COM !                          :
/COM  --------------------------:
/COM
/COM target
/COM
/COM nominal
/COM    magnetic field in the core    : Hn  = (N1 I1 + N2 I2) / y    = 25
/COM    flux density   in the core    : Bn  = Bs sqrt(H/Hs)          = 1
/COM    tangent reluctivity           : dH/dB = 2 Hs/Bs B/Bs         = 50
/COM    magnetic energy in the core   : nlene = Hs/Bs^2 Bn^3/3 2xyz  = 0.0166
/COM    magnetic coenergy in the core : nlcene = Bn Hn 2xyz - nlene  = 0.0333
/COM
/COM inductances
/COM    self coil 1                   : L11 ~ 2 N1^2  x z / (y nui)  = 0.4
/COM    self coil 2                   : L22 ~ 2 N2^2  x z / (y nui)  = 1.6
/COM    mutual between coil 1 and 2   : L12 ~ 2 N1 N2 x z / (y nui)  = 0.8
/COM
/COM flux linkages
/COM    coil 1                        : psi1 = 2 N1 x z B0           = 0.2
/COM    coil 2                        : psi2 = 2 N2 x z B0           = 0.4

!       GEOMETRY DATA
N=1                     ! MESHING PARAMETER
X1=0.1                  ! WIDTH (X SIZE) OF COIL 1
X2=0.1                  ! WIDTH (X SIZE) OF COIL 2
X=0.1                   ! WIDTH (X SIZE) OF CORE
Y=0.1                   ! HIGHT OF CORE, Y SIZE OF WINDOW
Z=0.1                   ! THICKNESS OF IRON IN Z DIRECTION
NUI=50                  ! ABSOLUTE RELUCTIVITY OF IRON
N1=10                   ! NUMBER OF TURNS IN COIL1
N2=20                   ! NUMBER OF TURNS IN COIL2
!      EXCITATION DATA
SYMFAC=2                ! SYMMETRIC FACTOR FOR INDUCTANCE COMPUTATION
NC=2                    ! NUMBER OF COILS
*DIM,CUR,ARRAY,NC       ! NOMINAL CURRENTS OF COILS
CUR(1)=0.2              ! NOMINAL CURRENT OF 1ST COIL
CUR(2)=0.025            ! TINY NOMINAL CURRENT OF 2ND COIL
!      DERIVED AUXILIARY PARAMETERS
MU0=3.1415926*4.0E-7
MURI=1/NUI/MU0          ! RELATIVE PERMEABILITY OF IRON
X3=X1+X2                ! X COORDINATE OF THE RIGHT OF COIL2
X4=X3+X                 ! X COORDINATE OF MIDDLE OF CORE (SYMMETRY PLANE)
JS1=CUR(1)*N1/(X1*Y)    ! NOMINAL CURRENT DENSITY OF COIL1
JS2=CUR(2)*N2/(X2*Y)    ! NOMINAL CURRENT DENSITY OF COIL2

/PREP7
SMRT,OFF
ET,1,SOLID236
MP,MURX,1,1             ! AIR/COIL
BS=2                    ! SATURATION FLUX DENSITY
HS=100                  ! SATURATION MAGNETIC FIELD
TB,BH,2                 ! CORE: H = Hs (B/Bs)^2; Bs=2T;Hs=100A/m
TBPT,,  1, 0.2
TBPT,,  4, 0.4
TBPT,,  9, 0.6
TBPT,, 16, 0.8
TBPT,, 25, 1.0
TBPT,, 36, 1.2
TBPT,, 49, 1.4
TBPT,, 64, 1.6
TBPT,, 81, 1.8
TBPT,,100, 2.0
TBPT,,121, 2.2
TBPT,,144, 2.4
TBPT,,169, 2.6
TBPT,,176, 2.8
TBPT,,225, 3.0
TBPT,,256, 3.2
TBPT,,289, 3.4
TBPT,,324, 3.6
TBPT,,361, 3.8
TBPT,,400, 4.0
TBPLOT,BH,2   !PLOT BH CURVE

BLOCK, 0,X1,0,Y,0,Z     ! COIL1
BLOCK,X1,X3,0,Y,0,Z     ! COIL2
BLOCK,X3,X4,0,Y,0,Z     ! CORE
VGLUE,ALL
VSEL,S,LOC,X,X1/2
VATT,1,1,1               ! COIL 1 VOLUME ATTRIBUTE
VSEL,S,LOC,X,X1+X2/2
VATT,1,2,1               ! COIL 2 VOLUME ATTRIBUTE
VSEL,S,LOC,X,X3+X/2
VATT,2,3,1               ! IRON VOLUME ATTRIBUTE
VSEL,ALL
ESIZE,,N
VMESH,ALL
NSEL,S,LOC,X,X4         ! FLUX PARALLEL DIRICHLET AT SYMMETRY PLAIN, X=X4,Z=0,Z=Z
NSEL,A,LOC,Z,0
NSEL,A,LOC,Z,Z
D,ALL,AZ,0
!                       ! HOMOGENEOUS NEUMANN FLUX NORMAL AT YOKE, X=0, Y=0, Y=Y
NSEL,ALL
ESEL,S,ELEM,,1          ! COIL 1 COMPONENT
BFE,ALL,JS,,,,JS1       ! CURRENT DENSITY IN COIL 1
ESEL,S,ELEM,,2          ! COIL 2 COMPONENT
BFE,ALL,JS,,,,JS2       ! UNITE CURRENT DENSITY IN COIL 2
ALLSEL
FINISH
/COM
/COM OBTAIN OPERATING SOLUTION
/COM
/SOLUTION
ANTYPE,STATIC
CNVTOL,CSG,1,1.0E-3
SOLVE
FINISH
/POST1
SET,LAST
/COM
/COM COMPUTE STORED ENERGY AND CO-ENERGY
/COM
ETABLE,_mene,MENE
ETABLE,_coen,COEN
ETABLE,_aene,AENE
SSUM
*get,STORENG,ssum,,item,_mene
*get,STORCOE,ssum,,item,_coen
*get,STORAEN,ssum,,item,_aene

/com,
/com, Energy = %STORENG*SYMFAC%
/com, Co-energy = %STORCOE*SYMFAC%
/com, Apparent energy = %STORAEN*SYMFAC%
/com
FINISH
*DIM,LABENG,CHAR,2
*DIM,VALENG,,2,2
*DIM,RESENG,,2,1
LABENG(1)='ENERGY','CO-ENERGY'
*VFILL,VALENG(1,1),DATA,0.0166,0.0333
*VFILL,RESENG(1,1),DATA,2*STORENG,2*STORCOE
*VFILL,VALENG(1,2),DATA,ABS(2*STORENG/0.0166),ABS(2*STORCOE/0.0333)
PARSAVE,all
/COM,
/COM, ***  COMPUTE INDUCTANCE AND FLUX USING THE LINEAR PERTURBATION PROCEDURE
/COM,
ALLSEL
/SOLUTION
ANTYPE,STATIC,RESTART,,,PERTURB
PERTURB,STATIC,,CURRENT,ALLKEEP
SOLVE,ELFORM
! Apply CUR(1) only to determine L11
BFE,1,JS,,,,JS1
BFEDELE,2,JS
SOLVE
! Apply CUR(2) only to determine L12
BFEDELE,1,JS
BFE,2,JS,,,,JS2
SOLVE
! Apply CUR(1) and CUR(2) together to determine L12
BFE,1,JS,,,,JS1
BFE,2,JS,,,,JS2
SOLVE
FINISH
PARRES
! define arrays for inductance, flux linkage, and energy
*DIM,INDI,ARRAY,2,2  ! incremental inductance matrix
*DIM,IENE,ARRAY,2,2  ! incremental energy
*DIM,COEN,ARRAY,2,2  ! coenergy energy
*DIM,FLX,ARRAY,2     ! flux
/POST1
FILE,,rstp
SET,1,LAST
ETABLE,_iene,IENE
ETABLE,_coen,COEN
SSUM
*GET,IENE(1,1),ssum,,item,_iene
*GET,COEN(1,1),ssum,,item,_coen
SET,2,LAST
ETABLE,_iene,IENE
ETABLE,_coen,COEN
SSUM
*GET,IENE(2,2),ssum,,item,_iene
*GET,COEN(2,2),ssum,,item,_coen
SET,3,LAST
ETABLE,_iene,IENE
ETABLE,_coen,COEN
SSUM
*GET,IENE(1,2),ssum,,item,_iene
*GET,COEN(1,2),ssum,,item,_coen
FINISH
! COMPUTE INCREMENTAL INDUCTANCE
INDI(1,1)=2*IENE(1,1)/CUR(1)**2*SYMFAC
INDI(2,2)=2*IENE(2,2)/CUR(2)**2*SYMFAC
INDI(1,2)=(IENE(1,2)-IENE(1,1)-IENE(2,2))/(CUR(1)*CUR(2))*SYMFAC
INDI(2,1)=INDI(1,2)
! COMPUTE FLUX
FLX(1)=COEN(1,1)/CUR(1)*SYMFAC
FLX(2)=COEN(2,2)/CUR(2)*SYMFAC
!SET UP AND FILL VM RATIO TABLE
RAT_1 = ABS(INDI(1,1)/0.40)
RAT_2 = ABS(INDI(2,2)/1.60)
RAT_3 = ABS(INDI(1,2)/0.80)
*DIM,LABEL,CHAR,3
*DIM,VALUE,,3,2
*DIM,RESULTS,,3,1
LABEL(1) = 'COIL1','COIL2','MUTUAL'
*VFILL,VALUE(1,1),DATA,0.40,1.60,0.80
!
!FILL RESULTS VECTOR WITH INDUCTANCE MATRIX VALUES
!
*VFILL,RESULTS(1,1),DATA,INDI(1,1),INDI(2,2),INDI(1,2)
*VFILL,VALUE(1,2),DATA,RAT_1,RAT_2,RAT_3
*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,2
*DIM,RESULT1,,2,1
LABEL1(1)= 'COIL1','COIL2'
*VFILL,VALUE1(1,1),DATA,0.2,0.4
!
! FILL RESULTS VECTOR WITH FLUX ARRAY VALUES
!
*VFILL,RESULT1(1,1),DATA,FLX(1),FLX(2)
*VFILL,VALUE1(1,2),DATA,ABS(FLX(1)/0.2),ABS(FLX(2)/0.4)
/COM
/OUT,vm213,vrt
/COM,------------------- VM213  RESULTS COMPARISON ---------------------
/COM
/COM,   ENERGY (J)   |   TARGET   |  Mechanical APDL  |   RATIO
/COM
*VWRITE,LABENG(1),VALENG(1,1),RESENG(1,1),VALENG(1,2)
(1X,A10,'     ',F10.4,'    ',F10.4,'     ',1F13.3)
/COM
/COM,  FLUX (Weber)  |   TARGET   |  Mechanical APDL  |   RATIO
/COM,
*VWRITE,LABEL1(1),VALUE1(1,1),RESULT1(1,1),VALUE1(1,2)
(1X,A10,'     ',F10.4,'    ',F10.4,'     ',1F13.3)
/COM,
/COM, INDUCTANCE (H) |   TARGET   |  Mechanical APDL  |   RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),RESULTS(1,1),VALUE(1,2)
(1X,A10,'     ',F10.4,'    ',F10.4,'     ',1F13.3)
/COM,-------------------------------------------------------------------
/OUT,
*LIST,vm213,vrt
FINISH

回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-10 17:22:14 | 显示全部楼层 来自 安徽宣城
本帖最后由 zengxiaodong 于 2015-12-16 21:45 编辑

/SOLUTION
ANTYPE,STATIC
CNVTOL,CSG,1,1.0E-3
SOLVE
FINISH
/POST1
SET,LAST
/COM
/COM COMPUTE STORED ENERGY AND CO-ENERGY
/COM
ETABLE,_mene,MENE
ETABLE,_coen,COEN
ETABLE,_aene,AENE
SSUM
*get,STORENG,ssum,,item,_mene
*get,STORCOE,ssum,,item,_coen
*get,STORAEN,ssum,,item,_aene


上面几句是进入求解器进行静态分析,并且,进入后处理求出磁能、磁共能、视在磁能的命令流!

对于plane233而言,查阅单元手册,输出数据表中最后4项为:

SENE or MENE:        Magnetic energy                               磁能
COEN:                  Magnetic co-energy                           磁共能
AENE:                   Apparent magnetic energy                 视在磁能
IENE:                   Incremental magnetic energy              增量磁能

因此,也可以仿照上贴VM213的例子,进行磁能、磁共能的计算,疑问就是:

有增量磁能,但没有增量磁共能,是否进行摄动分析以后,COEN就是增量磁共能呢?
回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-14 13:46:38 | 显示全部楼层 来自 上海
zengxiaodong 发表于 2015-12-10 17:22
/SOLUTION
ANTYPE,STATIC
CNVTOL,CSG,1,1.0E-3

既然进行静态分析以后,可以计算出单元的磁能、磁共能,也就可以直接利用这个功能计算工作点的磁能增量,根据微分电感的定义计算出电感参数,后面帖子将按此思路编程计算一下。
回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-15 22:10:08 | 显示全部楼层 来自 安徽芜湖
本帖最后由 zengxiaodong 于 2015-12-15 22:14 编辑

因为互感的计算比较复杂,现以自感和绝对通量计算为例进行编程,遗憾的是下面的程序根本就不能得到正确的结果!
因为在不同工况下计算时,竟然磁能和磁共能几乎不变化,简直不可理喻!

*set,II,115.38733374162411843244072844507
*AFUN,Deg

*SET,AA,-35449955*1.16*1.0
*SET,AAA,50
*SET,IA,AA*sin(90+AAA+Ang*16)   
*SET,IB,AA*sin(90+AAA+Ang*16-120)   
*SET,IC,-1.0*(IA+IB)   

*SET,IAz,IA+II
*SET,IAf,IA-II
*SET,IBz,IB+II
*SET,IBf,IB-II
*SET,ICz,IC+II
*SET,ICf,IC-II

ALLSEL

/solu

antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0

Cnvtol,csg,,1.0e-8
eqslv,sparse
SOLVE

finish

/post1
CMSEL,S,'rotor'
NSLE
ESLN
EMFT
*set,TQ,_tzsum*8
ALLSEL,ALL
etable,_sene,sene
etable,_coen,coen
ssum
*get,sene_0,ssum,,item,_sene
*get,coen_0,ssum,,item,_coen
finish

ALLSEL,ALL

/solu
antyp,static,new

BFA,  A+,JS,  , ,  IAz,0
BFA,  A-,JS,  , ,  -IAz,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0
solve

/post1
etable,_sene,sene
etable,_coen,coen
ssum
*get,sene_Az,ssum,,item,_sene
*get,coen_Az,ssum,,item,_coen
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IAf,0
BFA,  A-,JS,  , ,  -IAf,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0
solve

/post1
etable,_sene,sene
etable,_coen,coen
ssum
*get,sene_Af,ssum,,item,_sene
*get,coen_Af,ssum,,item,_coen
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IBz,0
BFA,  B-,JS,  , ,  -IBz,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0
solve

/post1
etable,_sene,sene
etable,_coen,coen
ssum
*get,sene_Bz,ssum,,item,_sene
*get,coen_Bz,ssum,,item,_coen
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IBf,0
BFA,  B-,JS,  , ,  -IBf,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0
solve

/post1
etable,_sene,sene
etable,_coen,coen
ssum
*get,sene_Bf,ssum,,item,_sene
*get,coen_Bf,ssum,,item,_coen
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  ICz,0
BFA,  C-,JS,  , ,  -ICz,0
solve

/post1
etable,_sene,sene
etable,_coen,coen
ssum
*get,sene_Cz,ssum,,item,_sene
*get,coen_Cz,ssum,,item,_coen
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  ICf,0
BFA,  C-,JS,  , ,  -ICf,0
solve

/post1
etable,_sene,sene
etable,_coen,coen
ssum
*get,sene_Cf,ssum,,item,_sene
*get,coen_Cf,ssum,,item,_coen
finish

/post1

L1=(sene_Az+sene_Af-2*sene_0)*8*100000000
PSIA=(coen_Az+coen_Af-2*coen_0)*8*10000

L2=(sene_Bz+sene_Bf-2*sene_0)*8*100000000
PSIB=(coen_Bz+coen_Bf-2*coen_0)*8*10000

L3=(sene_Cz+sene_Cf-2*sene_0)*8*100000000
PSIC=(coen_Cz+coen_Cf-2*coen_0)*8*10000

*CFOPEN, 'c:\Allres',txt, , Append
*VWRITE,Ang,L1,L2,L3,PSIA,PSIB,PSIC,TQ
(8e16.8)

*CFCLOS

finish
回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-16 18:12:10 | 显示全部楼层 来自 安徽芜湖
本帖最后由 zengxiaodong 于 2015-12-16 18:33 编辑

与上楼同样的计算方法,我们改成plane53单元,程序略加修改,可以正确计算出3相自感,但是3相磁链有问题!



1、转矩计算取消;
2、厚度无法通过实常数输入,因此最后结果要乘以0.087;
3、plane53单元在手册中是没有磁能、磁共能输出的;
4、查阅资料,其实plane53单元有mien和mico输出,分别对应的就是磁能、磁共能

程序如下:
*set,II,115.38733374162411843244072844507
*AFUN,Deg

*SET,AA,-35449955*1.16*0.0
*SET,AAA,50
*SET,IA,AA*sin(90+AAA+Ang*16)   
*SET,IB,AA*sin(90+AAA+Ang*16-120)   
*SET,IC,-1.0*(IA+IB)   

*SET,IAz,IA+II
*SET,IAf,IA-II
*SET,IBz,IB+II
*SET,IBf,IB-II
*SET,ICz,IC+II
*SET,ICf,IC-II

ALLSEL

/solu

antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0

Cnvtol,csg,,1.0e-10
eqslv,sparse
SOLVE

finish

/post1
ALLSEL,ALL
etable,_mien,mien
etable,_mico,mico
ssum
*get,mien_0,ssum,,item,_mien
*get,mico_0,ssum,,item,_mico
finish

ALLSEL,ALL

/solu
antyp,static,new

BFA,  A+,JS,  , ,  IAz,0
BFA,  A-,JS,  , ,  -IAz,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0
solve

/post1
etable,_mien,mien
etable,_mico,mico
ssum
*get,mien_Az,ssum,,item,_mien
*get,mico_Az,ssum,,item,_mico
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IAf,0
BFA,  A-,JS,  , ,  -IAf,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0
solve

/post1
etable,_mien,mien
etable,_mico,mico
ssum
*get,mien_Af,ssum,,item,_mien
*get,mico_Af,ssum,,item,_mico
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IBz,0
BFA,  B-,JS,  , ,  -IBz,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0
solve

/post1
etable,_mien,mien
etable,_mico,mico
ssum
*get,mien_Bz,ssum,,item,_mien
*get,mico_Bz,ssum,,item,_mico
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IBf,0
BFA,  B-,JS,  , ,  -IBf,0
BFA,  C+,JS,  , ,  IC,0
BFA,  C-,JS,  , ,  -IC,0
solve

/post1
etable,_mien,mien
etable,_mico,mico
ssum
*get,mien_Bf,ssum,,item,_mien
*get,mico_Bf,ssum,,item,_mico
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  ICz,0
BFA,  C-,JS,  , ,  -ICz,0
solve

/post1
etable,_mien,mien
etable,_mico,mico
ssum
*get,mien_Cz,ssum,,item,_mien
*get,mico_Cz,ssum,,item,_mico
finish

/solu
antyp,static,new
BFA,  A+,JS,  , ,  IA,0
BFA,  A-,JS,  , ,  -IA,0
BFA,  B+,JS,  , ,  IB,0
BFA,  B-,JS,  , ,  -IB,0
BFA,  C+,JS,  , ,  ICf,0
BFA,  C-,JS,  , ,  -ICf,0
solve

/post1
etable,_mien,mien
etable,_mico,mico
ssum
*get,mien_Cf,ssum,,item,_mien
*get,mico_Cf,ssum,,item,_mico
finish

/post1

L1=(mien_Az+mien_Af-2*mien_0)*8*100000000*0.087
PSIA=(mico_Az+mico_Af-2*mico_0)*8*10000*0.087

L2=(mien_Bz+mien_Bf-2*mien_0)*8*100000000*0.087
PSIB=(mico_Bz+mico_Bf-2*mico_0)*8*10000*0.087

L3=(mien_Cz+mien_Cf-2*mien_0)*8*100000000*0.087
PSIC=(mico_Cz+mico_Cf-2*mico_0)*8*10000*0.087

*CFOPEN, 'c:\Allres',txt, , Append
*VWRITE,Ang,L1,L2,L3,PSIA,PSIB,PSIC
(7e16.8)

*CFCLOS

finish

本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有账号?注册

×
回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-16 23:01:38 | 显示全部楼层 来自 安徽芜湖
本帖最后由 zengxiaodong 于 2015-12-17 11:39 编辑
zengxiaodong 发表于 2015-12-16 18:12
与上楼同样的计算方法,我们改成plane53单元,程序略加修改,可以正确计算出3相自感,但是3相磁链有问题!
...

意外发现:


Cnvtol,csg,,1.0e-10
这一句如果改成
Cnvtol,csg,,1.0e-6
就会产生很大的计算误差,请看前3行数据

0.00000000E+00  0.75090611E-02  0.74694981E-02  0.69868292E-02  
0.18000000E+00  0.74853233E-02  0.72795956E-02  0.68285772E-02
0.36000000E+00  0.76989636E-02  0.72954208E-02  0.69868292E-02

  0.00000000E+00  0.10571239E-01  0.11220072E-01  0.69630914E-02
  0.18000000E+00 -0.42420261E+00 -0.35522053E+00 -0.28405457E+00
  0.36000000E+00  0.74061973E-02  0.68048394E-02  0.69156158E-02


第二行计算出来的自感竟然变成了负数,这个误差也实在太大了吧!

回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-17 20:43:13 | 显示全部楼层 来自 安徽合肥
本帖最后由 zengxiaodong 于 2015-12-17 23:10 编辑
zengxiaodong 发表于 2015-12-16 18:12
与上楼同样的计算方法,我们改成plane53单元,程序略加修改,可以正确计算出3相自感,但是3相磁链有问题!
...

plane53单元除了用mien和mico作为输出以外,还可以用senergy宏命令计算:

结果几乎相同,磁链也计算不出来。

以工作点计算为例,程序修改如下


原来程序
ALLSEL,ALL
etable,_mien,mien
etable,_mico,mico
ssum
*get,mien_0,ssum,,item,_mien
*get,mico_0,ssum,,item,_mico

改成
ALLSEL,ALL
senergy,0,0
*set,mien_0,S_ENG
senergy,1,0
*set,mico_0,C_ENG



本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有账号?注册

×
回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-17 22:06:59 | 显示全部楼层 来自 安徽合肥
zengxiaodong 发表于 2015-12-17 20:43
plane53单元除了用mien和mico作为输出以外,还可以用serengy宏命令计算:

结果几乎相同,磁链也计算不出 ...

千万不能改成

ALLSEL,ALL
senergy,0,0
senergy,1,0
*set,mien_0,S_ENG
*set,mico_0,C_ENG

因为执行一个宏命令以后,得到磁能,就会把磁共能清零,反之亦然!
回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-22 13:02:11 | 显示全部楼层 来自 上海
在线性的情况下,磁能和磁共能是相等的,但是在非线性的情况下,两者不相等。
回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-22 22:58:37 | 显示全部楼层 来自 安徽芜湖
关于能量摄动法的论文

本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有账号?注册

×
回复 不支持

使用道具 举报

 楼主| 发表于 2015-12-24 08:02:26 | 显示全部楼层 来自 河北唐山
本帖最后由 zengxiaodong 于 2015-12-24 08:03 编辑

计算互感的公式比较复杂,也就是要计算4次磁场,得到每次的磁能,然后才能计算互感数值,具体的公式参见上贴中附件提供的论文。
回复 不支持

使用道具 举报

 楼主| 发表于 2016-1-1 09:13:57 | 显示全部楼层 来自 上海
zengxiaodong 发表于 2015-12-22 13:02
在线性的情况下,磁能和磁共能是相等的,但是在非线性的情况下,两者不相等。 ...

永磁材料除外。
回复 不支持

使用道具 举报

 楼主| 发表于 2016-1-16 19:59:50 | 显示全部楼层 来自 湖南常德
www.ansys.com/Products/Coming-Soon

据说Ansys V17.0不久要推出,我再试一下Plane233单元的线性摄动分析功能,看一下是否有改进?
回复 不支持

使用道具 举报

 楼主| 发表于 2016-1-17 09:51:13 | 显示全部楼层 来自 上海
ANSYS 17.0 新品亮点

我们在开发ANSYS 17.0时有一个愿景:跨越所有物理领域和仿真类别,将用户的工程仿真体验和产品开发结果改善10倍,用户的设计流程性能提升10倍、洞察力提升10倍、生产力提升10倍,从而让用户在明显降低成本的情况下显著加快新产品上市进程。这种创新水平、上市进程、运营效率和产品质量的数量级增长将助力用户遥遥领先其竞争对手。

瞬态电磁场仿真速度提升10倍

ANSYS Maxwell瞬态电磁场求解器引入了划时代的时域分解算法,为用户带来突破性的计算能力和速度。这项技术(目前已经在申请专利)可以将所有时间点分布到多个核、联网计算机和计算集群上,同时求解瞬态时步(不同于传统的顺序求解),最终能够显著提升仿真能力,实现前所未有的仿真速度。
回复 不支持

使用道具 举报

 楼主| 发表于 2016-1-20 22:34:19 | 显示全部楼层 来自 上海
从Ansys V17开始,已经在文档中取消了plane53单元,也取消了lmatrix宏命令!
回复 不支持

使用道具 举报

 楼主| 发表于 2016-1-22 11:54:51 | 显示全部楼层 来自 上海

用V17进行摄动分析求电感的结果与V16.2的没有什么区别,到底问题出在哪里?


本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有账号?注册

×
回复 不支持

使用道具 举报

 楼主| 发表于 2016-1-22 23:12:29 | 显示全部楼层 来自 上海
本帖最后由 zengxiaodong 于 2016-1-23 11:58 编辑

Multiframe restart has the following limitations for a nonlinear static analysis, a nonlinear full transient analysis, or a linear full transient analysis:
  • Material properties or elements cannot be changed during a restart.
  • The factorized matrix cannot be reused (KUSE). A new stiffness matrix and the related .LN22 file is regenerated.
  • The .Rnnn file does not save the EKILL and EALIVE commands. If EKILL or EALIVE commands are required in the restarted session, they must be issued again.
  • The database file (Jobname.DB) saved by the user (SAVE command) is not used by the restart. The Jobname.RDB file, which is a database file saved automatically by the program at the start of the first substep of the first load step, is used by the restart.
  • The .RDB file saves only the database information available at the first substep of the first load step. If other information is input after the first load step and that information is needed for the restart, it must be input again in the restart session. This situation often occurs when parameters are used (APDL); issue the PARSAV command to save the parameters during the initial run, and PARRES restore them in the restart. The situation also occurs when changing element REAL constants values; in this case, reissue the R command during the restart session.
  • A restart cannot occur at the equation solver level (for example, the PCG iteration level). The job can only be restarted at a substep level (either transient or Newton-Raphson loop).
  • Multiframe restart does not support the arc-length method (ARCLEN command).
  • All loading and boundary conditions are stored in the Jobname.LDHI file. Upon restart, removing or deleting solid modeling loading and boundary conditions does not remove these conditions from the finite element model. Loading and boundary conditions must be removed directly from nodes and elements.
  • To terminate a nonlinear analysis "cleanly" on a multitasking operating system, create an abort file named Jobname.ABT in the working directory (or on some case-sensitive systems, jobname.abt). This file should contain the word nonlinear in the first column of the first line. If the program locates this file at the start of an equilibrium iteration, the analysis stops and can be restarted at a later time.
  • Nested *DO loops are not supported for restarts.
  • The first time step of a restarted transient solution using the HHT algorithm (TRNOPT) uses the Newmark algorithm. Subsequent time steps use the HHT algorithm.
  • For the case of distributed memory parallel processing, you must use Distributed ANSYS prior to and during the restart, and the core count must be consistent. See Restarts in Distributed ANSYS in the Parallel Processing Guide for a more detailed description of how to perform restarts in Distributed ANSYS.





回复 不支持

使用道具 举报

 楼主| 发表于 2016-1-23 14:24:07 | 显示全部楼层 来自 上海
本帖最后由 zengxiaodong 于 2016-1-23 14:31 编辑

要进行多架构重启,需要下列文件:

Jobname.RDB文件- 这是ANSYS在第一载荷步的第一次迭代时系统自动保存的数据库文件.这个文件提供了规定了所有初始条件的求解的完整描述.而且不管对于特定工作进行了多 少次重启都一直保持不变.当执行一个工作时.在执行第一次命令之前,你需要输入所有求解必须的信息.包括参数 (APDL),构成,和强制求解设定信息.如果你在执行第一次命令前未指定参数,参数将不会保存到.RDB文件,这样的话,在开始求解前你必须使用命令PARSAV,重启时使用命令PARRES保存参数.如果.RDB文件中保存的信息不足以进行重启,你必须在执行SOLVE命令之前将附加信息输入重启文件.

Jobname.LDHI文件-这是指定工作的加载历史文件,他是一个ASCII码文件,类似LSWRITE命令生成的文件,它存储了每个载荷步的载荷与边界条件.载荷与边界条件是为 FE网格存储的,在被存入文件Jobname.LDHI前就被施加倒实体模型并转换到FE网格.当执行多架构重启时,ANSYS从这个文件读取重启载荷步的载荷与边界条件(类似于LSREAD命令).通常,因为重启的渐变载荷条件,你需要两相邻的载荷步的载荷与边界条件.你不能修改这个文件.因为任何改动都会引发难以预料的的重启情况. 这个文件在每个载荷步末被修改,也可能是执行ANTYPE,,REST,LDSTEP,SUBSTEP,ENDSTEP 命令.对于表格型载荷或边界条件,你应该确认APDL参数表在重启时可用.

Jobname.Rnnn文件 – 这个文件包含单元保存记录,类似于OSAV和.ESAV文件.它包含所有求解命令和一个载荷步的特定子步的状态. 所有.Rnnn文件在收敛载荷步被保存,因此所有单元保存记录是有效的. 如果子步不收敛,这个子步将不会保存.Rnnn文件.或者说,来自前面收敛载荷步的.Rnnn文件被保存了.

它不支持KUSE. 一个新的刚度矩阵及其相关的.TRI文件将被新建.
Rnnn文件不保存EKILL和EALIVE命令. 如果EKILL或EALIVE命令在重启时需要,你必须重新执行这些命令.
RDB文件在第一载荷步的第一子步时仅当数据库信息有效时才保存.如果在第一载荷步后输入其它信息,并且这些信息为重启所需,那么你必须在重启阶段输入这些信息,当使用参数语言(APDL)时,这种情况经常发生.你必须在初始运行时用PARSAV命令保存参数.用PARRES命令在重启中恢复参数. 当你想改变单元实常值时,这种情况也会出现.这时就要在重启期间重执行R命令

在方程求解器层次你不能重启工作,(例如,预条件共轭梯度法)工作只能在子步层次上重启(不管是瞬态还是Newton-Raphson loop).
当使用弧长法时,多架构重启不支持ANTYPE中的ENDSTEP选项.


所有载荷与边界条件都保存在Jobname.LDHI文件中;因此,对于重启,移动或者删除实体模型的载荷与边界条件不会导致边界条件和载荷从有限单元模型上被删除,你必须直接从节点和单元上删除这些条件才有效.

回复 不支持

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|小黑屋|联系我们|仿真互动网 ( 京ICP备15048925号-7 )

GMT+8, 2024-3-29 08:24 , Processed in 0.039059 second(s), 7 queries , Gzip On, MemCache On.

Powered by Discuz! X3.5 Licensed

© 2001-2024 Discuz! Team.

快速回复 返回顶部 返回列表