- 积分
- 9
- 注册时间
- 2003-12-2
- 仿真币
-
- 最后登录
- 1970-1-1
|
楼主 |
发表于 2004-4-29 20:04:25
|
显示全部楼层
来自 山东济南
回复: 【讨论】求救:对流换热系数随材料温度变化的边界条件怎么施加?
以下分别列出LOG文件及菜单操作
/prep7
/title,Steady-state thermal analysis of pipe junction
/units,bin !使用英制单位
et,1,90 !定义热单元
mp,dens,1,.285 !密度
mptemp,,70,200,300,400,500 !建立温度表
mpdata,kxx,1,,8.35/12,8.90/12,9.35/12,9.80/12,10.23/12 !导热系数
mpdata,c,1,,0.133,0.177,0.119,0.122,0.125 !比热
mpdata,hf,2,,426/144,405/144,352/144,275/144,221/144 !接管对流系数
!定义几何模型参数
ri1=1.3 !罐内半径
ro1=1.5 !罐外半径
z1=2 !罐长
ri2=0.4 !接管内半径
ro2=0.5 !接管外半径
z2=2 !接管长
!建立几何模型
cylind,ri1,ro1,,z1,,90 !1/4罐体
wprota,0,-90 !将工作平面旋转到垂直于接管轴线
cylind,ri2,ro2,,z2,-90 !1/4接管
wpstyl,defa !将工作平面恢复到默认状态
vovlap,1,2 !进行OVERLAP布尔操作
/pnum,volu,1 !打开实体编号
/view,,-3,-1,1 !定义显示角度
/type,,4
/title, Volumes used in building pipe/tank junction
vplot !显示实体
vdele,3,4,,1 !删除多余实体
!划分网格
asel,,loc,z,z1 !选择罐上Z=Z1的面
asel,a,loc,y,0 !添加选择罐上Y=0的面
cm,aremote,area !创建名为AREMOTE的面组
/pnum,area,1
/pnum,line,1
/title,lines showing the portion being modeled
aplot
/noerase
lplot
/erase
accat,all !组合罐远端的面及线,为映射划分网
!格作准备
lccat,12,7
lccat,10,5
lesize,20,,,4 !在接管壁厚方向分4等分
lesize,40,,,6 !在接管长度方向分6等分
lesize,6,,,4 !在罐壁厚方向分4等分
allsel !选择EVERYTHING
esize,0.4 !设定默认的单元大小
mshape,0,3d !选择3D映射网格
mshkey,1
save !保存数据文件
vmesh,all !划分网格,产生节点与单元
/pnum,defa
/title, elements in portion being modeled
eplot !显示单元
finish
!加载求解
/solu
antype,static !定义为稳态分析
nropt,auto !设置求解选项为Program-chosen
!Newton-Raphson
tunif,450 !设定初始所有节点温度
csys,1 !变为柱坐标
nsel,s,loc,x,ri1 !选择罐内表面的节点
sf,all,conv,250/144,450 !定义对流边界条件
cmsel,,aremote !选择AREMOTE面组
nsla,,1 !选择属于AREMOTE面组的节点
d,all,temp,450 !定义节点温度
wprota,0,-90 !将工作平面旋转到垂直于接管轴线
cswpla,11,1 !创建局部柱坐标
nsel,s,loc,x,ri2 !选择接管内壁的节点
sf,all,conv,-2,100 !定义对流边界条件????????????????????????????这条命令不懂————————————望解释!
allsel !选择EVERYTHING
/pbc,temp,,1 !显示所有温度约束
/psf,conv,,2 !显示所有对流边界
/title,Boundary conditions
nplot !显示节点
wpstyle,defa !工作平面恢复默认状态
csys,0 !变为直角坐标
autots,on !打开自动步厂长
nsubst,50 !设定子步数量
kbc,0 !设定为阶越
outpr,nsol,last !设置输出
solve !进行求解
finish
!进入后处理
/post1
/title,Temperature contrours at pipe/tank junction
plnsol,temp !显示温度彩色云图
finish
/exit,all |
评分
-
1
查看全部评分
-
|