【讨论】优化设计中设计参数在整个程序中迭代方式！！

lq_liuqiang

我建立优化程序时，模型建立成功，但是在循环优化的过程中，常常出现结构模型错位，也就是不能在优化过程中形成正确的模型！这样就不能进行优化！常常出现错误的提式：不能找到某个点、面、体等信息！不能创建体等！1
  
在优化过程中每一次循环中设计参数的变化，整个程序是不是也就重新从头开始，还是从有这个参数的位置开始变化。（简单模型很好处理，但是在复杂的模型中就会出现！）
  
还有在程序的变化中能不能让结构的关键点、面和体的标号不会变化！

simulationer

同感

lq_liuqiang

期待有人能够发表一些关于优化的体会,还是没有人发表自己的看法!
这里是论坛可以说说自己的关于这个的见解!

sunhaolan

lq_liuqiang wrote:
我建立优化程序时，模型建立成功，但是在循环优化的过程中，常常出现结构模型错位，也就是不能在优化过程中形成正确的模型！这样就不能进行优化！常常出现错误的提式：不能找到某个点、面、体等信息！不能创建体等！1
  
在优化过程中每一次循环中设计参数的变化，整个程序是不是也就重新从头开始，还是从有这个参数的位置开始变化。（简单模型很好处理，但是在复杂的模型中就会出现！）
  
还有在程序的变化中能不能让结构的关键点、面和体的标号不会变化！

  
跌代从建模部分重新开始，好像没有办法让标号不变。
所以点、面、体，最好用坐标选取，不要用标号选取。

lq_liuqiang

谢谢sunhaolan 帮助！！
  
迭代从建模重新开始，就是说每一个变量不论是值改变的和没有改变的都重新进行代入到模型从／PREP7开始执行了！！
  
如果每一次的迭代各体面线的标号改变的话那就最初状态变量的位值也就没有按照设计者的要求位置约束，在建模中用到GLUE  ADD  VDD等命令时就不能找到这个体或者面了，这样迭代就会出错误！！！
  
”点、面、体，最好用坐标选取，不要用标号选取“请问大侠我没有用过，能否给个具体的讲解或者例子！！！谢谢你的帮助！！！！

sunhaolan

sorry，早上刚起床没睡醒，就发贴了。:I
以我曾做过的优化分析来看，如果没有添加、删减几何模型元素的操作，他们的编号应该是不变的。当然如果你进行了布尔等操作，要注意他编号的变化。在以后命令流编辑中要用新产生的编号。
但是单元和节点的编号肯定会不同。
几何元素用单元选取也可以，但要选取多次，比较麻烦。
如：
vsel,s,loc,x,0,10 !选取x坐标从0到10的体元素。

lq_liuqiang

谢谢你这么快就回答我的问题!!我现在做的就是需要多次的布尔运算！！
如果用坐标选取元素，用二个体减去一个体能用坐标选取操作吗？？

lq_liuqiang

这个是我的程序你可以看看！
运行时出现错误，可能是我用GLUE这个命令出现错误！！
   
*SET,w1,1865  !工作台长度X
*SET,w2,1200  !工作台宽度Y
*SET,w3,1020  !工作台中心安装长X
*SET,w4,810   !工作台中心安装宽
*SET,w5,1610  !工作台二各立柱的距离X
w6=800        !工作台开口宽X
w7=1400       !工作台上小板的长度X
*SET,w8,850   !工作台立柱的距离Y
w9=470
*SET,h0,30  !工作台底板厚度
*SET,h1,40  !工作台Y向力板的厚度
*SET,h2,16  !工作台X两边力板的厚度
*SET,h3,40  !工作台中心力板的厚度
*SET,h4,85  !工作台下螺母左边板的厚度
*SET,h5,25  !工作台立柱边支板的的厚度
*SET,h6,60  !工作台螺母厚支板的厚度
  
*SET,k1,15  !工作台边距上下板外延边的距离
*SET,k2,250 !工作台底板X向距螺母左支板的距离
*SET,k3,250  !工作台螺母后面力板距前侧板的距离
  
*SET,g1,750 !工作台总高
*SET,g2,50  !工作台上板厚度
*SET,g3,20  !工作台上小板的厚度
*SET,g4,60  !工作台与螺母接触板的厚度
*SET,g5,280 !工作台底面距离螺母接触板上面的距离
*SET,g6,150 !工作台开口处距上板下面的距离
   
  
r1=100  !工作台开口处的圆角半径  
r2=75   !工作台处立柱孔
r3=65   !立柱半径
r4=265  !上横梁中心圆孔半径
r5=400  !上横梁法兰盘外径
r6=100  !螺母外径
r7=20  !工
  
zg1=4510 !整机高度
zg2=600  !活动横梁的高度
zg3=1900  !工作台和活动横梁的距离
zg4=560  !活动横梁和上横梁的距离
  
/prep7
et,1,solid95
mp,ex,1,1.96e5
mp,prxy,1,0.3
boptn,numb,off
csys,wp  
!建立底板h0=30  
block,0,w1/2,0,w2/2,0,h0
  
kwpave,5   !建立前面板h1=40
block,0,w1/2-h2-k1,k1,h1+k1,0,g1-h0-g2  
  
kwpave,6   !建立两边的侧板h2=16
block,-k1,-k1-h2,k1,w2/2,0,g1-g2-h0  
!建立实体挖去螺母空处
block,-k1,-w1/2+w3/2+h3,k1,w2/2-w9/2,0,g5-h0   
FLST,2,2,6,ORDE,2   
FITEM,2,2   
FITEM,2,3   
VSBV,P51X,       4   
  
kwpave,33 !建立中间支板h3=40   
block,0,-h3,0,(w2/2-h1-k1),0,g1-g2-h0   
kwpave,6
block,-k1,-w1/2+w3/2+h3,k1,w2/2-w9/2,0,g5-h0
block,0,-w1/2+w3/2+h3,0,w2/2-w9/2-h6,0,g5-g4-h0
  
vsbv,3,4
  
  !建立螺母下的的拉力板h4=85
block,-k2,-h4-k2,k1,k3+h1+k1,0,g5-h0-g4  
!建立立柱旁的支板h5=25
kwpave,48   
block,0,(w1/2-w3/2-k1-h2-h3),-(h6-h5),-h6,0,g1-g5-g2
!挖空中间  
  
kwpave,5   
block,0,w6/2,k1,h1+k1,0,g1-h0-g2-g6  
     
AFILLT,50,54,r1,!建立圆角R1=100
VSBA,       8,      56   
VDELE,      9, , ,1
   
VSBV,       5,      10
!建立上板g2=50 !建立上小板g3=20  
kwpave,2   
block,0,w1/2,,w2/2,g1-g2,g1
block,0,w7/2,,w2/2,g1,g1+g3
!建立中间空口   
kwpave,8
block,-20,w3/2,50,-(w4/2),g5,g1+g3   
FLST,2,2,6,ORDE,2   
FITEM,2,5   
FITEM,2,9   
VSBV,P51X,  10  
!建立中间四个四方立柱
kwpave,71   
block,0,w3/2-w6/2,0,w2/2-w4/2-k1-h1,0,g1-h0-g2   
  
!建立圆柱孔r2=75
kwpave,8
CYL4,w5/2,-w8/2,r2, , , ,g1
FLST,2,2,6,ORDE,2   
FITEM,2,11   
FITEM,2,7   
VSBV,P51X,       9   
  
vglue,all
  
MSHAPE,1,3D  
MSHKEY,0
SMRT,10
VMESH,all
ALLSEL,ALL
  
/solu
   
FLST,2,9,5,ORDE,9   
FITEM,2,5   
FITEM,2,12   
FITEM,2,16   
FITEM,2,50   
FITEM,2,76   
FITEM,2,77  
FITEM,2,99  
FITEM,2,114  
FITEM,2,116  
DA,P51X,SYMM
   
DA,1,ALL,0   
SFA,81,1,PRES,3.689   
  
SFA,127,1,PRES,15.6
  
SFTRAN
solve   
FINISH   
   
/POST1   
SET,LAST
/GRAPHICS,FULL   
ETABLE,,VOLU     !将每个单元的体积放入单元表
SSUM             !将单元表格内数据求和
*GET,tvolu,SSUM,,ITEM,volu  !单元表中体积和写入标量tvolu中
  
/GRAPHICS,FULL  !此命令为显示时不是应力的平均值
  
asel,s,,,56    !选择下横梁圆角面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm1,SORT,,MAX  
ALLSEL,ALL  
  
asel,s,,,106    !选择下横梁前面板后面上结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm2,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,108    !选择下横梁前侧面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm3,SORT,,MAX  
ALLSEL,ALL  
  
asel,s,,,74    !选择下横梁侧板立柱旁面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm4,SORT,,MAX  
ALLSEL,ALL  
  
asel,s,,,81    !选择下横梁上板面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm5,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,109    !选择下横梁上大阪面下底面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm6,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,113    !选择下横梁上大阪面后面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm7,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,126    !选择立柱螺母接触板上面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm8,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,127    !选择立柱螺母接触板下面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm9,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,101    !选择下横梁前册板立柱旁的面的结点等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm10,SORT,,MAX  
ALLSEL,ALL
finish
  
/opt
opanl,xia,lgw     
opvar,h1,dv,30,50,1  !工作台Y向力板的厚度
opvar,h2,dv,15,20,1  !工作台X两边力板的厚度
opvar,h3,dv,20,50,1  !工作台中心力板的厚度
opvar,h5,dv,20,40,1  !工作台立柱边支板的的厚度
opvar,g2,dv,30,60,1  !工作台上板厚度
opvar,g3,dv,10,30,1  !工作台上小板的厚度
opvar,h4,dv,50,100,1  !工作台下螺母左边板的厚度
opvar,g4,dv,40,70,1  !工作台与螺母接触板的厚度
opvar,r1,dv,100,200  !工作台开口处的圆角半径  
  
!定义状态变量
opvar,stressm1,sv,50,65,   
opvar,stressm2,sv,50,65,   
opvar,stressm3,sv,50,65,  
opvar,stressm4,sv,50,65,  
opvar,stressm5,sv,50,65,  
opvar,stressm6,sv,50,65,  
opvar,stressm7,sv,50,65,  
opvar,stressm8,sv,50,65,  
opvar,stressm9,sv,50,65,  
opvar,stressm10,sv,50,65,  
  
OPSAVE,xia2,opt0     !存储数据
  
opvar,tvolu,OBJ,,,1000
  
opkeep,on    !要确保了最优化设计序列时的数据库和结果文件
optype,subp  !子问题近似法也就是零阶方法。
opexe    !运行优化
  
fini

sunhaolan

大概看了一下你的命令流。
这个命令流应该是菜单方式转过来的？感觉你改的还是不干净。
里面很多菜单方式鼠标点选的地方，这是优化循环所忌讳的，你把它都换成直接用几何元素的编号，再试试。

lq_liuqiang

老大这是已经完全修改过的了,用鼠标点取难道不能在优化中运行吗??
我有的程序就是用鼠标点取后就能运算的!!!!
  
你能告诉我不用鼠标点取,用两个(或多个)体减去一个体的方法吗!?我不想先用一个减去后,被减体再生成一次!
如这几个命令
FLST,2,2,6,ORDE,2  
FITEM,2,11  
FITEM,2,7  
VSBV,P51X, 9  
用一条语句!!!

sunhaolan

lq_liuqiang wrote:
老大这是已经完全修改过的了,用鼠标点取难道不能在优化中运行吗??
我有的程序就是用鼠标点取后就能运算的!!!!
  
你能告诉我不用鼠标点取,用两个(或多个)体减去一个体的方法吗!?我不想先用一个减去后,被减体再生成一次!
如这几个命令
FLST,2,2,6,ORDE,2  
FITEM,2,11  
FITEM,2,7  
VSBV,P51X, 9  
用一条语句!!!

  
ansys优化手册中明确指出要避免鼠标点取的操作。
see ansys help, Advanced Analysis Techniques Guide
1.4.1.1. Build the Model Parametrically
Caution
If you build your model interactively (through the GUI), you will encounter many situations where data can be input through graphical picking (such as when defining geometric entities). However, some picking operations do not allow parametric input. Therefore, you should avoid these picking operations when defining items that will be used as DVs, SVs, or an objective function. Instead, use menu options that allow direct input of parameters.
  
对于vsbv
你可以把一次减去或被减的多个体做成一个component。
比如用体1，2减去3
vsel,,,,1,2
cm,sub,volu
vsbv,sub,3

sunhaolan

ps：不要叫我“老大”！！！！:!(:!(:!(:!(:!(:!(

lq_liuqiang

  
谢谢你的再次帮助！！我试试你告诉我的方法了！
你不喜欢我教你老大那我就叫你高手吧！！
真心的感谢你！！我就没有想到用cm,sub,volu这个命令！！！

lq_liuqiang

说明一下其实及时用鼠标点取也可以进行优化循环设计的！我要说明的意思是想我这样的对于命令很是不了解的人，在GUI中建立的模型简单修改一下把一些不必要的显示模型的命令去掉就可以的！
  
上面的例子我修改了下,主要是这两条语句我修改了一下,起他就没有变！！
“
kwpave,6
block,-k1,-w1/2+w3/2+h3,k1,w2/2-w9/2,0,g5-h0
block,0,-w1/2+w3/2+h3,0,w2/2-w9/2-h6,0,g5-g4-h0
allsel,all
vsbv,3,4
”
  
下面是我完整的例子：
  
*SET,w1,1865  !工作台长度X
*SET,w2,1200  !工作台宽度Y
*SET,w3,1020  !工作台中心安装长X
*SET,w4,810   !工作台中心安装宽
*SET,w5,1610  !工作台二各立柱的距离X
w6=800        !工作台开口宽X
w7=1400       !工作台上小板的长度X
*SET,w8,850   !工作台立柱的距离Y
  
*SET,h0,30  !工作台底板厚度
*SET,h1,40  !工作台Y向力板的厚度
*SET,h2,16  !工作台X两边力板的厚度
*SET,h3,40  !工作台中心力板的厚度
*SET,h4,85  !工作台下螺母左边板的厚度
*SET,h5,25  !工作台立柱边支板的的厚度
*SET,h6,60  !工作台螺母厚支板的厚度
  
*SET,k1,15  !工作台边距上下板外延边的距离
*SET,k2,250 !工作台底板X向距螺母左支板的距离
*SET,k3,250  !工作台螺母后面力板距前侧板的距离
  
*SET,g1,750 !工作台总高
*SET,g2,50  !工作台上板厚度
*SET,g3,20  !工作台上小板的厚度
*SET,g4,60  !工作台与螺母接触板的厚度
*SET,g5,280 !工作台底面距离螺母接触板上面的距离
*SET,g6,150 !工作台开口处距上板下面的距离
  r1=100  !工作台开口处的圆角半径  
r2=75   !工作台处立柱孔
r3=65   !立柱半径
r4=265  !上横梁中心圆孔半径
r5=400  !上横梁法兰盘外径
r6=100  !螺母外径
r7=20  !工
zg1=4510 !整机高度
zg2=600  !活动横梁的高度
zg3=1900  !工作台和活动横梁的距离
zg4=560  !活动横梁和上横梁的距离
  
/prep7
et,1,solid95
mp,ex,1,1.96e5
mp,prxy,1,0.3
boptn,numb,off
csys,wp  
!建立底板h0=30  
block,0,w1/2,0,w2/2,0,h0
  
kwpave,5   !建立前面板h1=40
block,0,w1/2-h2-k1,k1,h1+k1,0,g1-h0-g2  
  
kwpave,6   !建立两边的侧板h2=16
block,-k1,-k1-h2,k1,w2/2,0,g1-g2-h0  
!建立实体挖去螺母空处
block,-k1,-w1/2+w3/2+h3,k1,h1+k3+g4+k1,0,g5-h0   
FLST,2,2,6,ORDE,2   
FITEM,2,2   
FITEM,2,3   
VSBV,P51X,       4   
  
kwpave,33 !建立中间支板h3=40   
block,0,-h3,0,(w2/2-h1-k1),0,g1-g2-h0   
  
kwpave,30 !建立螺母接触的厚板g4=60   
block,0,-(w1/2-w3/2-h3-k1),0,h1+k3+h6,0,-g4  
  
kwpave,27   !建立螺母旁的力板h6=60
block,0,-(w1/2-w3/2-h3-k1),0,-h6,0,g5-g4-h0
  
kwpave,6  !建立螺母下的的拉力板h4=85
block,-k2,-h4-k2,k1,k3+h1+k1,0,g5-h0-g4  
!建立立柱旁的支板h5=25
kwpave,48   
block,0,(w1/2-w3/2-k1-h2-h3),-(h6-h5),-h6,0,g1-g5-g2
!挖空中间  
  
kwpave,5   
block,0,w6/2,k1,h1+k1,0,g1-h0-g2-g6  
     
AFILLT,54,58,r1,!建立圆角R1=100
VSBA,       9,      60   
VDELE,      10, , ,1
   
VSBV,       5,      11
!建立上板g2=50 !建立上小板g3=20  
kwpave,2   
block,0,w1/2,,w2/2,g1-g2,g1
block,0,w7/2,,w2/2,g1,g1+g3
!建立中间空口   
kwpave,8
block,-20,w3/2,50,-(w4/2),g5,g1+g3   
FLST,2,2,6,ORDE,2   
FITEM,2,5   
FITEM,2,10   
VSBV,P51X,      11   
!建立中间四个四方立柱
kwpave,75   
block,0,w3/2-w6/2,0,w2/2-w4/2-k1-h1,0,g1-h0-g2   
  
!建立圆柱孔r2=75
kwpave,8
CYL4,w5/2,-w8/2,r2, , , ,g1
FLST,2,2,6,ORDE,2   
FITEM,2,3   
FITEM,2,12   
VSBV,P51X,       10   
  
vglue,all
  
MSHAPE,1,3D  
MSHKEY,0
SMRT,10
VMESH,all
ALLSEL,ALL
  
/solu
   
FLST,2,9,5,ORDE,9   
FITEM,2,5   
FITEM,2,12   
FITEM,2,16   
FITEM,2,54   
FITEM,2,80   
FITEM,2,81  
FITEM,2,113  
FITEM,2,135  
FITEM,2,137  
DA,P51X,SYMM
   
DA,1,ALL,0   
SFA,85,1,PRES,3.689   
  
SFA,129,1,PRES,15.6
  
SFTRAN
solve   
FINISH   
   
/POST1   
SET,LAST
/GRAPHICS,FULL   
ETABLE,,VOLU     !将每个单元的体积放入单元表
SSUM             !将单元表格内数据求和
*GET,tvolu,SSUM,,ITEM,volu  !单元表中体积和写入标量tvolu中
  
/GRAPHICS,FULL  !此命令为显示时不是应力的平均值
  
asel,s,,,60    !选择下横梁圆角面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm1,SORT,,MAX  
ALLSEL,ALL  
  
asel,s,,,120    !选择下横梁前面板后面上结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm2,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,122    !选择下横梁前侧面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm3,SORT,,MAX  
ALLSEL,ALL  
  
asel,s,,,97    !选择下横梁侧板立柱旁面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm4,SORT,,MAX  
ALLSEL,ALL  
  
asel,s,,,85    !选择下横梁上板面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm5,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,130    !选择下横梁上大阪面下底面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm6,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,134    !选择下横梁上大阪面后面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm7,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,128    !选择立柱螺母接触板上面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm8,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,129    !选择立柱螺母接触板下面结点的等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm9,SORT,,MAX  
ALLSEL,ALL
  
asel,s,,,115    !选择下横梁前册板立柱旁的面的结点等效应力的最大值
nsla,,1  
nsort,s,eqv
*GET,stressm10,SORT,,MAX  
ALLSEL,ALL
finish
  
/opt
opanl,xia,lgw     ! 此文件的内容应于读入的文件的内容一样，且此文件必须存在
!xiahengliang
opvar,h1,dv,30,50,1  !工作台Y向力板的厚度
opvar,h2,dv,15,20,1  !工作台X两边力板的厚度
opvar,h3,dv,20,50,1  !工作台中心力板的厚度
opvar,h4,dv,50,100,1  !工作台下螺母左边板的厚度
opvar,h5,dv,20,40,1  !工作台立柱边支板的的厚度
opvar,h6,dv,40,70,1  !工作台螺母厚支板的厚度
opvar,g2,dv,30,60,1  !工作台上板厚度
opvar,g3,dv,10,30,1  !工作台上小板的厚度
  
opvar,r1,dv,100,200  !工作台开口处的圆角半径  
  
!定义状态变量
opvar,stressm1,sv,50,65,   
opvar,stressm2,sv,50,65,   
opvar,stressm3,sv,50,65,  
opvar,stressm4,sv,50,65,  
opvar,stressm5,sv,50,65,  
opvar,stressm6,sv,50,65,  
opvar,stressm7,sv,50,65,  
opvar,stressm8,sv,50,65,  
opvar,stressm9,sv,50,65,  
opvar,stressm10,sv,50,65,  
  
OPSAVE,xia2,opt0     !存储数据
!定义目标函数次函数  目标函数的公差默认的是当前tvolu的值乘0.01，此值过大
opvar,tvolu,OBJ,,,1000
  
opkeep,on    !要确保了最优化设计序列时的数据库和结果文件
optype,subp  !子问题近似法也就是零阶方法。
opexe    !运行优化
fini

lq_donger

将这个程序不使用鼠标点击的痕迹再次给出！！望大家指正！
  
w1=1865  !
w2=1200  !
w3=1020  !
w4=810   !
w5=1610  !X
w6=800   !
w7=1400  !X
w8=850   !
w9=470
h0=30  !
h1=40  !
h2=16  !
h3=40  !
h4=85  !
h5=25  !
h6=60  !
k1=15  !
k2=250 !
  
g1=750 !
g2=50  !
g3=20  !
g4=60  !
g5=280 !
g6=150 !
r1=200  !  
r2=75   !
r3=70   !
r4=265  !
r5=400  !
r6=100  !
r7=20  !工
  
zg1=4510 !
zg2=600  !
zg3=1900  !
zg4=560  !
  
/prep7
et,1,solid95
mp,ex,1,1.96e5
mp,prxy,1,0.3
  
boptn,numb,off
csys,wp  
  
block,0,w1/2,0,w2/2,0,h0
  
kwpave,5   !
block,0,w1/2-h2-k1,k1,h1+k1,0,g1-h0-g2  
  
kwpave,5
block,w1/2-k1-h2,w1/2-k1,k1,w2/2,0,g1-g2-h0
  
vsel,s,loc,z,0,g1-h0-g2
cm,luom,volu
allsel,all
  
block,w3/2+h3,w1/2-k1,k1,w2/2-w9/2,0,g5-h0
  
vsel,s,loc,z,0,g5-h0
cm,luom1,volu
allsel,all
VSBV,luom,luom1  
  
bloc,w3/2,w3/2+h3,k1+h1,w2/2,0,g1-g2-h0
   
block,w3/2+h3,w1/2-k1,k1,w2/2-w9/2, g5-h0-g4,g5-h0
  
block,w3/2+h3,w1/2-k1,w2/2-w9/2-h6,w2/2-w9/2,0,g5-h0-g4
  
kwpave,6  !
block,-k2,-h4-k2,k1,w2/2-w9/2-h6,0,g5-h0-g4  
  
kwpave,5
block,w3/2+h3,w1/2-k1-h2,w2/2-w9/2-h6,w2/2-w9/2-h6+h5,g5-h0,g1-h0-g2
  
kwpave,5   
block,0,w6/2,k1,h1+k1,0,g1-h0-g2-g6  
     
AFILLT,54,58,r1,!
VSBA,       9,      60   
VDELE,      10, , ,1
   
VSBV,       5,      11
  
kwpave,2   
block,0,w1/2,,w2/2,g1-g2,g1
block,0,w7/2,,w2/2,g1,g1+g3
!建立中间空口   
kwpave,1
block,0,w3/2,0,-(w4/2),g5,g1+g3   
  
vsel,s,loc,z,g1-g2,g1+g3
cm,volu1,volu
allsel,all
  
vsel,s,loc,z,g5,g1+g3
vsel,r,loc,y,0,-w4/2
vsel,r,loc,x,0,w3/2
cm,v1,volu
allsel,all
VSBV,volu1,v1  
   
!建立中间四个四方立柱  
kwpave,5
block,w6/2,w3/2,k1+h1,w2/2-w4/2,0,g1-h0-g2
  
!建立圆柱孔r2=75
kwpave,8
CYL4,w5/2,-w8/2,r2, , , ,g1
kwpave,1
vsel,s,loc,z,g1-g2,g1
vsel,a,loc,z,g5-g4,g5
  
cm,v2,volu
allsel,all
VSEL,U, , ,v2
vsel,r,loc,x,w5/2-r2,w5/2+r2
vsel,r,loc,y,-w8/2+r2,-w8/2-r2
cm,v3,volu
allsel,all
VSBV,v2,v3
  
kwpave,1
  
vsel,s,loc,z,0,h0
cm,v40,volu
allsel,all
vsel,s,loc,z,h0,g1-g2
cm,v41,volu
vadd,all
allsel,all
vsel,s,loc,z,g1-g2,g1+g3
cm,v42,volu
allsel,all
  
vglue,all
  
CSYS,0  !原始坐标
WPAVE,0,0,0  
CSYS,4   
  
MSHAPE,1,3D  
MSHKEY,0
SMRT,7
VMESH,all
  
fini
/solu
asel,s,loc,x,0
asel,a,loc,y,w2/2
DA,all,SYMM
allsel,all
DA,1,ALL,0  
  
asel,s,loc,z,g5-g4
  
SFA,113,1,PRES,15.6
allsel,all
asel,s,loc,z,g1+g3
cm,area85,AREA
SFA,area85,1,PRES,3.689   
allsel,all
  
SFTRAN
solve   
fini
  
/POST1   
SET,LAST
/GRAPHICS,FULL   
ETABLE,,VOLU     !将每个单元的体积放入单元表
SSUM             !将单元表格内数据求和
*GET,tvolu,SSUM,,ITEM,volu  !单元表中体积和写入标量tvolu中
  
/GRAPHICS,FULL  !
  
  
asel,s,loc,y,k1+h1    !
nsla,,1  
nsort,s,eqv
*GET,stressm1,SORT,,MAX  
ALLSEL,ALL
  
asel,s,loc,x,w1/2-k1-h2    !
nsla,,1  
nsort,s,eqv
*GET,stressm2,SORT,,MAX  
ALLSEL,ALL  
  
asel,s,loc,z,g1-g2    !
nsla,,1  
nsort,s,eqv
*GET,stressm3,SORT,,MAX  
ALLSEL,ALL
  
asel,s,loc,z,g5    !
nsla,,1  
nsort,s,eqv
*GET,stressm4,SORT,,MAX  
ALLSEL,ALL
  
finish
  
/opt
opanl,zhengji,lgw         
!xiahengliang
  
opvar,h1,dv,30,50,0.01     
opvar,h2,dv,15,20,0.01     
opvar,h3,dv,20,50,0.01    !
opvar,h4,dv,50,100,0.01   !
opvar,h5,dv,20,40,0.01    !
opvar,h6,dv,40,70,0.01    !
  
opvar,g2,dv,40,60,0.01    !
opvar,g3,dv,10,30,0.01    !
opvar,g4,dv,40,80,0.01    !
opvar,r1,dv,100,200,0.01   !
  
!定义状态变量
opvar,stressm1,sv,50,70,0.01   
opvar,stressm2,sv,50,70,0.01   
opvar,stressm3,sv,50,70,0.01  
opvar,stressm4,sv,50,70,0.01  
OPSAVE,zhengji,opt0     !
opvar,tvolu,OBJ,,,100
opkeep,on    !件
optype,subp  !子问题近似法也就是零阶方法。
opexe    !运行优化
fini

winterhorse

明白了！
我改改试试！

bhs

好铁