[原创]梁单元和弹簧单元模拟桩土作用例题 请老师们指点！！（附命令流）

windalike

大家帮我看看对不对，另外还有几个问题请教一下：
问题：
1.关于弹簧刚度的计算是否正确 K=MZ，弹簧的长度选取有何依据。
2.计算中为何加上弯矩荷载就不能收敛，是不是对beam单元的设置上有问题。
命令流：
/clear
!定义相关参量,5层土体
*DIM,MK,ARRAY,1,5,, , ,     !定义水平抗力系数比例常数m的矩阵
*SET,MK(1,1,1) , 4500      !第一层土的m值
*SET,MK(1,2,1) , 5000       !第二层土的m值
*SET,MK(1,3,1) , 5500      !第三层土的m值
*SET,MK(1,4,1) , 8000      !第四层土的m值
*SET,MK(1,5,1) , 9000     !第五层土的m值

!定义荷载（单位KN.m）
*SET,FX, 716               !水平荷载
*SET,FY, 278
*SET,FZ, 2071
*SET,Mx, 6373   ! 弯矩
*SET,My, 46814
*SET,Mz, 2263

!进入前处理器
/prep7
et,1,beam188                !桩身单元
et,2,combin14               !弹簧单元

!薄壁圆筒桩的截面定义 外半径2.4m,内半径2.355m
SECTYPE,   1, BEAM, CTUBE, ctube, 0
SECOFFSET, CENT
SECDATA,2.355,2.4,8,0,0,0,0,0,0,0  
!!!!!!!!!!
mp,ex,1,2.06e8            !桩的材料属性(Q235钢)
mp,nuxy,1,0.3
mp,dens,1,78

!建立整个桩模型的节点（用户操作建模，再提取编号用EXCEL编辑得）
CSYS,0
n,1 ,,,47             ,,,,   
n,2 ,,,43.0136951     ,,,,   
n,3 ,,,39.3914444     ,,,,   
n,4 ,,,36.1           ,,,,   
n,5 ,,,33.0490563     ,,,,   
n,6 ,,,30.6097146     ,,,,   
n,7 ,,,28.6593712     ,,,,   
n,8 ,,,27.1           ,,,,   
n,9 ,,,25.5666667     ,,,,   
n,10,,,24.0333333     ,,,,   
n,11,,,22.5           ,,,,   
n,12,,,20.92          ,,,,   
n,13,,,19.34          ,,,,   
n,14,,,17.76          ,,,,   
n,15,,,16.18          ,,,,   
n,16,,,14.6           ,,,,   
n,17,,,13.0666667     ,,,,   
n,18,,,11.5333333     ,,,,   
n,19,,,10             ,,,,   
n,20,,,8.37542693     ,,,,   
n,21,,,6.09052315     ,,,,   
n,22,,,2.87688787     ,,,,   
n,23,,,-1.64297495    ,,,,   
n,24,,,-8             ,,,,   
!生成单元
type,1
*do,i,1,23
e,i,i+1
*enddo

!建立桩侧X方向弹簧模型,共19个弹簧（弹簧长度5m）
NSEL,S,LOC,Z,10,47  !桩身在土内的高程为10～47
ngen,2,100,all,,,5
type,2
allsel,all
!按节点分层
!层1  17～19

*do,i,17,19,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,1,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,100+i
*enddo

!层2  12～16

*do,i,12,16,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,2,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,100+i
*enddo

!层3  9～11

*do,i,9,11,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,3,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,100+i
*enddo

!层4  5～8

*do,i,5,8,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,4,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,100+i
*enddo

!层5  1～4

*do,i,1,4,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,5,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,100+i
*enddo

!建立桩侧y方向弹簧模型,共19个弹簧（弹簧长度5m）
NSEL,S,LOC,Z,10,47  !桩身在土内的高程为10～47
NSEL,r,LOC,x,0
ngen,2,300,all,,,,5,,1,
type,2
allsel,all
!按节点分层
!层1  17～19

*do,i,17,19,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,1,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,300+i
*enddo

!层2  12～16

*do,i,12,16,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,2,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,300+i
*enddo

!层3  9～11

*do,i,9,11,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,3,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,300+i
*enddo

!层4  5～8

*do,i,5,8,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,4,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,300+i
*enddo

!层5  1～4

*do,i,1,4,1
*get,vZ,node,i,loc,Z       !获取节点的Y坐标值
r,i,mk(1,5,1)*abs(vZ-10)     !根据Y值计算水平抗力系数，即弹簧的刚度KK=MZ
real,i
    e,i,300+i
*enddo

!底层弹簧
allsel
csys,0
NGEN,2,200,1, , , , ,5,1,
type,2
real,1
e,1,201
allsel
save
finish

!进入求解器
/solu
csys,0
allsel
!约束边界条件
nsel,s,loc,x,5               
nsel,a,loc,z,52
nsel,a,loc,y,5     
d,all,all                  
ALLSEL,ALL
D,1, , , , , ,UX,UY, , , ,   

ACEL,0,,-9.81  !施加重力加速度

!桩顶载荷(只有力的荷载可以收敛 加上力矩荷载无法收敛？？)
allsel
F,24,FX,FX
F,24,FZ,FZ
F,24,Fy,Fy
!F,24,MX,MX
!F,24,MZ,MZ
!F,24,My,My

time,1
autot,on
nlgeom,On
nropt,full
csys,0
solve
finish

windalike

最近又仔细研究了一下beam梁单元和弹簧单元，发现自己以前的命令流还有不少错误，重新做了一个用beam44单元，用弹性地基刚度来模拟土作用的例子，贴上来请高手指教。
/CLEAR                              
/UNITS,SI                           
/PREP7                              
ET,1,BEAM44                          
TYPE,1                              
MP,EX,1,2.1E+08                     
MP,NUXY,1,.3                        
MP,GXY,1,7.9E+07                     
!泥面以下                           
R,1,0.6722,1.9,1.9,2.4,2.4,3.8      
RMORE,0.6722,1.9,1.9,2.4,2.4,3.8     
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,1458000,1458000            
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
                                    
                                    
R,2,0.6722,1.9,1.9,2.4,2.4,3.8      
RMORE,0.6722,1.9,1.9,2.4,2.4,3.8     
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,1058400,1058400            
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
                                    
                                    
R,3,0.6722,1.9,1.9,2.4,2.4,3.8      
RMORE,0.6722,1.9,1.9,2.4,2.4,3.8     
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,748800 ,748800            
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
                                    
                                    
R,4,0.6722,1.9,1.9,2.4,2.4,3.8      
RMORE,0.6722,1.9,1.9,2.4,2.4,3.8     
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,590400,590400              
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
                                    
                                    
R,5,0.6722,1.9,1.9,2.4,2.4,3.8      
RMORE,0.6722,1.9,1.9,2.4,2.4,3.8     
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,367200,367200              
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
                                    
                                    
R,6,0.6722,1.9,1.9,2.4,2.4,3.8      
RMORE,0.6722,1.9,1.9,2.4,2.4,3.8     
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,144000,144000              
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
                                    
                                    
R,7,0.6722,1.9,1.9,2.4,2.4,3.8      
RMORE,0.6722,1.9,1.9,2.4,2.4,3.8     
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,24000,24000               
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
                                    
!泥面以上自由端                     
R,8,0.6722,1.9,1.9,2.4,2.4,3.8      
RMORE,0.6722,1.9,1.9,2.4,2.4,3.8     
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,0,0                        
RMORE,,,,,,                          
RMORE,,,,,,                          
RMORE,,,,,,                          
N, 1,,,-54,,,,                       
N, 2,,,-47,,,,                       
N, 3,,,-36,,,,                       
N, 4,,,-32,,,,                       
N, 5,,,-29,,,,                       
N, 6,,,-25,,,,                       
N, 7,,,-15,,,,                       
N, 8,,,-10,,,,                       
N, 9,,,-5,,,,                        
N, 10,,,0,,,,                        
N, 11,,,4,,,,                        
N, 12,,,8,,,,                        
                                    
MAT,1                                
REAL,1                              
E,1, 2                              
REAL,2                              
E,2, 3                              
REAL,3                              
E,3, 4                              
REAL,4                              
E,4, 5                              
REAL,5                              
E,5, 6                              
REAL,8                              
E,6, 7                              
REAL,8                              
E,7, 8                              
REAL,8                              
E,8, 9                              
E,9, 10                              
E,10, 11                             
E,11, 12                             
                                    
FINISH                              
/SOLU                                
ANTYPE,STATIC                        
OUTPR,BASIC,ALL                     
ANTYPE,STATIC                        
D,1,ALL                              
                                    
F,12,FX,716                          
F,12,FY,278                          
F,12,FZ,-2071                        
F,12,MX,6373                        
F,12,MY,46814                        
F,12,MZ,2263                        
                                    
!波浪水流力                          
SFBEAM,8,1,PRES,46.55,48.85,0,0,0,0  
SFBEAM,8,2,PRES,-6.82,-6.82,0,0,0,0  
SFBEAM,9,1,PRES,48.85,54,0,0,0,0     
SFBEAM,9,2,PRES,-6.82,-6.82,0,0,0,0  
SFBEAM,10,1,PRES,54,80,0,0,0,0      
SFBEAM,10,2,PRES,-6.82,-6.82,0,0,0,0
                                    
SOLVE                                
FINISH

windalike

自己给自己顶一下，希望高手点评一下做的对错与否，谢谢！

jinqinghai

Good work, I think.

But I don't know the failure criterion for this analysis.

lhui828

!定义相关参量
*DIM,MK,ARRAY,1,4,, , ,     !定义水平抗力系数比例常数m的矩阵
*SET,MK(1,1,1) , 6000       !第四层土的m值
*SET,MK(1,2,1) , 5000       !第三层土的m值
*SET,MK(1,3,1) , 4000       !第二层土的m值
*SET,MK(1,4,1) , 2000       !第一层土的m值
*DIM,FQ,ARRAY,1,4,, , ,     !定义桩周单位面积摩擦力
*SET,FQ(1,1,1) , 40.53      !中性点以下的单位面积正摩擦力
*SET,FQ(1,2,1) , -33.78     !中性点以上第三层的单位面积负摩擦力
*SET,FQ(1,3,1) , -16.14  
*SET,FQ(1,4,1) , -4.8
*SET,QX, 100                !水平荷载
*SET,QZ, 100
*SET,b0, 1
*SET,h0, 0.5


!进入前处理器
/prep7
et,1,solid45                !桩身单元
et,2,combin14               !弹簧单元
et,3,surf154                !表面效应单元
keyopt,1,1,0
keyopt,2,3,0                !作为纵向三维弹簧
keyopt,3,4,1                !不包含中间节点
r,1
mp,ex,1,3.25e10             !桩的材料属性
mp,nuxy,1,0.3
mp,dens,1,2700

!建立整个桩模型的节点
n,1                        
n,6,1
fill,1,6
ngen,6,6,1,6,1,,,0.2
ngen,21,36,1,36,1,,0.5
/view,1,1,1,1               !以正等侧显示
/ang,1
/REP,FAST
GPLOT

!建立桩的几何实体模型
k,1
k,2,1
k,3,1,,1
k,4,,,1
k,5,,10,
k,6,1,10,
k,7,1,10,1
k,8,,10,1
/PNUM,kp,1
kplot
v,1,2,3,4,5,6,7,8
lsel,s,loc,y,0
lsel,a,loc,y,10
lesize,all,,,5
allsel
lsel,s,loc,y,5
lesize,all,,,20
vmesh,1
nummrg,all                  !压缩重复元素
numcmp,all                  !合并重复元素

!建立第一组弹簧模型,共7*16=102个弹簧
nsel,s,loc,x,1
nsel,r,loc,y,-0.1,8.1
nplot
ngen,2,1000,all,,,2
type,2
*do,i,1,17,1
*if,i,le,4,then            !判断属于哪一层土
   kk=1
   *elseif,i,le,8,then
   kk=2
   *elseif,i,le,12,then
   kk=3
   *elseif,i,le,17,then
   kk=4
*endif
*do,j,6,36,6
*get,vy,node,j+(i-1)*36,loc,y       !获取节点的Y坐标值
    r,kk+1,mk(1,kk,1)*abs(vy-8)*b0*h0/6      !根据Y值计算水平抗力系数，即弹簧的刚度
    real,kk+1
    e,j+(i-1)*36,1000+j+(i-1)*36
*enddo
*enddo
allsel
!最大单元号602

!第二组弹簧单元,共7*16=102个弹簧
allsel
nsel,s,loc,x,0
nsel,r,loc,y,-0.1,8.1
nsel,r,loc,z,-0.1,1.1
nplot
ngen,2,2000,all,,,-2
type,2
*do,i,1,17,1
*if,i,le,4,then
   kk=1
   *elseif,i,le,8,then
   kk=2
   *elseif,i,le,12,then
   kk=3
   *elseif,i,le,17,then
   kk=4
*endif
*do,j,1,31,6
*get,vy,node,j+(i-1)*36,loc,y
    r,kk+10,mk(1,kk,1)*abs(vy-8)*b0*h0/6
    real,kk+10
    e,j+(i-1)*36,2000+j+(i-1)*36
*enddo
*enddo
allsel
!最大单元号704

!第三组弹簧单元,共7*16=102个弹簧
local,11,0,,,,,90
csys,0
allsel
nsel,s,loc,z,1
nsel,r,loc,y,-0.1,8.1
nsel,r,loc,x,-0.1,1.1
nplot
ngen,2,3000,all,,,,,2
type,2
*do,i,1,17,1
*if,i,le,4,then
   kk=1
   *elseif,i,le,8,then
   kk=2
   *elseif,i,le,12,then
   kk=3
   *elseif,i,le,17,then
   kk=4
*endif
*do,j,31,36,1
*get,vy,node,j+(i-1)*36,loc,y
    r,kk+20,mk(1,kk,1)*abs(vy-8)*b0*h0/6
    real,kk+20
    esys,0
    e,j+(i-1)*36,3000+j+(i-1)*36
*enddo
*enddo
allsel
!最大单元号码806

!第四组弹簧单元,共7*16=102个弹簧
allsel
nsel,s,loc,z,0
nsel,r,loc,y,-0.1,8.1
nsel,r,loc,x,-0.1,1.1
nplot
ngen,2,4000,all,,,,,-2
type,2
*do,i,1,17,1
*if,i,le,4,then
   kk=1
   *elseif,i,le,8,then
   kk=2
   *elseif,i,le,12,then
   kk=3
   *elseif,i,le,17,then
   kk=4
*endif
*do,j,1,6,1
*get,vy,node,j+(i-1)*36,loc,y
    r,kk+20,mk(1,kk,1)*abs(vy-8)*b0*h0/6
    real,kk+20
    esys,0
    e,j+(i-1)*36,4000+j+(i-1)*36
*enddo
*enddo
allsel
!最大单元号码为908

!底层弹簧
allsel
csys,0
ngen,2,5000,1,36,1,,-1
type,2
r,1000,mk(1,1,1)*8*b0*h0/6*20
real,1000
*do,i,1,36,1
  e,i,5000+i
*enddo
allsel
gplot

!第一组表面效应单元
allsel
r,1001
real,1001
local,13,0,,,,90
type,3
*do,i,1,16,1
*do,j,6,30,6
  nsel,s,node,,j+(i-1)*36
  nsel,a,node,,j+6+(i-1)*36
  nsel,a,node,,j+42+(i-1)*36
  nsel,a,node,,j+36+(i-1)*36
  esys,13
  esurf
*enddo
*enddo

!第二组表面效应单元
allsel
local,13,0,,,,90
type,3
*do,i,1,16,1
*do,j,1,29,6
  nsel,s,node,,j+(i-1)*36
  nsel,a,node,,j+6+(i-1)*36
  nsel,a,node,,j+42+(i-1)*36
  nsel,a,node,,j+36+(i-1)*36
  esys,13
  esurf
*enddo
*enddo

!第三组表面效应单元
allsel
local,14,0,,,,90
type,3
*do,i,1,16,1
*do,j,1,5,1
  nsel,s,node,,j+(i-1)*36
  nsel,a,node,,j+1+(i-1)*36
  nsel,a,node,,j+37+(i-1)*36
  nsel,a,node,,j+36+(i-1)*36
  esys,14
  esurf
*enddo
*enddo
csys,0

!第四组表面效应单元
allsel
local,15,0,,,,90
type,3
*do,i,1,16,1
*do,j,31,35,1
  nsel,s,node,,j+(i-1)*36
  nsel,a,node,,j+1+(i-1)*36
  nsel,a,node,,j+37+(i-1)*36
  nsel,a,node,,j+36+(i-1)*36
  esys,15
  esurf
*enddo
*enddo
save
finish

!进入求解器
/solu
csys,0
allsel
nsel,s,loc,x,3               
nsel,a,loc,x,-2
nsel,a,loc,z,3
nsel,a,loc,z,-2
d,all,all                   !约束边界条件
nsel,a,loc,y,-1
d,all,all
nsel,a,loc,y,0
d,all,ux
d,all,uz
ACEL,0,9.81,0,              !施加重力加速度

!桩顶表面平均分布载荷
allsel
nsel,s,loc,y,10
nsel,r,loc,x,-0.1,1.1
nsel,r,loc,z,-0.1,1.1
nplot
esln,s
sfe,all,6,pres,,5000        !桩顶表面分布荷载
nsel,r,loc,x,1
f,all,fx,QX                  !水平载荷
nsel,s,loc,y,10
nsel,r,loc,z,1
f,all,fz,QZ                  !水平载荷
allsel
gplot

!第四层土的表面正摩擦力
csys,0
allsel
nsel,s,loc,y,0,1.5
esln,s
esel,r,type,,3
sfe,all,2,pres,,FQ(1,1,1)
/PSF,PRES,TANx,2,0,1
gplot

!第三层土的表面负摩擦力
csys,0
allsel
nsel,s,loc,y,2.5,3.5
esln,s
esel,r,type,,3
sfe,all,2,pres,,FQ(1,2,1)
/PSF,PRES,TANx,2,0,1
gplot

!第二层土的表面负摩擦力
csys,0
allsel
nsel,s,loc,y,4.5,5.5
esln,s
esel,r,type,,3
sfe,all,2,pres,,FQ(1,3,1)
/PSF,PRES,TANx,2,0,1
gplot

!第一层土的表面负摩擦力
csys,0
allsel
nsel,s,loc,y,6.5,7.5
esln,s
esel,r,type,,3
sfe,all,2,pres,,FQ(1,4,1)
/PSF,PRES,TANx,2,0,1
gplot

allsel
gplot
time,1
autot,on
nlgeom,on
nropt,full
csys,0
solve
finish

/POST1
!PLNSOL,U,Y,1,1
!PLNSOL,S,Z,1,1

PATH,path1,2,30,20,
PPATH,P51X,1
PATH,STAT   

/PBC,PATH,1
!/REPLOT
/PBC,PATH,0
  
AVPRIN,0,0,

PDEF,SY,S,Y,AVG
/PBC,PATH, ,0   

PRANGE,1,1,10,YG,   
PLPATH,SY
也许有帮助吧

lxlxx1314

你qq多少，交流一下吧，我也在做桩土，我的59783530

sea2066

我的qq是379458228多交流下

ansys1.0

楼主犀利，我的QQ541844639，最近研究桩土，弹簧单元，期待交流！

mthinking

楼主的资料值得研究