各位,我在下面附加的程序是在网上的一个比较著名和经典的例子,想必大家都见识过的。我在做一个混凝土重力坝的仿真计算,都是参照这个例子进行的,温度场的计算没有什么问题,但在进行应力场计算的时候,我发现一个问题,大家可以以下面的命令流进行检验。我的问题是:在后处理检查结果时,如果我在计算完成后,不退出ansys直接察看结果,则没什么问题;但是我如果save everything ,退出ansys,然后再打开ansys 察看的时候,就会发现,模型的变形会非常的夸张!大家有没有谁遇到过,或谁能告诉我为什么?怎么解决?还是我的操作有问题?
!100*80*10基岩上浇筑混凝土50*40*10,每三天浇筑1米高(第一天浇完,剩下两天窝工),
!共用一个月时间,分为十层(layer)浇筑,模型、条件均为假设
!建模
/filename,test !命名文件
/PREP7 !进入前处理
BLOCK,,50,,10,,40, !生成体(上层混凝土)(当前工作平面)(
BLOCK,-25,75,-10,0,-20,60 !生成体(基岩)
ET,1,70 !定义单元类型
LSEL,S,,,9,12,1 !选择线(9-12,以1为单位递增)
LESIZE,ALL,,,10 !划分10份
LSEL,S,,,21,24,1
LESIZE,ALL,,,20
LSEL,S,,,2,4,2 !选择线(2-4,以2为单位递增)
LSEL,A,,,5,7,2 !A为S的附加选择
LESIZE,ALL,,,10
LSEL,S,,,14,16,2
LSEL,A,,,17,19,2
LESIZE,ALL,,,20
LSEL,S,,,1,3,2
LSEL,A,,,6,8,2
LESIZE,ALL,,,10
LSEL,S,,,13,15,2
LSEL,A,,,18,20,2
LESIZE,ALL,,,5
allsel !全选所有实体
MP,DENS,1,2400.0 !定义材料1 密度
MP,KXX ,1,300.89 !热传导率
MP,C,1,0.94500 !比热容
MAT,1
VMESH,1 !体1内生成结点和单元
MP,DENS,2,2600.0 !定义材料2
MP,KXX ,2,300.89
MP,C,2,0.94500
MAT,2
VMESH,2
nummrg,all !合并相同的定义
!热分析
/SOLU !进入求解
NROPT,FULL !Specifies the Newton-Raphson options in full !transient analysis
ESEL,S,MAT,,2 !选择材料2的单元
NSLE,S !选择结点
IC,all,TEMP,16.4, !加基岩初温16.4
ASEL,S,,,7,9,1 !选择面
ASEL,A,,,11,12,1
NSLA,S,1 !1-选择所有与上述面相连的结点;0-只选择上述面 !相连的内部的结点
SF,all,HFLUX,0 !加基岩绝热边界条件,HFLUX为heat flux(热流量)
NSEL,S,LOC,Y,-0.1,0.1 !按坐标选择结点
ASEL,S,,,3 !选择面
NSLA,U,1 !从面上选点,U为否
SF,ALL,CONV,2016,20 !加基岩第三边界条件(和空气接触面);
!CONV(对流)
!加初始条件
ALLSEL,ALL
ESEL,U,MAT,,2
NSLE,S
EKILL,ALL !KILL 混凝土
IC,all,TEMP,35, !混凝土浇筑时温度为35度
ANTYPE,TRANSIENT,new !分析类型
!日子的流逝
*DO,LAYER,1,10,1
!激活第N层单元
ALLSEL,ALL
NSEL,S,LOC,Y,(LAYER-1),LAYER !第一层从Y=0~1米,第二层从Y=1~2米,...
ESLN,S,1 !选择与点相连的面(面上所有点都已经被选中)
EALIVE,ALL !激活
*DO,DAY,LAYER*3-2,LAYER*3,1 !每三天浇筑一层
ALLSEL,ALL
ASEL,S,,,1,2,1
ASEL,A,,,5,6,1
NSLA,S,1
NSEL,R,LOC,Y,0,LAYER
NSEL,A,LOC,Y,LAYER-0.1,LAYER+0.1
SF,ALL,CONV,2016,20 !加混凝土第三类对流边界条件
*DO,LOOP,1,LAYER,1
ALLSEL,ALL
NSEL,R,LOC,Y,LOOP-1,LOOP
ESLN,S,1
TDAY=DAY-(LOOP-1)*3 !已经完工的天数
HE00=47880*(TDAY/(0.862+TDAY)-(TDAY-1)/(0.862+TDAY-1))
BFE,ALL,HGEN,,HE00 !加水化热
*ENDDO
!计算设置
ALLSEL
TRNOPT,FULL !瞬态分析选项
LUMPM,0 !块矩阵的计算
TIME,DAY !时间步长
AUTOTS,0 !自动调整时间或荷载步长
DELTIM,1,,,1 !确定荷载步的时间步长
KBC,0 !荷载步递加方式
TSRES,ERASE !定义关键时间点
OUTRES,ALL,ALL, !结果文件保存内容
SOLVE !求解
*ENDDO
ESEL,S,MAT,,1
NSLE,S,
SFEDELE,ALL,ALL,CONV !删对流边界条件
SFDELE,ALL,CONV
*ENDDO
FINISH
!结构分析
/PREP7
ET,1,SOLID65 !变热单元为结构单元
*DIM,EXX,ARRAY,30 !考虑变化的EX
EXX(1)=0.325E10,0.57778E10,0.78E10,0.94545E10,0.10833E11,0.12E11,0.13E11,0.13867E11,0.14625E11,0.15294E11, 0.15889E11, 0.1642E11 ,0.169E11, 0.17333E11, 0.17727E11, 0.18087E11,0.18417E11,0.1872E11
EXX(19)=0.190E11, 0.19259E11, 0.195E11, 0.19724E11, 0.19933E11, 0.20129E11,0.20312E11, 0.20485E11, 0.20647E11, 0.208E11, 0.20944E11, 0.21081E11
*DO,I,1,30,1 !定义材料,混凝土浇筑完每过一天变一种材料
MP,DENS,I,2400
MP,EX,I,EXX(I)
MP,PRXY,I,0.167 !定义泊松比
MP,ALPX,I,0.9E-5 !定义热膨胀系数
MP,REFT,I,15 !定义参考温度
*ENDDO
MP,DENS,31,2600 !定义基岩材料
MP,EX,31,0.20800E+11
MP,PRXY,31,0.167
MP,ALPX,31,0.9E-5
ESEL,S,MAT,,2
MPCHG,31,ALL, !!变热材料为结构材料
ALLSEL
/SOLU
NROPT,FULL !Specifies the Newton-Raphson options in a !full transient analysis
NLGEOM,ON !Includes large-deflection effects !in a static or full transient analysis.
NSLA,S,,,7,9,1
NSLA,A,,,11,12,1
D,all,ALL !加基岩约束
!KILL THE CONCRETE ELEMENT
ESEL,U,MAT,,1
NSLE,S
EKILL,ALL !KILL 混凝土
*DO,DAY,1,30,1 !随时间改变,变换材料
*DO,LAYER,1,10
*IF,DAY,GT,LAYER*3-3,THEN
NSEL,S,LOC,Y,LAYER-1,LAYER
ESLN,S,1
EALIVE,ALL !ACTIVE NEXT LAYER
MPCHG,DAY-(LAYER-1)*3,ALL, !CHANG MAT
ALLSEL,ALL
*ENDIF
*ENDDO
ALLSEL,ALL
ACEL,0,0,-9.8, !GRAVITY LOAD
LDREAD,TEMP,,,DAY, ,'TEST','rth',' ' !TEMP LOAD Reads results from the results file and applies them as loads.
CNVTOL,F, ,0.2,2,200, !Sets convergence values for nonlinear analyses.
TIME,DAY
AUTOTS,0
DELTIM,1, , ,1
KBC,0
TSRES,ERASE !Defines an array of keytimes at which the time-stepping strategy changes
OUTRES,ALL,ALL,
SOLVE
*ENDDO |