- 积分
- 0
- 注册时间
- 2003-5-10
- 仿真币
-
- 最后登录
- 1970-1-1
|
发表于 2005-6-19 09:04:59
|
显示全部楼层
来自 北京
Re:一个k系列网壳计算程序
建摸部分与《ansys7。0分析实例与工程应用》ex13.dat一致
ex13.dat:
!第13章 用APDL实现空间网壳结构参数化建模
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》,机械工业出版社(2004年)
FINISH ! 退出以前的处理模块
/Clear ! 清除内存中的所有数据
/Prep7 ! 进入前处理模块PREP7
!(1) 定义基本几何参数! 初始化设计变量参数
R=20000 ! 给定默认半径值20米
Kn=8 ! 默认网壳类型K8
Pi=3.14159 ! 圆周率值
Span=R*1.5 ! 默认跨度1.5倍的半径
Nx=6 ! 默认环向圈数6圈
!(2) 用户界面设计,输入基本几何参数
multipro,'start',4
*cset,1,3,R,'Curvature Radius R= (mm)',20000
*cset,4,6,Kn,'Cymmytric Area Number =',8
*cset,7,9,Span,'Span <= 2R Span=(mm)',30000
*cset,10,12,Nx,'Node Circle Number Nx =',6
*cset,61,62,'Please input geometry parameters of the shell.'
multipro,'end'
!(3) 计算节点坐标位置,并定义节点
DPha=Atn(Span/2/Sqrt(R*R-Span*Span/4))/Nx
N,1,0,R,0 ! 定义1号节点的位置坐标为(0,R,0)
*do,i,1,Nx ! 半径方向的节点循环
*do,j,1,Kn*i ! 环向的节点循环
x=R*sin(i*DPha)*cos((j-1)/i*2*Pi/Kn)
y=R*cos(i*DPha)
z=R*sin(i*DPha)*sin((j-1)/i*2*Pi/Kn)
N,1+Kn*(i-1)*i/2+j,x,y,z ! 依次计算并定义节点的编号和位置
*enddo
*enddo
/Pnum,node,1 ! 标注节点的号码
Nplot ! 图中不显示节点号码
!(4) 定义单元连接
ET,1,Link8 ! 定义第1类单元类型为三维杆单元Link8
*DO,i,1,Kn ! 对各对称区循环
E,1,1+i ! 定义中心处径向杆单元
*ENDDO
! 环向的单元连接
*DO,j,1,Nx ! 从里向外对圈数循环
*DO,i,1,Kn*j-1 ! 对整个一圈上的杆循环
E,1+Kn*(j-1)*j/2+i,1+Kn*(j-1)*j/2+i+1
*ENDDO
E,1+Kn*(j-1)*j/2+1,1+Kn*(j-1)*j/2+Kn*j !第1个节点和最后一个节点的连杆
*ENDDO
! 径向的单元连接
*Do,j,1,Nx-1 ! 从里圈第2圈开始向最外圈循环
*Do,k,1,Kn ! 对各个对称区循环
*Do,i,1,j+1 ! 对每个对称区内的杆循环
*If,i,eq,j+1,then ! 判断是否是当前对称区内的最后一根杆
*If,k,eq,Kn,Then ! 判断是否是最后一个对称区
E,1+Kn*(j-1)*j/2+1,1+Kn*(j+1)*j/2+(k-1)*(j+1)+i ! 第1个节点和最后一个节点的连杆
*else
E,1+Kn*(j-1)*j/2+(k-1)*j+i,1+Kn*(j+1)*j/2+(k-1)*(j+1)+I !一般区内的最后一根连杆
*Endif
*Else
E,1+Kn*(j-1)*j/2+(k-1)*j+i,1+Kn*(j+1)*j/2+(k-1)*(j+1)+I ! 一般正向连杆
*EndIf
*Enddo
*Do,i,1,j
E,1+Kn*(j-1)*j/2+(k-1)*j+i,1+Kn*(j+1)*j/2+(k-1)*(j+1)+i+1 ! 一般负向连杆
*Enddo
*Enddo
*Enddo
!(5) 定义杆件截面性质和材料特性
multipro,'start',3
*cset,1,3,SA,'Section Area (mm^2), SA =',10
*cset,4,6,Elas,'Elasticity (GPa), Elas =',210
*cset,7,9,Passion,'Passion Ratio, Passion =',0.3
*cset,61,62,'Input Section & Material Property:'
multipro,'end'
Elas=Elas*1000
R,1,SA ! 定义第1类单元的截面积
MP,EX,1, Elas*1E9 ! 定义第1类材料的弹性模量EX
MP,PRXY,1,passion ! 定义第1类材料的泊松比PRXY
!(6) 定义边界约束和节点载荷
multipro,'start',1
*cset,1,3,P,'Loads(N)',200
*cset,61,62,'Please input loads value:'
multipro,'end'
*Do,i,1,1+Kn*(Nx-1)*Nx/2+Kn*Nx
*If,i,lt,1+Kn*(Nx-1)*Nx/2+1,then ! 非边界节点
F,i,fy,-P ! 给中间节点定义向下的节点载荷
*Else
D,i,all,0 ! 给最外层节点定义边界约束
*Endif
*Enddo
FINISH
!(7) 进入求解模块求解
/Solu
Solve ! 开始静力分析的求解
FINISH
!(8) 进入后处理模块POST1,输出计算结果
/Post1
multipro,'start',1
*cset,1,3,Disp1,'Print Diplacement Yes(1)/No(0)?',1 ! 选择输出位移值
*cset,4,6,Disp2,'Plot Deformation Yes(1)/No(0)?',1 ! 选择输出变形图
*cset,61,62,'Result Display Mode Option:'
multipro,'end'
*If,Disp1,eq,1,then ! 列表显示结点位移值
Pldisp
*Endif
*If,Disp2,eq,1,then ! 图形显示变形图
Pldisp,2
*Endif
FINISH ! 退出后处理模块 |
|