【原创】热应力分析命令流

ansysabaqus

这两天做了一个热应力分析的问题，由于需要计算不同温度、不同厚度等条件下的结果，所以编了命令流文件。现贡献出来，希望对大家有所帮助。
   问题简述：
   三个体连接在一起，其中左边和右边的体为同一种材料（标为V1），中间的体为另一种材料（V2）。V1和V2具有不同的弹性模量、热膨胀系数。参考温度为1400，计算结构从1400降到20时的热应力。

ansysabaqus

/BATCH  
!
! Part1---predefined scalar parameters
!
! parameters for geometrical dimension
xlayer=1
xlength=2
ylength=10
zlength=8
! paramters for material properties
mtialc=297000  !elastic modulus MPa
mtisialc=200000
atialc=9.2E-6   !CTE
atisialc=9.1E-6
! paramters for temperatures
tempref=1400 !reference temperature
tempnow=20  ! room temperature
!
! Part2----preprocessor
!
/PREP7
! building geometry  
BLOCK,0,xlayer/2,0,ylength/2,0,zlength/2,
BLOCK,xlayer/2,xlayer/2+xlength,0,ylength/2,0,zlength/2,  
ALLSEL,ALL  
VGLUE,ALL  
VPLOT,ALL
ALLSEL,ALL  
!*  
! element definition
ET,1,SOLID45
!*  
! material properties
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,mtialc
MPDATA,PRXY,1,,0.2  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
UIMP,1,REFT,,,tempref  
MPDATA,ALPX,1,,atialc   
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,2,,mtisialc
MPDATA,PRXY,2,,0.2  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
UIMP,2,REFT,,,tempref  
MPDATA,ALPX,2,,atisialc   
ALLSEL,ALL  
!
! define components
!
!  components of volume, 1-tialc  2-tisialc
VSEL,S,LOC,X,xlayer/2+xlength/2
CM,v1,VOLU
VSEL,INVE
CM,v2,VOLU
ALLSEL,ALL
!  components of area for symmetry boundary x
ALLSEL,ALL
ASLV,S  
ASEL,R,LOC,X,0-1e-6,0+1e-6
APLOT
CM,a-x-symm,AREA
ALLSEL,ALL
!  components of area for symmetry boundary y
ALLSEL,ALL
ASLV,S  
ASEL,R,LOC,Y,0-1e-6,0+1e-6
APLOT
CM,a-y-symm,AREA
ALLSEL,ALL
!  components of area for symmetry boundary z
ALLSEL,ALL
ASLV,S  
ASEL,R,LOC,Z,0-1e-6,0+1e-6
APLOT
CM,a-z-symm,AREA
ALLSEL,ALL
! component of lines of volume1
CMSEL,S,v1
ASLV,S  
LSLA,S  
LPLOT,ALL
CM,line-v1,LINE
ALLSEL,ALL
!  x direction line division of volume1
CMSEL,S,line-v1   
LSEL,R,LOC,Z,0  
LSEL,R,LOC,Y,0  
CM,line-x1,LINE
ALLSEL,ALL
!  y direction line division of volume1
CMSEL,S,line-v1   
LSEL,R,LOC,X,xlayer/2+xlength  
LSEL,R,LOC,Z,0  
CM,line-y,LINE
ALLSEL,ALL  
!  z direction line division of volume1
CMSEL,S,line-v1   
LSEL,R,LOC,X,xlayer/2+xlength  
LSEL,R,LOC,Y,0  
CM,line-z,LINE
ALLSEL,ALL  
!  x direction line divison of volume2
CMSEL,S,v2
ASLV,S  
LSLA,S  
LPLOT,ALL
LSEL,R,LOC,Z,0  
LSEL,R,LOC,Y,0  
CM,line-x2,LINE
ALLSEL,ALL
! mesh division
LESIZE,line-x1, , ,20, , , , ,1
LESIZE,line-y, , ,25, , , , ,1
LESIZE,line-z, , ,20, , , , ,1
LESIZE,line-x2, , ,5, , , , ,1
! mesh volumes
TYPE,   1   
MAT,       1
REAL,   
ESYS,       0   
SECNUM,
!*  
VMESH,v1   
!*  
TYPE,   1   
MAT,       2
REAL,   
ESYS,       0   
SECNUM,
!*  
VMESH,v2   
!
FINISH  
! PART3---solution
/SOL
ALLSEL,ALL  
!*  
ANTYPE,0
!
DA,a-x-symm,SYMM
DA,a-y-symm,SYMM
DA,a-z-symm,SYMM
! temperature specification
TUNIF,tempnow,   
ALLSEL,ALL  
SAVE,'tempok','db',
SOLVE   
FINISH  
!  PART4---POSTPROCESSOR
/POST1  
ALLSEL,ALL
SET,LAST
!*  get the maximum of s1 stress
/EFACET,1   
AVPRIN,0,   
PLNSOL, S,1, 0,1.0  
*GET,s1max,PLNSOL,0,MAX,,,,
!*  get the maximum of seqv stress
/EFACET,1   
AVPRIN,0,   
PLNSOL, S,EQV, 0,1.0
*GET,seqvmax,PLNSOL,0,MAX,,,,
!*  get the maximum of sx stress
/EFACET,1   
AVPRIN,0,   
PLNSOL, S,X, 0,1.0
*GET,sxmax,PLNSOL,0,MAX,,,,   
!*  get the maximum of sy stress
/EFACET,1   
AVPRIN,0,   
PLNSOL, S,Y, 0,1.0  
*GET,symax,PLNSOL,0,MAX,,,,
!*  get the maximum of sz stress
/EFACET,1   
AVPRIN,0,   
PLNSOL, S,Z, 0,1.0  
*GET,szmax,PLNSOL,0,MAX,,,,
!   output the result got
*CFOPEN,YIN-RESULT,TXT,'G:\YIN\',APPEND
*VWRITE,'Emodulus','thickness','tempnow','s1max','seqvmax','sxmax','symax','szmax'
%12C%12C%12C%12C%12C%12C%12C%12C
*VWRITE,mtisialc,xlayer,tempnow,s1max,seqvmax,sxmax,symax,szmax
(8F12.3)
*CFCLOS
FINISH

freemoon

希望搂住这样的热心人能不断出现
谢谢

dingwei

能和搂住更好的交流吗？
我的QQ：42723162。

xiongjinhui

这是你做的吗？
书上有这样的例子吧？

yuxiaoyuh1138

我想请教一下，关于温度上升膨胀系数不一致导致的热应力计算方法中，有的是通过
tref=XX，
bfunif=XX
计算，
而楼上是通过TUNIF,xx计算，
这两种方法是不是得到同样的结果？
还有如果采用：
d,all,temp与采用上述两种方法是不是一样呢？

zhuljuan

xiongjinhui
请问你在那本书上看到的，我刚刚接触热应力分析，想买本热应力分析的参考书，能不能推荐一下？
谢谢！

gengqingtao

现在我有一问题想请教您，关于hgen的，一个体大小为1*2*3，假设其功率为10w,则其HGEN=10/6,现在我把3维的体改为2维的面，比如只建2*3这个面，那么应在这个面上加载多大的HGEN,如何计算。

xiaoma'winter

不管怎么样，谢谢楼主！

niufangyong

好资料，谢谢楼主

adam.mars

好资料，谢谢好心楼主

victor2044

好东西啊，楼主！刚好我做的课题有些相似，有机会讨论下

u-boat

多谢分享，正好要学做热应力了。

yigexiaoyu

感谢分享，不得已要学习热应力啦！郁闷啊！

victor2044

加载部分看的不是很明白，楼主能不能解释下啊，俺是菜鸟

crazy_leo

学习ing,希望有所帮助

ljlaser

热应力很好的例子，赞一个

linchenghao

谢谢楼住

山顺

好贴啊！快流泪了，正在学这个

zaishuiyifang6

借鉴一下！